[日期时间] [已解决]批处理跨年份日期问题？

cbnuisve

在跨年份的时间得出的结果会出错。

@echo off
setlocal enabledelayedexpansion
 set DaysAgo=7
 call :DateToDays %date:~0,4% %date:~5,2% %date:~8,2% PassDays
 set /a PassDays-=%DaysAgo%
 call :DaysToDate %PassDays% DstYear DstMonth DstDay

 set "yyyy=%DATE:~0,4%" 
echo %yyyy%%DstMonth%%DstDay%\


 :DateToDays %yy% %mm% %dd% days
 setlocal ENABLEEXTENSIONS
 set yy=%1&set mm=%2&set dd=%3
 if 1%yy% LSS 200 if 1%yy% LSS 170 (set yy=20%yy%) else (set yy=19%yy%)
 set /a dd=100%dd%%%100,mm=100%mm%%%100
 set /a z=14-mm,z/=12,y=yy+4800-z,m=mm+12*z-3,j=153*m+2
 set /a j=j/5+dd+y*365+y/4-y/100+y/400-2472633
 endlocal&set %4=%j%&goto :EOF

 :DaysToDate %days% yy mm dd
 setlocal ENABLEEXTENSIONS
 set /a a=%1+2472632,b=4*a+3,b/=146097,c=-b*146097,c/=4,c+=a
 set /a d=4*c+3,d/=1461,e=-1461*d,e/=4,e+=c,m=5*e+2,m/=153,dd=153*m+2,dd/=5
 set /a dd=-dd+e+1,mm=-m/10,mm*=12,mm+=m+3,yy=b*100+d-4800+m/10
 (if %mm% LSS 10 set mm=0%mm%)&(if %dd% LSS 10 set dd=0%dd%)
 endlocal&set %2=%yy%&set %3=%mm%&set %4=%dd%&goto :EOF
复制代码

Batcher

请举例说明你的测试数据是什么，希望得到的结果是什么，实际得到的结果是什么？

cbnuisve

回复 2# Batcher


    假设把当前日期修改为2016年1月1日 ，计算出的当前日期七天前的日期是20161225 （echo %yyyy%%DstMonth%%DstDay%\）面不是20151225

flyinnet9

改了以前写的程序，想前几天应该都可以（28天？？），测试后结果说一下
闰年判断有误，已改正

@echo off
setlocal enabledelayedexpansion
set daysago=7
set year=%date:~0,4%
set month=%date:~5,2%
set day=%date:~8,2%
if %day% gtr %daysago% goto normal
if %month%==03 goto february
if %month%==01 goto aty
for %%i in (05 07 10 12) do if %month%==%%i goto abortion
for %%i in (02 04 06 08 09 11 ) do if %month%==%%i goto monthly

:abortion
set /a day=30+!day!
if %month:~0,1%==0 set /a month=%month:~1%
set /a month=!month!-1
if !month! lss 10 set month=0!month!
goto normal

:monthly
set /a day=31+!day!
if %month:~0,1%==0 set /a month=%month:~1%
set /a month=!month!-1
if !month! lss 10 set month=0!month!
goto normal

:february
set month=02
if %year:~2,4%==00 (set /a yy=%year%%%400) else (set /a yy=%year%%%4)
if %yy%==0 (set /a day=29+!day!) else (set /a day=28+!day!)
goto normal

:aty
set /a day=31+!day!
set month=12
set /a year=%year%-1
goto normal

:normal
set /a Yourday=!year!!month!!day!-%daysago%
echo Today is %date:~0,4%%date:~5,2%%date:~8,2%
echo Yourday is %Yourday%
pause
复制代码

DAIC

怀疑是你的系统里面%date%格式有问题导致%date:~0,4% %date:~5,2% %date:~8,2%没有取到正确的值，把@echo off删掉重新执行一遍，完整的执行过程发出来看看。

回家路上

回复 1# cbnuisve
http://www.bathome.net/viewthread.php?tid=17079&highlight=%C7%B0%D2%BB%CC%EC

cbnuisve

回复 4# flyinnet9
非常感谢你。你这批处理解决了我之前哪跨年的问题，但是又有个新问题，当日期是2016年3月1日时，获取前七天的日期会是20160251而不是正确的 20160223

cbnuisve

回复 5# DAIC

C:\Users\user\Desktop>setlocal enabledelayedexpansion

C:\Users\user\Desktop>set DaysAgo=7

C:\Users\user\Desktop>call :DateToDays 2016 01 01 PassDays

C:\Users\user\Desktop>setlocal ENABLEEXTENSIONS

C:\Users\user\Desktop>set yy=2016  & set mm=01  & set dd=01

C:\Users\user\Desktop>if 12016 LSS 200 if 12016 LSS 170 (set yy=202016 )  else (set yy=192016 )

C:\Users\user\Desktop>set /a dd=10001%100,mm=10001%100

C:\Users\user\Desktop>set /a z=14-mm,z/=12,y=yy+4800-z,m=mm+12*z-3,j=153*m+2

C:\Users\user\Desktop>set /a j=j/5+dd+y*365+y/4-y/100+y/400-2472633

C:\Users\user\Desktop>endlocal & set PassDays=16801  & goto :EOF

C:\Users\user\Desktop>set /a PassDays-=7

C:\Users\user\Desktop>call :DaysToDate 16794 DstYear DstMonth DstDay

C:\Users\user\Desktop>setlocal ENABLEEXTENSIONS

C:\Users\user\Desktop>set /a a=16794+2472632,b=4*a+3,b/=146097,c=-b*146097,c/=4,c+=a

C:\Users\user\Desktop>set /a d=4*c+3,d/=1461,e=-1461*d,e/=4,e+=c,m=5*e+2,m/=153,dd=153*m+2,dd/=5

C:\Users\user\Desktop>set /a dd=-dd+e+1,mm=-m/10,mm*=12,mm+=m+3,yy=b*100+d-4800+m/10

C:\Users\user\Desktop>(if 12 LSS 10 set mm=012 )  & (if 25 LSS 10 set dd=025 )

C:\Users\user\Desktop>endlocal & set DstYear=2015  & set DstMonth=12  & set DstDay=25  & goto :EOF

C:\Users\user\Desktop>set "yyyy=2016"

C:\Users\user\Desktop>echo 20161225\
20161225\

C:\Users\user\Desktop>pause
复制代码

cbnuisve

回复 6# 回家路上
谢谢，看了好久还是没看明白。能否解释一下它是怎么运行的吗？如果我要获取七天前的日期要怎么做修改呢？

@echo off & setlocal enabledelayedexpansion

call :yesterday yesterday
echo %yesterday%



:yesterday
for /f "tokens=2*" %%a in ('reg query "HKCU\Control Panel\International" /v sShortDate^|find/i"sSh"') do (
  >nul reg add "HKCU\Control Panel\International" /v sShortDate /t REG_SZ /d "yyyyMMdd" /f
  set /a "y=!date:~0,4!,m=1!date:~4,2!-100,d=1!date:~-2!-101"
  setlocal disabledelayedexpansion
  set /a "m-=!d,y-=!m,d+=!d*(31-(!(m-4)|!(m-6)|!(m-9)|!(m-11))-!(m-2)*(3-(!(y%%4)&!!(y%%100)|!(y%%400)))),m+=!m*12"
  set /a "m+=100,d+=100"
  >nul reg add "HKCU\Control Panel\International" /v sShortDate /t REG_SZ /d "%%~b" /f
)
endlocal & set "%1=%y%%m:~-2%%d:~-2%" & exit /b
复制代码

DAIC

回复 8# cbnuisve


从第35行可以看到函数正确计算出了年月日 set DstYear=2015  & set DstMonth=12  & set DstDay=25
顶楼的代码错误在第9行 echo %yyyy%%DstMonth%%DstDay% 你不应该手工设置这个 yyyy
应该使用 echo %DstYear%%DstMonth%%DstDay%

cbnuisve

回复 10# DAIC

谢谢，终于解决这问题了。

回家路上

改了一些，前N天的（还不能超过一个月）。

@echo off
:: 前n天
set pre=3
::今天
set td=%date%
::如果今天是2016-03-01
set td=2016-03-01
echo;%td%
echo;==========================
set /a "y=%td:~0,4%,m=1%td:~5,2%-100,d=1%td:~8,2%-100-%pre%"
echo;%y%
echo;%m%
echo;%d%
::这之前就是能把 y m d 各种截取得正确，就ok了
echo;==========================
set /a "m-=!(%d:~1%+%d%),y-=!m,d+=!(%d:~1%+%d%)*(31-(!(m-4)|!(m-6)|!(m-9)|!(m-11))-!(m-2)*(3-(!(y%%4)&!!(y%%100)|!(y%%400)))),m+=!m*12"
echo;%y%
echo;%m%
echo;%d%
pause & exit /b
复制代码

超过一个月的话，你可以试试搞一下。O(∩_∩)O~


论坛里也有其他计算时间的地儿，可以看一下
http://bbs.bathome.net/viewthrea ... e%3D1&frombbs=1

cbnuisve

回复 12# 回家路上


    谢谢你，我的问题已经解决了。