[已解决]批处理如何获取FTP上面下载1天前的文件？ - BAT求助&讨论 - 批处理之家 BAT,CMD,批处理,PowerShell,VBS,DOS

Rank: 12

帖子: 14981
积分: 46194
技术: 859
捐助: 745
注册时间: 2008-6-9

31楼 跳转到 »

发表于 2009-4-7 22:47 | 只看该作者

回复 30楼的帖子

 @echo off
rem 指定FTP用户名
set ftpUser=USERNAME
rem 指定FTP密码
set ftpPass=PASSWORD
rem 指定FTP服务器地址
set ftpIP=192.168.0.2
rem 指定待下载的文件位于FTP服务器的什么位置
set ftpFolder=\export\home\PROD\ntcdata\
rem 指定下载几天前的文件
set DaysAgo=1
set ftpDir=%temp%\TempDir.txt
set ftpDown=%temp%\TempDown.txt
rem 假设本机日期格式为yyyy-mm-dd
set FileY=%date:~0,4%
call :DateToDays %date:~0,4% %date:~5,2% %date:~8,2% PassDays
set /a PassDays-=DaysAgo
call :DaysToDate %PassDays% DstYear DstMonth DstDay
 
>"%ftpDir%" echo.%ftpUser%
>>"%ftpDir%" echo.%ftpPass%
>>"%ftpDir%" echo bin
>>"%ftpDir%" echo cd "%ftpFolder%"
>>"%ftpDir%" echo dir * "%temp%\FileList.txt"
>>"%ftpDir%" echo bye
start ftp -v -i -s:"%ftpDir%" %ftpIP%
rem 根据实际情况自行调节延迟时间
ping -n 10 127.1 >nul
 
findstr /i ":*\.SWM$" "%temp%\FileList.txt">"%temp%\FileDate.txt"
findstr /i ":*\.TWM$" "%temp%\FileList.txt">>"%temp%\FileDate.txt"
findstr /i ":*\.XWM$" "%temp%\FileList.txt">>"%temp%\FileDate.txt"
 
>"%ftpDown%" echo.%ftpUser%
>>"%ftpDown%" echo.%ftpPass%
>>"%ftpDown%" echo bin
>>"%ftpDown%" echo cd "%ftpFolder%"
(for /f "usebackq tokens=1-9 delims= " %%a in ("%temp%\FileDate.txt") do (
  setlocal enabledelayedexpansion
  if "%%f" equ "Jan" (
    set FileM=01
  ) else if "%%f" equ "Feb" (
    set FileM=02
  ) else if "%%f" equ "Mar" (
    set FileM=03
  ) else if "%%f" equ "Apr" (
    set FileM=04
  ) else if "%%f" equ "May" (
    set FileM=05
  ) else if "%%f" equ "Jun" (
    set FileM=06
  ) else if "%%f" equ "Jul" (
    set FileM=07
  ) else if "%%f" equ "Aug" (
    set FileM=08
  ) else if "%%f" equ "Sep" (
    set FileM=09
  ) else if "%%f" equ "Oct" (
    set FileM=10
  ) else if "%%f" equ "Nov" (
    set FileM=11
  ) else if "%%f" equ "Dec" (
    set FileM=12
  )
  set FileD=10%%g
  set FileD=!FileD:~-2!
  if "!FileM!" equ "%DstMonth%" (
    if "!FileD!" equ "%DstDay%" (
      echo get "%%i"
    )
  )
  endlocal
))>>"%ftpDown%"
>>"%ftpDown%" echo bye
start ftp -v -i -s:"%ftpDown%" %ftpIP%
goto :eof
 
:DateToDays %yy% %mm% %dd% days
setlocal ENABLEEXTENSIONS
set yy=%1&set mm=%2&set dd=%3
if 1%yy% LSS 200 if 1%yy% LSS 170 (set yy=20%yy%) else (set yy=19%yy%)
set /a dd=100%dd%%%100,mm=100%mm%%%100
set /a z=14-mm,z/=12,y=yy+4800-z,m=mm+12*z-3,j=153*m+2
set /a j=j/5+dd+y*365+y/4-y/100+y/400-2472633
endlocal&set %4=%j%&goto :EOF
 
:DaysToDate %days% yy mm dd
setlocal ENABLEEXTENSIONS
set /a a=%1+2472632,b=4*a+3,b/=146097,c=-b*146097,c/=4,c+=a
set /a d=4*c+3,d/=1461,e=-1461*d,e/=4,e+=c,m=5*e+2,m/=153,dd=153*m+2,dd/=5
set /a dd=-dd+e+1,mm=-m/10,mm*=12,mm+=m+3,yy=b*100+d-4800+m/10
(if %mm% LSS 10 set mm=0%mm%)&(if %dd% LSS 10 set dd=0%dd%)
endlocal&set %2=%yy%&set %3=%mm%&set %4=%dd%&goto :EOFCOPY

[ 本帖最后由 Batcher 于 2009-4-7 22:50 编辑 ]

我帮忙写的代码不需要付钱。如果一定要给，请在微信群或QQ群发给大家吧。
【微信公众号、微信群、QQ群】http://bbs.bathome.net/thread-3473-1-1.html
【支持批处理之家，加入VIP会员！】http://bbs.bathome.net/thread-67716-1-1.html

Rank: 5 Rank: 5

帖子: 157
积分: 633
技术: 0
捐助: 0
注册时间: 2008-8-2

32楼

发表于 2009-4-8 09:41 | 只看该作者

请问batcher，我获取文件不成功，是不是没有把文件放到本地指定的路径？

Rank: 12

帖子: 14981
积分: 46194
技术: 859
捐助: 745
注册时间: 2008-6-9

33楼

发表于 2009-4-8 09:48 | 只看该作者

仅凭一句“获取文件不成功”，我无法给你更多的帮助。

Rank: 5 Rank: 5

帖子: 157
积分: 633
技术: 0
捐助: 0
注册时间: 2008-8-2

34楼

发表于 2009-4-8 10:03 | 只看该作者

那请问程序的默认路径是在哪里？能不能指定路径？

Rank: 12

帖子: 14981
积分: 46194
技术: 859
捐助: 745
注册时间: 2008-6-9

35楼

发表于 2009-4-8 11:34 | 只看该作者

回复 34楼的帖子

能指定路径

 @echo off
rem 指定FTP用户名
set ftpUser=USERNAME
rem 指定FTP密码
set ftpPass=PASSWORD
rem 指定FTP服务器地址
set ftpIP=192.168.0.2
rem 指定待下载的文件位于FTP服务器的什么位置
set ftpFolder=\export\home\PROD\ntcdata
rem 指定从FTP下载下来的文件存放到什么地方
set DownFolder=C:\temp
rem 指定下载几天前的文件
set DaysAgo=1
set ftpDir=%temp%\TempDir.txt
set ftpDown=%temp%\TempDown.txt
rem 假设本机日期格式为yyyy-mm-dd
set FileY=%date:~0,4%
call :DateToDays %date:~0,4% %date:~5,2% %date:~8,2% PassDays
set /a PassDays-=DaysAgo
call :DaysToDate %PassDays% DstYear DstMonth DstDay
 
>"%ftpDir%" echo.%ftpUser%
>>"%ftpDir%" echo.%ftpPass%
>>"%ftpDir%" echo bin
>>"%ftpDir%" echo cd "%ftpFolder%"
>>"%ftpDir%" echo dir * "%temp%\FileList.txt"
>>"%ftpDir%" echo bye
start ftp -v -i -s:"%ftpDir%" %ftpIP%
rem 根据实际情况自行调节延迟时间
ping -n 10 127.1 >nul
 
findstr /i ":*\.SWM$" "%temp%\FileList.txt">"%temp%\FileDate.txt"
findstr /i ":*\.TWM$" "%temp%\FileList.txt">>"%temp%\FileDate.txt"
findstr /i ":*\.XWM$" "%temp%\FileList.txt">>"%temp%\FileDate.txt"
 
>"%ftpDown%" echo.%ftpUser%
>>"%ftpDown%" echo.%ftpPass%
>>"%ftpDown%" echo bin
>>"%ftpDown%" echo cd "%ftpFolder%"
(for /f "usebackq tokens=1-9 delims= " %%a in ("%temp%\FileDate.txt") do (
  setlocal enabledelayedexpansion
  if "%%f" equ "Jan" (
    set FileM=01
  ) else if "%%f" equ "Feb" (
    set FileM=02
  ) else if "%%f" equ "Mar" (
    set FileM=03
  ) else if "%%f" equ "Apr" (
    set FileM=04
  ) else if "%%f" equ "May" (
    set FileM=05
  ) else if "%%f" equ "Jun" (
    set FileM=06
  ) else if "%%f" equ "Jul" (
    set FileM=07
  ) else if "%%f" equ "Aug" (
    set FileM=08
  ) else if "%%f" equ "Sep" (
    set FileM=09
  ) else if "%%f" equ "Oct" (
    set FileM=10
  ) else if "%%f" equ "Nov" (
    set FileM=11
  ) else if "%%f" equ "Dec" (
    set FileM=12
  )
  set FileD=10%%g
  set FileD=!FileD:~-2!
  if "!FileM!" equ "%DstMonth%" (
    if "!FileD!" equ "%DstDay%" (
      echo get "%%i" "%DownFolder%\%%i"
    )
  )
  endlocal
))>>"%ftpDown%"
>>"%ftpDown%" echo bye
start ftp -v -i -s:"%ftpDown%" %ftpIP%
goto :eof
 
:DateToDays %yy% %mm% %dd% days
setlocal ENABLEEXTENSIONS
set yy=%1&set mm=%2&set dd=%3
if 1%yy% LSS 200 if 1%yy% LSS 170 (set yy=20%yy%) else (set yy=19%yy%)
set /a dd=100%dd%%%100,mm=100%mm%%%100
set /a z=14-mm,z/=12,y=yy+4800-z,m=mm+12*z-3,j=153*m+2
set /a j=j/5+dd+y*365+y/4-y/100+y/400-2472633
endlocal&set %4=%j%&goto :EOF
 
:DaysToDate %days% yy mm dd
setlocal ENABLEEXTENSIONS
set /a a=%1+2472632,b=4*a+3,b/=146097,c=-b*146097,c/=4,c+=a
set /a d=4*c+3,d/=1461,e=-1461*d,e/=4,e+=c,m=5*e+2,m/=153,dd=153*m+2,dd/=5
set /a dd=-dd+e+1,mm=-m/10,mm*=12,mm+=m+3,yy=b*100+d-4800+m/10
(if %mm% LSS 10 set mm=0%mm%)&(if %dd% LSS 10 set dd=0%dd%)
endlocal&set %2=%yy%&set %3=%mm%&set %4=%dd%&goto :EOFCOPY

Rank: 5 Rank: 5

帖子: 157
积分: 633
技术: 0
捐助: 0
注册时间: 2008-8-2

36楼

发表于 2009-4-8 11:57 | 只看该作者

回复 35楼的帖子

我已经试过了，还是抓不到文件。请问是否可以设置断点来排除错误？

Rank: 12

帖子: 14981
积分: 46194
技术: 859
捐助: 745
注册时间: 2008-6-9

37楼

发表于 2009-4-8 12:01 | 只看该作者

回复 36楼的帖子

可以，随便设吧。

Rank: 5 Rank: 5

帖子: 157
积分: 633
技术: 0
捐助: 0
注册时间: 2008-8-2

38楼

发表于 2009-4-8 13:07 | 只看该作者

请问batcher，这两句是什么意思？
set ftpDir=%temp%\TempDir.txt 设置临时文件夹？
set ftpDown=%temp%\TempDown.txt 设置临时文件？

Rank: 12

帖子: 14981
积分: 46194
技术: 859
捐助: 745
注册时间: 2008-6-9

39楼

发表于 2009-4-8 13:26 | 只看该作者

回复 38楼的帖子

是的，设置临时文件。
用来在后面的ftp命令中实现“自动”下载。

Rank: 5 Rank: 5

帖子: 157
积分: 633
技术: 0
捐助: 0
注册时间: 2008-8-2

40楼

发表于 2009-4-8 13:50 | 只看该作者

我在Temp文件夹下发现了两个文件，分别是TempDir.txt和TempDown.txt.
文件的内容TempDir.txt:
asx-asx
bin
cd "\export\home\PROD\ntcdata"
dir * "E:\DOCUME~1\eetc\LOCALS~1\Temp\FileList.txt"
bye

TempDown.txt:
asx
asx-asx
bin
cd "\export\home\PROD\ntcdata"
bye

但是我还是没有在set DownFolder=C:\temp（我的电脑上是E:\Temp）
获得*.SWM等文件。

Rank: 12

帖子: 14981
积分: 46194
技术: 859
捐助: 745
注册时间: 2008-6-9

41楼

发表于 2009-4-8 14:50 | 只看该作者

回复 40楼的帖子

1、检查"%temp%\FileList.txt"文件内容是否正确
2、set DaysAgo=1，只下载昨天的问题，检查FTP服务器上指定目录下是否有昨天的文件
3、学学怎么调试代码吧：
不要双击运行
把代码保存为C:\test.bat
把@echo off删除
在合适的地方加上pause
开始
运行
cmd
C:\test.bat
看看执行过程再好好想想到底是哪里出问题了

Rank: 5 Rank: 5

帖子: 157
积分: 633
技术: 0
捐助: 0
注册时间: 2008-8-2

42楼

发表于 2009-4-8 15:02 | 只看该作者

FileList.txt的文件内容获取的是我连接上ftp时的默认目录：/export/home/asx/。那我怎样才能获得\export\home\PROD\ntcdata\目录下的文件内容呢？

[ 本帖最后由 lazygc520 于 2009-4-8 16:16 编辑 ]

Rank: 12

帖子: 14981
积分: 46194
技术: 859
捐助: 745
注册时间: 2008-6-9

43楼

发表于 2009-4-8 16:43 | 只看该作者

回复 42楼的帖子

set ftpFolder=\export\home\PROD\ntcdata
>>"%ftpDir%" echo cd "%ftpFolder%"
>>"%ftpDir%" echo dir * "%temp%\FileList.txt"
自己试着改改这三句

Rank: 5 Rank: 5

帖子: 157
积分: 633
技术: 0
捐助: 0
注册时间: 2008-8-2

44楼

发表于 2009-4-8 17:21 | 只看该作者

我还是只能获取ftp链接上的默认路径：：/export/home/asx/ 下的文件内容。

Rank: 12

帖子: 14981
积分: 46194
技术: 859
捐助: 745
注册时间: 2008-6-9

45楼

发表于 2009-4-8 17:30 | 只看该作者

回复 44楼的帖子

你定义ftpFolder的时候咋写的？注意别把路径中的斜线和反斜线搞混淆了。