[问题求助] [已解决]在文件或文件夹上右键后，发送到，根据剪切板内容重命名当前文件。

zhangop9

在文件或文件夹上右键后，发送到，根据剪切板内容重命名当前文件。

broly

什么系统的？WIN7的非administrateR 用户比XP处理起来要麻烦

zhangop9

winxp系统，如果能改一下如下代码就好了

Set objIE = CreateObject("InternetExplorer.Application")
objIE.Navigate("about:blank")
strText = objIE.document.parentwindow.clipboardData.GetData("text")
objIE.Quit
Wscript.Echo strText

Set objFile = CreateObject("Scripting.FileSystemObject").CreateTextFile("C:\Users\Acer\Desktop\测试.vbs")

objFile.Write strText
objFile.Close
复制代码

1、如果桌面能用环境变量就好了，
2、如果桌面上有同名文件就在文件名后加1“测试1.vbs”

broly

winxp系统就容易很多了。
使用步骤:
1.把下面的VBS保存为 d盘.vbs，然后右键->复制
2.运行->输入"sendto"->确定
3.在打开的文件夹中右键->粘贴快捷方式

这样右键->发送到  就会多了一个选项，使用即可

注意，如果要发送到以他地方，把VBS中的  "d:\" 改为你相应的目录即可，最后一定要有 \

'保存我为 d盘.vbs
Dim objArgs,fso,strText,fileName,extName,destPath

destPath = "d:\" '发送到d:\

Set objArgs = WScript.Arguments
If objArgs.Count = 0 Then WScript.Quit

strText = CreateObject("htmlfile").ParentWindow.ClipboardData.GetData("text")

'剪贴板的内容为空就退出
If strText = "" Then WScript.Quit

Set fso = CreateObject("SCripting.FileSystemObject")

If fso.FileExists(objArgs.Item(0)) Then 
	extName = fso.GetExtensionName(objArgs.Item(0))
	If fso.FileExists(strText & "." & extName) Then 
		fileName = strText & "1." & extName
	Else
		fileName = strText & "." & extName
	End If
	fso.CopyFile objArgs.Item(0),destPath & fileName
ElseIf fso.FolderExists(objArgs.Item(0)) Then
	If fso.FolderExists(strText) Then 
		fileName = strText & "1"
	Else
		fileName = strText
	End If
	fso.CopyFolder objArgs.Item(0),destPath & fileName
End If

Set fso = Nothing
Set objArgs = Nothing
复制代码

zhangop9

可以用，不过好像不是我想要了，我是想用剪切板内容改当前文件名称，这个vbs新建了一个文件

broly

理解错误

Dim objArgs,fso,f,strText,fileName,extName

Set objArgs = WScript.Arguments
If objArgs.Count = 0 Then WScript.Quit

strText = CreateObject("htmlfile").ParentWindow.ClipboardData.GetData("text")

'剪贴板的内容为空就退出
If strText = "" Then WScript.Quit

Set fso = CreateObject("SCripting.FileSystemObject")

If fso.FileExists(objArgs.Item(0)) Then 
        extName = fso.GetExtensionName(objArgs.Item(0))
        If fso.FileExists(strText & "." & extName) Then 
                fileName = strText & "1." & extName
        Else
                fileName = strText & "." & extName
        End If
        Set f = fso.GetFile(objArgs.Item(0))
        f.Name = fileName
ElseIf fso.FolderExists(objArgs.Item(0)) Then
        If fso.FolderExists(strText) Then 
                fileName = strText & "1"
        Else
                fileName = strText
        End If
        Set f = fso.GetFolder(objArgs.Item(0))
        f.Name = fileName
End If

Set fso = Nothing
Set f = Nothing
Set objArgs = Nothing
复制代码

zhangop9

ok,行了，谢谢，帖子中那个问题我自己东搞搞西搞搞，搞出来了，谢谢你版主