**********************************************************************************


【程序9】
题目：要求输出国际象棋棋盘。
1.程序分析：用i控制行，j来控制列，根据i+j的和的变化来控制输出黑方格，还是白方格。

@echo off &setlocal enabledelayedexpansion
set "str=1 2 3 4 "
for %%a in (%str%) do (
        set var1=!str:%%a =!
        for %%b in (!var1!) do (
                set var2=!var1:%%b =!
                for %%c in (!var2!) do (
                        echo %%a%%b%%c
                )
        )

)

pause>nul
复制代码

@echo off &setlocal enabledelayedexpansion
set /p Cdate=请输入日期(如：2008-1-2日或2008/01/02)：
for /f "tokens=1-3 delims=/-, " %%a in ("%Cdate%") do (
set/a yy=%%a,mm=100%%b%%100,dd=100%%c%%100
)
call ate2Day %yy%-1-1 days1
call ate2Day %Cdate% days2
set/a res=days2-days1+1
echo.&echo %yy%年%mm%月%dd%日 是 %yy%年 的第 %res% 天。
pause>nul
goto :eof
::注意：以下"函数"由willsort完成(略有改动)；
ate2Day 日期 传回(数值)结果
setlocal ENABLEEXTENSIONS 
for /f "tokens=1-3 delims=/-, " %%a in ('echo/%1') do ( 
  set yy=%%a & set mm=%%b & set dd=%%c 
)
set /a dd=100%dd%%%100,mm=100%mm%%%100 
set /a z=14-mm,z/=12,y=yy+4800-z,m=mm+12*z-3,j=153*m+2 
set /a j=j/5+dd+y*365+y/4-y/100+y/400-2472633
endlocal&set %2=%j%&goto :EOF 
ay2Date 数值 传回(日期)结果
setlocal ENABLEEXTENSIONS 
set /a i=%1,a=i+2472632,b=4*a+3,b/=146097,c=-b*146097,c/=4,c+=a 
set /a d=4*c+3,d/=1461,e=-1461*d,e/=4,e+=c,m=5*e+2,m/=153,dd=153*m+2,dd/=5 
set /a dd=-dd+e+1,mm=-m/10,mm*=12,mm+=m+3,yy=b*100+d-4800+m/10 
(if %mm% LSS 10 set mm=0%mm%)&(if %dd% LSS 10 set dd=0%dd%) 
endlocal&set %2=%yy%-%mm%-%dd%&goto :EOF 
复制代码

@echo off &setlocal enabledelayedexpansion
for /l %%a in (1 1 9) do (
        for /l %%b in (1 1 %%a) do (
                set/a res=%%a*%%b
                set "res=!res!  " %======此处用来对齐=========%
                set/p=%%ax%%b=!res:~0,2!  <nul
        )
        echo.
) 
pause>nul
复制代码

@echo off&setlocal EnableDelayedExpansion
for /l %%a in (101 1 200) do (
  set /a n=%%a-1&set "flag="
  for /l %%b in (2 1 !n!) do (
    set /a m=%%a%%%%b
     if !m! equ 0 set flag=a
  )
  if not defined flag echo 素数 %%a
)
echo\&pause
复制代码

 
@echo off&setlocal EnableDelayedExpansion
for /l %%a in (101 2 200) do (
  set "flag="
  for /l %%b in (3 2 15) do (
    set /a m=%%a %% %%b
     if !m! equ 0 set flag=A
  )
  if not defined flag echo 素数 %%a
)
echo\&pause

 
复制代码

@echo off&setlocal enabledelayedexpansion
:: 原创作者： 梦想种子
for /l %%i in (0 1 9) do set /a t%%i=%%i*%%i*%%i
for /l %%i in (1 1 10000) do (
  set "k=00000%%i"
  set a=!k:~-1!
  set b=!k:~-2,1!
  set c=!k:~-3,1!
  set d=!k:~-4,1!
  set e=!k:~-5,1!
  set /a n=t!a!+t!b!+t!c!+t!d!+t!e!
  if "!n!" == "%%i" echo %%i
)
pause
复制代码

@echo off&setlocal enabledelayedexpansion
echo 水仙花数有：&echo.
for /l %%i in (100 1 999) do (
        set var=%%i
        set/a num1=!var:~0,1!,num2=!var:~1,1!,num3=!var:~2,1!
        set/a var=!num1!*!num1!*!num1!+!num2!*!num2!*!num2!+!num3!*!num3!*!num3!
        if !var! EQU %%i echo %%i
        )

pause>nul
复制代码

@echo off&setlocal enabledelayedexpansion
set "ko=                              "
for /l %%i in (1 2 13) do (
  if defined flag (set /a n-=2&set /a c-=1) else set /a n=%%i&set /a c+=1
  call set m=%%ko:~!c!%%
  set /p=!m!<nul
  for /l %%b in (1 1 !n!) do set /p=*<nul
  echo.
  if !n! geq 7 set flag=a
)
echo.&pause
复制代码

@echo off&setlocal enabledelayedexpansion
:top
::原创作者：wudixin96
::  in=行数：
set/a ab=1,var=30,in=10
set str=1
for /l %%i in (1,1,%in%) do (
   set "num="
   set /a num2=0
   for %%a in (!str!) do (
   set /a num2+=1
   if !num2!==1 set "str1="
   set /a num1=%%a+num
   set "str1=!str1! !num1!"
   set num=%%a
   )
   call :lis "!str1:~1!"
   set "str=!str1! 0"
)
pause>nul
exit
:lis
set max=%~1
for /l %%a in (0 1 300) do (
  if not "!max:~%%a,1!"=="" set /a ci+=1
)
set /a ki=var-ci/2
for /l %%a in (1 1 !ki!) do set "kg= !kg!"
echo !kg!!max!
set nam!ab!=!kg!!max!
set /a ab+=1
set ci=0&set "kg="
goto :eof
复制代码

@echo off
set /p a=请输入要分解的数
set /a c=a/2
:a
set /a b=%b%+1
set /a d=%a%/%b%
set /a s=%a%%%%b%
if not "%s%"=="0" (goto a) else (set/p=%b% <nul &set a=%d% &set b=1&goto a)
pause
复制代码

@echo off&setlocal enabledelayedexpansion
:start
cls
set "str=1"
set /p EN=请输入一个数字：
call :CheckPrime %EN% Prime Remainder
set str=%str% x !OBJ! 

if "!str:~-2,1!"=="1" set str=!str:~0,-4!
if not "!str:~-6,1!"=="1" set str=!str:~4!

echo.&echo %EN% = !str!
pause>nul
goto :start

:CheckPrime OBJ Prime Remainder
set /a OBJ=%~1,Remainder=0
set /a var=!OBJ!/2+1,var_=!OBJ! %% 2
if !var_! EQU 0 (
	set str=!str! x 2
	set/a Prime=2,Remainder=!OBJ!/2
	call :CheckPrime !Remainder! Prime Remainder
	)
for /l %%i in (3 2 !var!) do (
	set /a var_=!OBJ! %% %%i
	if !var_! EQU 0 (
		set str=!str! x %%i
		set/a Prime=%%i,Remainder=!OBJ!/%%i
		call :CheckPrime !Remainder! Prime Remainder
		)
	)
复制代码

@echo off
echo.
echo          求两数的最大公约数、最小公倍数
echo ========================================
title 求两数的最大公约数
setlocal enabledelayedexpansion
set /p num1=请输入第一个数字：
set /p num2=请输入第二个数字：
set/a res=%num1%*%num2%
echo ----------------------------------------
echo %num1%和%num2%：&echo.
:test
     set /a temp=%num1% %% %num2%
     if %temp% NEQ 0 (
         set /a num1=!num2!
         set /a num2=!temp!
         goto :test)

set /a res=%res%/%num2%
echo 最小公倍数为：%res% 最大公约数为：%num2%
pause>nul
复制代码

@echo off&setlocal EnableDelayedExpansion
set a=0
for /l %%i in (1,1,10) do (
set /a a=a*2+1
echo 倒数第%%i天时有!a!个桃子)
pause
复制代码

@echo off&setlocal EnableDelayedExpansion
set a=1
set b=0
for /l %%i in (1,1,20) do (
set /a a=!a! * %%i
set /a b=!b!+!a!
)
echo 20的累积为：!b!
pause
复制代码

@echo off&setlocal EnableDelayedExpansion
set /p nnn=请输入一个数 &cls
set mmm=%nnn%
:loop
set bbb=%mmm:~0,1%%bbb%
set mmm=%mmm:~1%
if not "%mmm%"=="" goto loop
if "%bbb%"=="%nnn%" (echo %nnn% 是回文数) else echo %nnn% 不是回文数
pause
复制代码

@echo off&setlocal EnableDelayedExpansion
set a=0
for /l %%i in (1,1,5) do (
set /a a=a*5+1
)
echo 最少要!a!只桃子
pause
复制代码

@echo off &setlocal enabledelayedexpansion
for /l %%i in (1,1,8)do (
	for /l %%j in (1,1,8) do (
	set /a n=%%i+%%j,n=n%%2
	if !n! equ 1 (set/p=■<nul) else (set/p=  <nul)
	)
	echo.
)
pause>nul
复制代码

@echo off
set n=100
for /l %%i in (1,1,10) do (set /a n/=2,ns+=n)
echo 共经过%ns%米 第10次反弹%n%米
pause>nul
复制代码

@echo off&setlocal enabledelayedexpansion
for /l %%a in (100 -1 1) do set "kk= %%a !kk!"
:main
set "ie=0"
for %%a in (%kk%) do set /a ie+=1
if %ie% neq 1 call :st
echo %kk%
pause&exit
:st
for %%a in (%kk%) do (
        set /a num+=1
        if !num! equ 3 (
                set "num=0"
                set "kk=!kk: %%a =!
            )
    )
goto main
复制代码

@echo off&setlocal enabledelayedexpansion
for /l %%a in (10 1 99) do (
   for /l %%b in (10 1 99) do (
      set /a x=9*%%b
      set /a y=8*%%a
      if !y! geq 10 if !y! leq 99 (
         if !x! geq 100 if !x! leq 999 (
            if %%a==%%b (
               set /a k=809*%%a
               set /a l=800*%%a+9*%%a
               if "!k!"=="!l!" (
                  echo "??" 代表的两位数是%%a 
                  echo "809*??" 后的结果是!k!
               )
            )
          )
       )
   )
)
pause>nul 
复制代码

@ECHO OFF&SETLOCAL ENABLEDELAYEDEXPANSION
:KT 
SET /P F= 请输入日期，如2008年2月3日 2008-2-3  :
FOR /F "TOKENS=1,2,3 DELIMS=-" %%A IN ("%F%") DO SET K=%%A &SET M=%%B &SET D=%%C
SET G=%K:~-2%
IF "%G%"=="00" (
   SET/A E=%K%/400*400
   IF !E! == %K% GOTO RUN 
   IF !E! NEQ %K% GOTO PING
)     
IF "%G%" NEQ "00" (
         SET/A R=%K%/4*4
         IF !R! == %K% GOTO RUN 
         IF !R! NEQ %K% GOTO PING
)
:RUN
SET R=4
GOTO H
:PING
SET R=1
GOTO H
:H 
GOTO %M%
:1
SET I=0
GOTO Z
:2 
SET I=31
GOTO Z
:3
SET I=59
GOTO Z
:4
SET I=90
GOTO Z
:5
SET I=120
GOTO Z
:6
SET I=151
GOTO Z
:7
SET I=181
GOTO Z
:8
SET I=212
GOTO Z
:9
SET I=243
GOTO Z
:10
SET I=273
GOTO Z
:11
SET I=304
GOTO Z
:12
SET I=334
GOTO Z
:Z
IF "%R%" == "1" (
SET/A J=%D%+%I% )
IF "%R%" == "4" (
If "%m%" leq "2" SET /A J=%D%+%I% 
IF "%M%" GTR "2" SET /A J=%D%+%I%+1 
) 
ECHO 你输入的日期是这一年中的第!J!天 
GOTO KT 
复制代码

@echo off&setlocal enabledelayedexpansion
echo 请输入日期，如2008年8月9日:2008-8-9
set /p p=
for /f "tokens=1,2,3 delims=-" %%i in ("%p%") do set y=%%i &set m=%%j &set d=%%k
set "g= 00+31+28+31+30+31+30+31+31+30+31+30"
set /a s=%m%*3
call set /a j=%%g:~1,%s%%%%d%
set i=%y:~-2%
if "%i%" == "00" (
   set /a k=%y%%%400
   if !k! == 0 (goto run) else goto ping
) else (
set /a l=%y%%%4
       if !l! == 0 (goto run)else goto ping
) 
:run 
if %m% leq 2 (set /a j=%j%) else set /a j=!j!+1
:ping
echo 你输入的日期是这一年中的第%j%天 
pause&exit
复制代码

@echo off&setlocal enabledelayedexpansion
for /l %%i in (1 1 9) do (set b=
   for /l %%j in (1 1 %%i) do (
   set /a a=%%i*%%j
   set b=!b! %%i*%%j=!a!
   )
echo !b!
)
pause
复制代码

@echo off
if exist ss.txt goto :bb

::显示100以内素数
set m=2
>ss.txt echo 2
set/a m+=1
>>ss.txt echo 3

:zz
set flag=
set/a m+=2
set/a n=m-1
for /l %%i in (2 1 %n%) do (
　call :sf %%i
)
if not defined flag >>ss.txt echo %m%
if %m% lss 99 goto :zz

:bb
::显示100以内偶数
for /l %%o in (4 2 100) do call :pd %%o
pause
goto :eof

::显示偶数成两个素数的和
:pd
　set sflag=
　for /f %%m in (ss.txt) do (
　　for /f %%n in (ss.txt) do (
　call :bj %%m %%n he %1
　if defined sflag goto :show
　　)
　)
:show
　echo %1=%xx%+%yy%
　goto :eof
:sf
　set/a x=m%%%1
　if %x%==0 set flag=1
　goto :eof
:bj
　set/a xx=%1
　set/a yy=%2
　set/a %3=%1+%2
　if %he% equ %4 set sflag=1
复制代码

 
@echo off
set /a a=99/8
echo a是%a%
set /a b=809*%a%
echo b是%b%
pause>nul
复制代码

@echo off
for /l %%a in (1 1 4) do (
for /l %%b in (1 1 4) do (
for /l %%c in (1 1 4) do (
if %%a neq %%b (
if %%b neq %%c (
if %%a neq %%c echo %%a%%b%%c 2>nul
)
)
)
)
)
pause>nul
复制代码

::输出0-7组成的大于500的奇数个数
::code by nomyself
::05/12/2008
@echo off
rem 初值为1
set sum=0
set n=1
goto set
:set
rem 将值赋予临时变量k并转入判断是输出还是续循环
set k=%n%
goto flag
:flag
rem k大于0就继续循环，否则就转入输出
if %k% GTR 0 (call goto while) else goto printf
:while
rem  将j的值与7比较，小于7就设flag为1并重置循环数k;大于7就增加n的值
set /a j=%k%%%10
if %j% LEQ 7 (call goto setwhile) else goto add
:setwhile
set flag=1 & set /a k/=10
goto flag
:printf
if %flag%==1 set /a sum+=1
:add
::n自增2并且n大于500就输出总数
set /a n+=2
if %n% GTR 500 goto end
goto set
:end
echo 满足条件的值的总数为：%sum%
pause
复制代码

@echo off
setlocal enabledelayedexpansion
for /l %%i in (1,1,4) do (
 for /l %%j in (1,1,4) do (
   for /l %%k in (1,1,4) do (
   set dd=%%i%%j%%k 
   if %%i neq %%j if %%j neq %%k if %%i neq %%k set /a n+=1 &echo !dd!
)))
echo 总共!n!个
pause>nul
复制代码

@echo off
setlocal enabledelayedexpansion
for /l %%i in (1,1,4) do (
 for /l %%j in (1,1,4) do (
   for /l %%k in (1,1,4) do (
   set /a dd=%%i%%j%%k 
   if "!dd:~0,1!" neq "!dd:~1,1!" if "!dd:~0,1!" neq "!dd:~2,1!" if "!

dd:~2,1!" neq "!dd:~1,1!" set /a n+=1 &echo !dd!
)))
echo 总共!n!个
pause>nul
复制代码

@echo off
setlocal enabledelayedexpansion
for /l %%i in (1,1,4) do (
　for /l %%j in (1,1,4) do (
  　 for /l %%k in (1,1,4) do (
  　　 set /a dd=%%i%%j%%k 
  　　 if %%i neq %%j (
   　　   if %%i neq %%k (
      　　   if %%j neq %%k set /a n+=1 &echo !dd!))
)))
echo 总共!n!个
pause>nul
复制代码

@echo off
setlocal enabledelayedexpansion
for /l %%i in (101,2 200) do (
  set tag=
  set /a c=%%i/2
  for /l %%j in (2,1,!c!) do (
    set /a b=%%i %% %%j
    if !b!==0 set tag=1)
  if not defined tag echo %%i &set /a n+=1
)
echo 共!n!个素数
pause>nul
复制代码

:main
@echo off
setlocal enabledelayedexpansion
set /a a=1
set /a b=1
set /p n=请输入月份
if "!n!" gtr "2" (
for /l %%i in (3,1,!n!) do (
set /a c=!a!+!b!
set /a b=!a!
set /a a=!c!)) else ( set /a c=1)
echo !c!
goto :main
pause>nul
复制代码

@echo off
setlocal enabledelayedexpansion
set /p n=请输入一个整数
set /a k=2
for /l %%i in (2,1,%n%) do (
   set /a d=!n!%%!k!
   if !d!==0 (
    echo !k!
    set /a n=!n!/!k!
   ) else (
    set /a k=!k!+1 
    if !n!==!k! echo !k! & call :ex   
 )
)
goto :eof
:ex
pause>nul
复制代码

@echo off
setlocal enabledelayedexpansion
set /p p1=请输入整数
set /p p2=请输入另一个整数
set /a a=p1
set /a b=p2
:be
set /a c=!a! %% !b!
set /a a=!b!
set /a b=!c!
if !c! neq 0 (goto :be) else echo !a!是最大公约数
pause>nul
echo 求最大公倍数
set /a max=%p1%*%p2%/!a!
echo %max%是最大公倍数
pause>nul
复制代码

@echo off
setlocal enabledelayedexpansion
set /p a=请输入一个整数
set /p b=请输入另一个整数
for /l %%i in (%a%,-1,1) do (
set /a a1=!a!%%%%i
set /a a2=!b!%%%%i
if !a1!==0 if !a2!==0 set c=%%i&echo %%i& goto :t1
)
:t1
pause>nul

set /a cc=!a!*!b!/!c!
echo !cc!
pause>nul
复制代码

@echo off
setlocal enabledelayedexpansion
set /p n=请输入整数
set /p=%n%=<nul
set /a k=2
:main
if !k!==%n% set /p=!k!<nul & goto :ex
set /a c=!n! %% !k!
if !c!==0 (
 set /p=!k!*<nul
 set /a n=!n!/!k!
 ) else (
 set /a k+=1
)
goto :main
:ex
pause>nul
复制代码

@echo off
setlocal enabledelayedexpansion
for /l %%i in (1,1,1000) do (
 set /a k=%%i
 set /a n=!k!/2
 set /a s=0
 for /l %%j in (1,1,!n!) do (
   set /a kk=!k! %% %%j
   if !kk!==0  set /a s+=%%j
 )
 if !s!==!k! echo !k!
)
pause>nul
复制代码

@echo off
setlocal enabledelayedexpansion
set /a a=1
for /l %%i in (1,1,9) do (
set /a b=2*!a!+2
set /a a=!b!
)
echo 第一天摘的桃子数是 !a!
pause>nul
复制代码

@echo off
setlocal enabledelayedexpansion
for /l %%i in (1,2,7) do (
 set /a n=%%i
 for /l %%j in (1,1,!n!) do (
   set /p=*<nul
  )
 echo.
) 
for /l %%i in (5,-2,1) do (
 set /a n=%%i
 for /l %%j in (1,1,!n!) do (
   set /p=*<nul
  )
 echo.
) 
pause>nul
复制代码

@echo off
setlocal enabledelayedexpansion
set /a s=0
for /l %%i in (1,1,20) do (
 set /a k=%%i
 set /a s1=1
 for /l %%j in (1,1,!k!) do (
   set /a s1*=%%j
 )
 set /a s+=!s1!
)
echo !s!&pause>nul
复制代码

@echo off
setlocal enabledelayedexpansion
:main
set a=
set /p a=请输入一个五位数
if "!a:~0,1!"=="!a:~4,1!" (
if "!a:~1,1!"=="!a:~3,1!"  (echo !a!是回文) else echo !a!不是回文
) else (
echo !a!不是回文
)
pause>nul 
goto :main
复制代码

 
@echo off
setlocal enabledelayedexpansion
set /a n=5
set  b=
call :loop 5
echo 第五个人!b!岁
pause>nul
goto :eof
:loop
set /a n=%1
set /a n-=1
if !n!==0 (set /a b=10 & goto :eof) else (
call :loop !n!
set /a b+=2
)
复制代码

@echo off
::有1、2、3、4个数字，能组成多少个互不相同且无重复数字的三位数？都是多少？
::原创：sjzong
setlocal enabledelayedexpansion
set num=0
for /l %%i in (1 1 4) do (
for /l %%j in (1 1 4) do (
  for /l %%k in (1 1 4) do (
   if %%i neq %%j if %%i neq %%k if %%k neq %%j (echo %%i%%j%%k & set /a num=!num!+1)
  )
)
)
echo !num!
pause
复制代码

@echo off
setlocal enabledelayedexpansion
::原创：sjzong
echo 请输入十个数字……
set str=
for /l %%a in (1 1 10) do (
set /p shuzi=请输入%%a个数:
set str=!str! !shuzi!
) 
set zimu=ABCDEFGHIJ
set ss=
for %%b in (!str!) do (
set count=0
for %%c in (!str!) do if %%b geq %%c set /a count=!count!+1
set /a count=!count!-1
set ss=!ss! !count!
)
for /l %%d in (0 1 9) do (
set cou=
for %%e in (!ss!) do if %%d==%%e set /a cou=!cou!+1
for /l %%f in (1 1 !cou!) do set num=!num! !zimu:~%%d,1!
)
for %%i in (!str!) do (
set count=0
for %%j in (!str!) do if %%i geq %%j set /a count=!count!+1
set /a count=!count!-1
if !count!==0 set num=!num:A=%%i!
if !count!==1 set num=!num:B=%%i!
if !count!==2 set num=!num:C=%%i!
if !count!==3 set num=!num:D=%%i!
if !count!==4 set num=!num:E=%%i!
if !count!==5 set num=!num:F=%%i!
if !count!==6 set num=!num:G=%%i!
if !count!==7 set num=!num:H=%%i!
if !count!==8 set num=!num:I=%%i!
if !count!==9 set num=!num:J=%%i!
)
echo 你输入的十个数字是：!str!
echo 排序后的十个数字是：!num!
pause
复制代码

@echo off
::打印杨辉三角
::原创：sjzong
setlocal enabledelayedexpansion
set str= 1
echo !str!
for /l %%a in (1 1 9) do (
::求出上一个数列的相邻两个数的和。
set num1=1
for %%b in (!str!) do ( 
::num1是用来控制是相邻两数的前一个数%%i；num2为后一个数%%j
set /a num1=!num1!+1
set /a shu=!num1!+1
set num2=1
for %%c in (!str!) do (
set /a num2=!num2!+1
if !num2!==!shu! set /a sum=%%b+%%c
)
set str1=!str1! !sum!
set sum=
)
::在求出每相邻两数之和后，在前后各加上1
set str=1!str1!1
::用来打印时在数字的前面加上空格
set /a a=10-%%a
set b=
for /l %%d in (0 1 !a!) do (set b= !b!)
set str=!b!!str!
set str1=
echo !str!
)
pause
复制代码

@echo off&setlocal EnableDelayedExpansion
::程序分析： 注意是先吃一半再吃一个则公式是a=2*(a+1)
::原创：sjzong
set num=1
echo 第10天时有!num!个桃子
for /l %%i in (9 -1 1) do (
set /a num=!num!*2+2
echo 第 %%i天时有!num!个桃子)
pause
复制代码

@echo off&setlocal EnableDelayedExpansion
::程序分析：这些桃子，每一只猴子来分的时候，把桃子的数量减一后必须是五的倍数！所以五只猴子来分，必须进行五次判断的！
::程序中的num是用来判断是否达到五次判断！
::原创：sjzong
for /l %%i in (1 1 10000) do (
set /a a=%%i
set /a num=0
for /l %%j in (1 1 5) do (
  set /a b=!a!-1
  set /a c=!b! %% 5
  if !c! == 0 (
  set /a a=!b!/5 
  set /a a=!a!*4
  set /a num=!num!+1)
)
if !num!==5 (echo 最少要%%i只桃子 & goto :end)
)
:end
pause
复制代码

@echo off
setlocal enabledelayedexpansion
::原创：sjzong
echo 请输入十个数字……
::读入10个数字，分别放在t1~t10内，并把数字合成一行，中间加个空格。
set str=
for /l %%a in (1 1 10) do (
set /p t%%a=请输入%%a个数:
set str=!str! !t%%a!
)
echo 排序前的数字序列是：!str!
::数字排序是采用冒泡排序的，每相邻的两个数进行比较，大的放在后面。
::要进行9趟比较，第1趟求出最大放在最后一个数…第9趟是剩下两个数进行比较
::其实t%%b代表相邻的前一个数，b代表相邻的后一个数，比较后进行交换
for /l %%a in (1 1 9) do (
set /a a=10-%%a
for /l %%b in (1 1 !a!) do (
  set /a c=%%b+1
  set /a b=t!c!
  if !t%%b! gtr !b! (
   set /a temp=t%%b
   set /a t%%b=t!c!
   set /a t!c!=!temp!
  )
)
)
::把排序后的数字排列出来
set str=
for /l %%a in (1 1 10) do (
set str=!str! !t%%a!
)
echo 排序后的数字序列是：!str!
pause
复制代码

@echo off
setlocal enabledelayedexpansion
::原创：sjzong
echo 请输入十个数字……
::读入10个数字，分别放在t1~t10内，并把数字合成一行，中间加个空格。
set str=
for /l %%a in (1 1 10) do (
set /p t%%a=请输入%%a个数:
set str=!str! !t%%a!
)
echo 排序前的数字序列是：!str!
::数字排序是采用选择排序的，取第1个数跟后面的9个数进行比较，大的话进行交换。
::然后取第2个数跟后面的8个数进行比较，大的进行交换，以此类推。
for /l %%a in (1 1 9) do (
set /a a=%%a+1
for /l %%b in (!a! 1 10) do (
  if !t%%a! gtr !t%%b! (
   set /a temp=t%%a
   set /a t%%a=t%%b
   set /a t%%b=!temp!
  )
)
)
::把排序后的数字排列出来
set str=
for /l %%a in (1 1 10) do (
set str=!str! !t%%a!
)
echo 排序后的数字序列是：!str!
pause
复制代码

@echo off
setlocal enabledelayedexpansion
::原创：sjzong
::程序分析：每个数的分子是上一个数的分子与分母之和，分母为上一个数的分子
::fz为分子，fm为分母
set fz=1
set fm=1
set qiuji=1
set qiuhe=0
echo 正在输出这二十个数……
for /l %%i in (1 1 20) do (
set /a c=!fm!
set /a fm=!fz!
set /a fz=!fz!+!c!
echo !fz!^/!fm!
set /a qiuji=!qiuji!*!fz!/!fm!
set /a qiuhe=!qiuhe!+!fz!/!fm!
)
echo.
echo 这二十个数的积为：!qiuji!
echo 这二十个数的和为：!qiuhe!
echo.
pause
复制代码

::题目：有一分数序列：2/1，3/2，5/3，8/5，13/8，21/13...求出这个数列的前20项之和。
@echo off
setlocal enabledelayedexpansion
set /a b=1,a=2
set s=
for /l %%i in (1,1,20) do (
set /a c=b+a
echo !a!/!b!
set /a s=s+!a!/!b!
set /a b=a
set /a a=c
)
echo %s%
pause>nul
复制代码

@echo off
setlocal enabledelayedexpansion
::选择排序法
echo 共输入10个数
for /l %%i in (1,1,10) do (
 set /p a_%%i=请输入%%i个数
 set str=!str! !a_%%i!
)
echo %str%
for /l %%i in (1,1,9) do (
 set /a b=%%i+1
 for /l %%j in (!b!,1,10) do (
   if !a_%%i! gtr !a_%%j! (
      set /a t=a_%%i
      set /a a_%%i=a_%%j
      set /a a_%%j=t
    )
)
)
for /l %%i in (1,1,10) do (
 set str1=!str1! !a_%%i!
)
echo %str1%
pause>nul
复制代码

 
@echo off&setlocal EnableDelayedExpansion
set /p num=请输入要因数分解的数：
set str=!num!=1
:a
set /a n=2
:b
set /a aa=!num! %% !n!
::这if语句是能整除的语句，求出商，并记下那个质数n
if !aa! equ 0 (
  set /a num=!num!/!n!
  set str=!str!*!n!
::等于1，分解结束，跳到c，不等于1，继续把商除以素数列，跳到a
  if !num! neq 1 (goto :a) else (goto :c)
)
::这if语句是不能整除的，换下一个素数，并跳到b
if !aa! neq 0 (
::若等于2时n+1，不等于2时n+2
  if !n! equ 2 (set /a n=!n!+1) else (set /a n=!n!+2)
  goto :b
)
:c
echo 分解完是：!str!
pause
复制代码

 
@echo off
setlocal enabledelayedexpansion
::原创：sjzong
set /p num=请输入大于3的偶数：
set /a aa=!num! %% 2
rem 判断输入的数字是否为偶数
if !aa! neq 0 (
cls
echo 你输入的数字不是偶数！
set /p num=请再次输入大于3的偶数：
)
rem 判断输入的数字是否小于等于3
if !num! leq 3 (
cls
echo 你输入的数字小于4！
set /p num=请再次输入大于3的偶数：
)
rem 判断输入的偶数是否为4，是的话直接拆分为两个2的和，不是的话进行两个奇数的拆分。
if !num!==4 (echo 偶数 !num! 是素数 2 与 2 的和。) else (
set /a yiban=!num!/2
rem 拆分偶数时只需从3到该偶数的一半即可
for /l %%a in (3 2 !yiban!) do (
  set /a shu=!num!-%%a
  set /a a1=0
  set /a a2=0
  call :test %%a
  if !flag!==1 set /a a1=1
  call :test !shu!
  if !flag!==1 set /a a2=1
  if !a1!==1 if !a2!==1 echo 偶数 !num! 是素数 %%a 与 !shu! 的和。
)
)
pause
goto :eof
rem 判断该数是否为素数时，只需计算从1到该数的一半能被该数整除的次数
rem 次数为1时表示为素数，次数大于1时表示不是素数
:test
  set /a flag=1
  set /a b=%1/2
  set /a count=0
  for /l %%a in (1 1 !b!) do (
   set /a yushu=%1 %% %%a
   if !yushu! equ 0 set /a count=!count!+1
   if !count! gtr 1 (set /a flag=0 & goto :eof)
  )
复制代码

@echo off
setlocal enabledelayedexpansion
::判断是否为八进制，共几位
:1
set /p bb=请输入八进制整数:
set /a aa=%bb%
set /a n=0
:2
set b=%aa:~,1%
if %b% gtr 8  goto :1 
set /a n=n+1
set aa=!aa:~1!
if "%aa%" neq "" goto :2
::echo %n%
::利用权值，求各位十进制值并累加
:3
set /a n-=1
set /a c=%bb:~0,1%
for /l %%i in (1,1,%n%) do set /a c*=8
set /a t+=%c%
set bb=%bb:~1%
if "%bb%" neq "" goto :3
echo %t%
pause>nul
复制代码

@echo off
set /p x=要转换的数:
set /p y=要转换的进制:
call :10 %x% %y%
pause>nul
goto :eof
:10 
set/a t=%1/%2
if %t% gtr 0 call :10 %t% %2
set /a b=%1%%%2
set /p=%b% <nul
复制代码

@echo off&setlocal enabledelayedexpansion
:n
cls
set /p n=请输入人数n:
echo.%n%|findstr "^[1-9][0-9]*$">nul||goto n
:m
set /p m=请输入报数m:
echo.%m%|findstr "^[1-9][0-9]*$">nul||goto m
for /l %%a in (1 1 %n%) do (if %%a lss 10 (set str=!str! 0%%a) else (set str=!str! %%a))
set/a b=3*!m!-3
set/a c=3*!m!
:loop
if "!str:~%b%,3!" equ "" (set s1= 空) else (set s1=!s1!!str:~%b%,3!)
if "!str:~%c%,3!" equ "" (set str=!str:~0,%b%!) else (set str=!str:~%c%!!str:~0,%b%!)
set/a n-=1
if not !n! lss !m! goto loop
echo 出列的数据是：!s1:~1!&set s1=
if !m! equ 1 (echo 剩下的数据是：空&set str=) else (echo 剩下的数据是：!str:~1!&set str=)
pause>nul&goto n
复制代码