[文件操作] 求助批处理建立防止盗拷文件目录的方法

墨者革离

求助：工作电脑中有很多重要工作文件，时不时有人偷偷拷备，又不方便说。这些文件集中放在一个文件夹中。
目标：想复制这个文件夹下的文件、子目录，在另一分区下新建立一套，目录结构与文件相同，但是打开任一文件没有实际内容。
思路：用DIR命令获取源文件夹中的所有目录、文件、类型，用ECHO >在另一文件中建立相同所有目录、文件、类型；用fsutil file createnew 设置每个文件的字节数大小（如果无法按原文件大小，用随机数也可）
假设从D:\Afile真文件夹 新建到E:\Bfile假文件夹。
不知道我说的是否明白？本人不太懂批处理，求代码，谢谢。


————————————————————————————————————————————————
经测试，七楼代码为正解，问题解决，谢谢各位大师。

@echo off & xcopy "D:\Afile" "E:\Afile\" /tey
for /f "delims=" %%F in ('dir /b/s/a-d "D:\Afile" ') do fsutil file createnew "e:%%~pnxF" %%~zF
pause&exit/b
复制代码

flashercs

robocopy D:\Afile E:\Bfile * /E /Create /MT
复制代码

Five66

是监测文件复制 ,然后让其复制假文件么?是的话很麻烦 ,想准确还得弄成驱动

墨者革离

回复 2# flashercs

老师，您这组代码很好，能完全抽拷备一个文件夹及以下文件名，可惜文件都是0字节的。
可不可以用，fsutil file createnew （不知道中间这个怎么写） %random%  
让所有文件有大小？

aloha20200628

回复 1# 墨者革离

@echo off & xcopy /teiy "D:\Afile" "E:\Bfile\"
for /f "delims=" %%F in ('dir /b/s/a-d "D:\Afile" ') do fsutil file createnew "e:%%~pnxF" %%~zF
pause&exit/b
复制代码

墨者革离

回复 5# aloha20200628

先表示感谢。
代码测试，显示：错误，系统找不到指定的路径。

teacoffee

回复  墨者革离
aloha20200628 发表于 2024-11-22 00:07

@echo off & xcopy "D:\Afile" "E:\Afile\" /tey
for /f "delims=" %%F in ('dir /b/s/a-d "D:\Afile" ') do fsutil file createnew "e:%%~pnxF" %%~zF
pause&exit/b

帮试了一下，要这样才行

flashercs

@echo off
set "src=A"
set "dst=B"
@REM robocopy "%src%" %dst% * /E /Create /MT
for %%A in ("%src%") do set "src=%%~fA"
for %%A in ("%dst%") do set "dst=%%~fA"
md "%dst%" 2>nul
xcopy "%src%\*" "%dst%" /E /T /Y
for /r "%src%" %%A in (*) do (
  set "f=%%~fA"
  set "z=%%~zA"
  setlocal enabledelayedexpansion
  set "f2=!f:%src%=%dst%!"
  fsutil file createNew "!f2!" !z!
  endlocal
)
pause
复制代码

aloha20200628

回复 6# 墨者革离

抱歉  xcopy 上路之前忘了充电 漏了一个参数 /i， 5楼代码已订正...

墨者革离

回复 8# flashercs
提示：
找不到文件 - *
请按任意键继续. . .

墨者革离

回复  墨者革离

抱歉  xcopy 上路之前忘了充电  漏了一个参数 /i， 5楼代码已订正...
aloha20200628 发表于 2024-11-22 20:38

    还是这样：

错误:  系统找不到指定的路径。
错误:  系统找不到指定的路径。
错误:  系统找不到指定的路径。
错误:  系统找不到指定的路径。
错误:  系统找不到指定的路径。

请按任意键继续. . .

墨者革离

@echo off & xcopy "D:\Afile" "E:\Afile\" /tey
for /f "delims=" %%F in ('dir /b/s/a-d "D:\Afil ...
teacoffee 发表于 2024-11-22 16:42

谢谢，正解！ :handshake

aloha20200628

回复 11# 墨者革离

！最后爆胎是在 fsutil file createnew！复查原测试样本还真是 ‘源目录’ 与 ‘到达目录’ 仅是盘符不同！若还是维持楼主要求从 "D:\Afile" 到达 "E:\Bfile\"，盘符和路径均不同，须用以下代码 ‘补胎’...

@echo off & xcopy /teiy "D:\Afile" "E:\Bfile\"
for /f "delims=" %%F in ('dir /b/s/a-d "D:\Afile" ') do (
   set "_F=%%F" &setlocal enabledelayedexpansion
   set "_F=!_F:D:\Afile=E:\Bfile!"
   (fsutil file createnew "!_F!" %%~zF) &endlocal)
pause&exit/b
复制代码