[文件操作] 获取批处理所在的文件夹名及名字中的各个部分,和文件夹的父文件夹名

5i365

非常想知道CMD和Powershell实现如下效果的代码, 哪个更容易理解一些, 个人感觉批处理用正则实现起来代码会少很多,但是会感觉不稳，期待高手能出招，感谢!

例如:
我有一个批处理文件 a.bat 它所在的完整路径如下:

C:\Users\Administrator\Desktop\54 阿YueYue、戾格、小田音乐社 - 沈园外\a.bat

想实现双击a.bat后, 能回显:

1.它所在的文件夹名 %wjj%   即  54 阿YueYue、戾格、小田音乐社 - 沈园外        【注：54是序号,后面有个空格，阿YueYue、戾格、小田音乐社  是歌手，后面有个空格-空格，沈园外是歌曲】

2.文件夹名的三个部分分别进行回显:
A.序号  %xh%  即 54
B.歌手  %gs%  即 阿YueYue、戾格、小田音乐社
C.歌曲  %gq%  即 沈园外

3.父文件夹名 %fwjj%  即 Desktop

netbenton

@echo off&setlocal enabledelayedexpansion
for %%a in ("%~p0") do (
	set var=%%~a
	for %%b in ("!var:~0,-1!") do (
		for /f "tokens=1,2,3 delims=- " %%1 in ("%%~nb") do (
			set _xh=%%1
			set _gs=%%2
			set _gq=%%3
		)
	)

)
set _

pause
复制代码

5i365

回复 2# netbenton


    感谢, 没用正则也取出了文件夹名字的三个部分, 但代码理解起来还是有些困难, 没有echo 却能回显, 太高端了
估计powershell会好理解一些

最后的 set _  是什么意思呢?

qixiaobin0715

@echo off
setlocal enabledelayedexpansion
for %%i in ("%~dp0.") do (
    set Folder1=%%~nxi
    echo,!Folder1!
    for /f "tokens=1-2* delims=- " %%a in ("!Folder1!") do (
        set xh=%%a
        set gq=%%b
        set gs=%%c
        echo,!xh!
        echo,!gq!
        echo,!gs!
    )
)
for %%k in ("%~dp0..") do (
    set Folder2=%%~nxk
    echo,!Folder2!
)
pause
复制代码

qixiaobin0715

set _：显示所有变量名以_开头的变量。

5i365

回复 4# qixiaobin0715

感谢出招,所有路径部分都显示了,
下面两行的意思,貌似是: 一个.表示所在文件夹, 两个.表示父文件夹, 真没想到还能这样用,
代码相对好理解一些, 但还是没有用正则

%~dp0.

%~dp0..

5i365

回复 4# qixiaobin0715


  你好, 文件夹名的三个部分是用for输出的, 怎样赋值到单独的变量 %xh%, %gq%, %gs%上呢? 因为后面要用, 脑子一时转不过玩儿来

5i365

回复 4# qixiaobin0715


    直接回显 echo %~dp0. 又不是想要的结果, 难道 . 只是用作 转义 ?

qixiaobin0715

回复 7# 5i365
按2楼的方法即可，已修改。

5i365

回复 9# qixiaobin0715


    为什么要改, 您以前的下面的方法, 不稳吗?

    set "str=%%~ni"
    set "str=!str:-=!"
    for %%j in (!str!) do echo,%%j

5i365

回复 9# qixiaobin0715


    最后那个变量显示错误:

54 阿YueYue、戾格、小田音乐社 - 沈园外
54
阿YueYue、戾格、小田音乐社
沈园外
%~ni
请按任意键继续. . .

qixiaobin0715

回复 10# 5i365
使用for /f 单独赋值方便些。最后循环变量笔误，已修改。

for_flr

$p=$MyInvocation.MyCommand.definition
(split-path $p).split("\")[-1]
(split-path $p).split("\")[-2]
$id=@("序号","歌手","歌名")
$delim=(split-path $p).split("\")[-1].split(" -",[System.StringSplitOptions]::RemoveEmptyEntries)
for($n=0;$n -lt 3;$n++){write-host $id[$n]    $delim[$n]}
$null=[console]::readkey()
复制代码

理解的话，怕是powershell容易一点，比较口语化

qixiaobin0715

谢谢。学习学习powershell

5i365

回复 4# qixiaobin0715


    这个出错了， 如果批处理所在的文件夹的名字是    151 G.E.M.邓紫棋 - 光年之外     回显的值是错误的

151 G.E.M.邓紫棋 - 光年之外

绿色部分总是数字
红色部分可能是数字字母符号空格的组合
蓝色部分也可能是数字字母符号空格的组合，有更稳的办法吗？ 感谢

回显的信息：
151
G.E.M
ECHO 处于关闭状态。
请按任意键继续. . .
-------------------------------------------------------------------------------
批处理代码;
@echo off&mode con cols=106 lines=13&setlocal enabledelayedexpansion

for %%i in ("%~dp0.") do (set wjj=%%~ni
    for /f "tokens=1-2* delims=- " %%a in ("!wjj!") do (
        set xh=%%a
        set gs=%%b
        set gq=%%c
    )
)
echo %xh%
echo %gs%
echo %gq%
pause