@echo off
rem code by 523066680@cn-dos.net
setlocal enabledelayedexpansion
set source=%~dp0
set dest=L:\files\烧录
 
rem 源路径可以是自身路径，考虑到输入和%~dp0都可能出现末尾有\的情况，
rem 增加了判断及处理
 
if "%source:~-1%"=="\" (set source=%source:~0,-1%)
if "%dest:~-1%"=="\" (set dest=%dest:~0,-1%)
 
if not exist "%source%\" (
   echo 源[目录]不存在，按任意键退出
   pause>nul
   exit
)
 
echo 请确认: 源目录 %source%
echo 备份到 %dest%
if not exist "%dest%\" (
  echo 作为备份的目录%dest%  不存在，将尝试建立。
  (md "%dest%")||(
    echo 目标不能建立，可能是目标磁盘不存在，按任意键退出。
    pause>nul
    exit
  )
  goto :justcopy
)
 
type nul>DelFile.txt
type nul>DelFold.txt
 
echo _
echo 按任意键开始搜索+清理 "%dest%"中可能多出的文件或子文件夹
pause>nul
echo _
 
for /f "tokens=*" %%a in ('dir /a /s /b "%dest%"') do (
  set pathname=%%a
  set pathname=!pathname:%dest%\=!
  if exist "%%a" ( 
      if not exist %source%\!pathname! (
            rem dir是一次性的，可能已删除了总目录，所以增加判断_是否存在
            if exist "%%a\" (
                 Tree "%%a">>DelFold.txt
                 rd /s /q "%%a"
                 rem echo Remove directory : %%a>>DelFold.txt
            ) else (
                 del /f /s /a /q "%%a">>DelFile.txt
            )
      )
  )
)
echo 本次清理生成日志 DelFold.txt DelFile.txt
type "DelFold.txt" "Delfile.txt"
 
:justcopy
echo _
echo 按任意键继续开始XCOPY...
pause>nul
echo _
  if exist cut.txt (
    xcopy /s /d /c /h /exclude:cut.txt  "%source%" "%dest%"
  ) else (
    xcopy /s /d /c /h "%source%" "%dest%"
  )
echo 按任意键退出
pause>nul
exit
复制代码

@echo off
setlocal enabledelayedexpansion
if "%~1"=="" (echo arg1 empty &exit /b)
if "%~2"=="" (echo arg2 empty &exit /b)

rem 参数中的路径末尾不应有斜杠。
set src=%~1
set dest=%~2
set exclude=%~3
echo %src%   to   
echo           %dest%
echo exclude : %exclude%
if not exist "%src%" (echo %src% does not exist &pause>nul &exit) 
if not exist "%dest%" (echo %dest% does not exist &pause>nul &exit)
if "%src:~-1%"=="\" (set src=%src:~0,-1%)
if "%dest:~-1%"=="\" (set dest=%dest:~0,-1%)
pause

echo Clear files. some dest\files not exist in source
rem 如果只提示找不到文件而没有显示文件名，是因为目标目录一个文件也没有
rem 是dir的提示
for /f "tokens=*" %%a in ('dir /a-d /s /b %dest%') do (
	set str=%%a
	set str=!str:%dest%\=!
	if not exist "%src%\!str!" (
		echo !str! not exist in %src%
		del "%dest%\!str!"
	)
)
echo clear folder
for /f "tokens=*" %%a in ('dir /ad /s /b %dest%') do (
	set str=%%a
	set str=!str:%dest%\=!
	if not exist "%src%\!str!" (
		echo !str! not exist in %src%
		rd "%dest%\!str!"
	)
)
echo xcopy
xcopy /i /f /s /d /y /h /EXCLUDE:%exclude% %src% %dest%
rem /i   如果目标不存在又在复制一个以上的文件，则假定目标是个目录。
rem /S   复制目录和子目录，除了空的
rem /f   复制时显示完整的源和目标文件名。
rem /c   即使有错误，也继续复制。
rem /y   复制文件审核设置(隐含 /O 复制文件所有权和 ACL 信息)
rem /h   也复制隐藏和系统文件。
pause
复制代码