[文本处理] [已解决]有没有办法批处理合并两个文本中的部分信息啊，

asdbb

如题求助啊，有两个文档，合并成一个新文档，但是两个文档中只提取部分资料，文档行中用逗号分开的。

pcl_test

回复 1# asdbb

新手提问必读
http://www.bathome.net/thread-13187-1-1.html
http://www.bathome.net/thread-9959-1-1.html
http://www.bathome.net/thread-7690-1-1.html

asdbb

文件一
101112345676,00000,1,1234567891012344,,9876543210123456,00000,1
101112345677,00000,1,1234567891012345,,9876543210123456,00000,1
文件2 名字111.txt
111.111.1112,1234567891,1234567891123456,
111.111.1112,1234567892,1234567891123457,
生成文件
1234567891,1234567891123456,00000,1,文件2的文件名111,101112345676，1234567891012344,,9876543210123456,00000,1
1234567892,1234567891123457,00000,1,文件2的文件名111,101112345677，1234567891012344,,9876543210123456,00000,1

Batcher

@echo off
setlocal enabledelayedexpansion
set "FileA=1.txt"
set "FileB=111.txt"
set "FileC=临时.txt"
set "FileD=结果.txt"

(for /f "delims=" %%i in (%FileA%) do (
    set /p str=
    echo !str!%%i
))<%FileB% >%FileC%

set "FileBname=%FileB:~0,-4%"
(for /f "tokens=2-11 delims=," %%a in (%FileC%) do (
    echo %%a,%%b,%%d,%%e,%FileBname%,%%c,%%f,,%%g,%%h,%%i
))>%FileD%
复制代码

asdbb

可以生成啊，谢谢，还有个要是生成结果第一行我要加上些字符如何处理，还有就是那两个文档的第一行有字符但是不需要生成到文档中如何处理？？？非常感谢版主

Batcher

回复 5# asdbb

@echo off
setlocal enabledelayedexpansion
set "FileA=1.txt"
set "FileB=111.txt"
set "FileC=临时.txt"
set "FileD=结果.txt"

(for /f "delims=" %%i in (%FileA%) do (
    set /p str=
    echo !str!%%i
))<%FileB% >%FileC%

set "FileBname=%FileB:~0,-4%"
>%FileD% echo 我要加上些字符
(for /f "skip=1 tokens=2-11 delims=," %%a in (%FileC%) do (
    echo %%a,%%b,%%d,%%e,%FileBname%,%%c,%%f,,%%g,%%h,%%i
))>>%FileD%
复制代码

asdbb

文件一
字符串
101112345676,00000,1,1234567891012344,,9876543210123456,00000,1
101112345677,00000,1,1234567891012345,,9876543210123456,00000,1
字符11111
文件2 名字111.txt
字符串
111.111.1112,1234567891,1234567891123456,
111.111.1112,1234567892,1234567891123457,
生成文件
我要加上些字符
1234567891,1234567891123456,00000,1,文件2的文件名111,101112345676，1234567891012344,,9876543210123456,00000,1
1234567892,1234567891123457,00000,1,文件2的文件名111,101112345677，1234567891012344,,9876543210123456,00000,1
还有些小问题，文件一的最后字符能否删除？原始文件文件一多一行的

Batcher

回复 7# asdbb

@echo off
setlocal enabledelayedexpansion
set "FileA=1.txt"
set "FileB=111.txt"
set "FileC=临时.txt"
set "FileD=结果.txt"

(for /f "delims=" %%i in (%FileB%) do (
    set /p str=
    echo %%i!str!
))<%FileA% >%FileC%

set "FileBname=%FileB:~0,-4%"
>%FileD% echo 我要加上些字符
(for /f "skip=1 tokens=2-11 delims=," %%a in (%FileC%) do (
    echo %%a,%%b,%%d,%%e,%FileBname%,%%c,%%f,,%%g,%%h,%%i
))>>%FileD%
复制代码

asdbb

可以满足现有需求，以后得学习这个BAT啊

pcl_test

回复 9# asdbb
问题得到解决后请在标题最前面注明[已解决]
http://www.bathome.net/thread-3473-1-1.html

yiwuyun

if ($true){}# == ($true){}# goto ___yiwuyun
<# 
:___yiwuyun
@echo off&setlocal&cls
(echo $strPath="%~dp0"&type "%~f0")|powershell -command -
pause
exit/b 0
#>
$file1="1.txt";$file2="111.txt";
$file2BaseName=(gi ($strPath+$file2)).BaseName;
$f1c=gc ($strPath+$file1);
$f2c=gc ($strPath+$file2);
"我要加上些字符";
for($i=0;$i -lt $f1c.count;$i++){
  $temp1=$f1c[$i] -split ",";
  $temp2=$f2c[$i] -split ",";
  $temp2[1]+","+$temp2[2]+","+$temp1[1]+","+$temp1[2]+","+$file2BaseName+","+$temp1[0]+","+$temp1[3]+","+$temp1[4]+","+$temp1[5]+","+$temp1[6]+","+$temp1[7];
}
复制代码

我去，命令行竟然可以直接无视执行策略。浪费表情了。

asdbb

你这个是什么啊，怎么看不懂啊

DAIC

回复 12# asdbb


11楼的代码保存成 test.bat 执行看看
原理是用BAT生成一段代码交给PowerShell去执行

asdbb

回复 13# DAIC


    谢谢！