[其他] 批处理的这个密码难不难破解？

wangxiulin

大家看看  这个密码行不行

@echo off
goto u
:b
msg * "SORRY"
:u
set /p cc=
if "%cc%"=="mima" goto :b
echo 输入错误 重新输入
goto u
复制代码

必须输入mima才能打开一个提示框 这个密码难不难破解BAT

[ 本帖最后由 wangxiulin 于 2011-2-6 15:04 编辑 ]

semiuel

查看批处理的源代码不就知道密码了?

wangxiulin

我用bat转EXE  转换后生成乱码 打开了也看不懂

CrLf

呵呵，bat转exe没用的，一行wmic命令轻松找到原文件

或者用万能密码：
1" neq "" cls&call type %0&pause>nul&

bat本身就是明文的，所以bat加密的性价比极低

Batcher

批处理bat转exe加密之后的解密破解还原方法
http://bbs.bathome.net/thread-3343-1-1.html

女孩不哭

没看懂4楼的代码，wmic的什么命令？

CrLf

大部分情况下，获取在运行的bat完整路径可以用：
wmic process where "name='cmd.exe'" get commandline

万能密码就是给电脑一个错觉，6楼可以输入这个当密码试试：
1"=="1" (echo 已破解)&if not "

wc726842270

上网下载个下载率“低”的加密软件。或都说用未破解的（但是不是真正的未破解，就不得而知了）。像你说的这种几乎所有对P有了解的人都知道（不过对像要是不知道原理还可以）。尽量还是别用了。太大众化了

CrLf

用常规办法很难防特殊字符，不过对付万能密码其实只要从预处理机制下手就行了，想了三种方法，各有利弊，按实际需要酌情择用：

方法一：

@echo off
set /p cc=请输入密码
for /f %%a in ("%cc%") do if "%%a"=="mima" (echo 正确) else echo 错误
pause
::仍然存在1") do pause &的漏洞
复制代码

方法二：

@echo off
set /p=请输入密码=<nul
more<con >tmp.tmp
findstr "^mima$" tmp.tmp&&(echo 正确)||echo 错误
pause
::输完密码还要ctrl+z结束
复制代码

方法三：

@echo off&setlocal enabledelayedexpansion
set str=1 2 3 4 5 6 7 8 9 0 a b c d e f g h i j k l m n o p q r s t u v w x y z A B C D E F G H I J K L M N O P Q R S T U V W X Y Z
for %%a in (%str%) do (set /a n+=1)&set .!n!=%%a
for %%a in (23 19 23 11) do (
    cls
    choice /c %str: =% /n /cs /m "请输入密码 !input!"
    set /a "true=true|(^!^!(%%a-!errorlevel!))"
    for %%z in (.!errorlevel!) do set input=!input!!%%z!
    )
)
cls&echo 请输入密码 %input%
if "%true%"=="0" (echo 正确) else echo 错误
pause&exit
::效率很低，而且不支持特殊字符
复制代码

[ 本帖最后由 zm900612 于 2011-2-7 14:01 编辑 ]

CrLf

靠，发现我又绕弯了，其实这样就可以：

@echo off&setlocal enabledelayedexpansion
set /p cc=请输入密码
if "!cc!"=="mima"  (echo 正确) else echo 错误
pause>nul
复制代码

因为变量扩展是先解释语句后解释变量

刚刚转了一圈，发现这办法早已有前辈提出了，呵呵，看来我的思维慢了不止一拍

[ 本帖最后由 zm900612 于 2011-2-9 01:32 编辑 ]

Batcher

可以试试你的加密能否顶得住以下几个方法
http://bbs.bathome.net/thread-6119-1-1.html
http://bbs.bathome.net/thread-8433-1-1.html