[文本处理] 【已解决】210个雷同的BAT代码如何合并简化

思想之翼

有两组BAT代码需要合并简化：

1、第一组210个BAT如何合并简化？
@echo off
setlocal enabledelayedexpansion
for /f "delims=" %%i in ('dir /b /s /a-d "C:\温度\001\时间\地点*.txt"') do (
    for /f "delims=-" %%j in ("%%~nxi") do (
        set NewName=%%j.txt
        set NewName=!NewName:~2!
    )
    ren "%%i" "!NewName!"
)

@echo off
setlocal enabledelayedexpansion
for /f "delims=" %%i in ('dir /b /s /a-d "C:\温度\002\时间\地点*.txt"') do (
    for /f "delims=-" %%j in ("%%~nxi") do (
        set NewName=%%j.txt
        set NewName=!NewName:~2!
    )
    ren "%%i" "!NewName!"
)

......

@echo off
setlocal enabledelayedexpansion
for /f "delims=" %%i in ('dir /b /s /a-d "C:\温度\210\时间\地点*.txt"') do (
    for /f "delims=-" %%j in ("%%~nxi") do (
        set NewName=%%j.txt
        set NewName=!NewName:~2!
    )
    ren "%%i" "!NewName!"
)

2、第二组210个BAT 如何合并简化？
@echo off&setlocal enabledelayedexpansion
set 文件数=100
for /l %%a in (1,1,%文件数%) do (
    for /f "delims=" %%i in (C:/湿度/001/地点/%%a.txt) do (
        set /a n+=1
        for %%a in (!n!) do set "#%%a=!#%%a! %%i"
    )
    set /a m=n,n=0
)
(for /l %%a in (1,1,%m%) do echo,!#%%a:~1!)>C:/湿度-文件1/001.txt

@echo off&setlocal enabledelayedexpansion
set 文件数=100
for /l %%a in (1,1,%文件数%) do (
    for /f "delims=" %%i in (C:/湿度/002/地点/%%a.txt) do (
        set /a n+=1
        for %%a in (!n!) do set "#%%a=!#%%a! %%i"
    )
    set /a m=n,n=0
)
(for /l %%a in (1,1,%m%) do echo,!#%%a:~1!)>C:/湿度-文件1/002.txt

......

@echo off&setlocal enabledelayedexpansion
set 文件数=100
for /l %%a in (1,1,%文件数%) do (
    for /f "delims=" %%i in (C:/湿度/210/地点/%%a.txt) do (
        set /a n+=1
        for %%a in (!n!) do set "#%%a=!#%%a! %%i"
    )
    set /a m=n,n=0
)
(for /l %%a in (1,1,%m%) do echo,!#%%a:~1!)>C:/湿度-文件1/210.txt

恳望得到帮助。

DAIC

@echo off
setlocal enabledelayedexpansion
for /l %%a in (1001,1,1210) do (
    set n=%%a
    for /f "delims=" %%i in ('dir /b /s /a-d "C:\温度\!n:~1!\时间\地点*.txt"') do (
        for /f "delims=-" %%j in ("%%~nxi") do (
            set NewName=%%j.txt
            set NewName=!NewName:~2!
        )
        ren "%%i" "!NewName!"
    )
)
复制代码

思想之翼

回复 2# DAIC

感谢！
上帖还有第二问：带输出路径的若干代码，如何合并简化？

2、以下210个BAT 如何合并简化？
@echo off&setlocal enabledelayedexpansion
set 文件数=100
for /l %%a in (1,1,%文件数%) do (
    for /f "delims=" %%i in (C:/湿度/001/地点/%%a.txt) do (
        set /a n+=1
        for %%a in (!n!) do set "#%%a=!#%%a! %%i"
    )
    set /a m=n,n=0
)
(for /l %%a in (1,1,%m%) do echo,!#%%a:~1!)>C:/湿度-文件1/001.txt



@echo off&setlocal enabledelayedexpansion
set 文件数=100
for /l %%a in (1,1,%文件数%) do (
    for /f "delims=" %%i in (C:/湿度/002/地点/%%a.txt) do (
        set /a n+=1
        for %%a in (!n!) do set "#%%a=!#%%a! %%i"
    )
    set /a m=n,n=0
)
(for /l %%a in (1,1,%m%) do echo,!#%%a:~1!)>C:/湿度-文件1/002.txt

.
.....


@echo off&setlocal enabledelayedexpansion
set 文件数=100
for /l %%a in (1,1,%文件数%) do (
    for /f "delims=" %%i in (C:/湿度/210/地点/%%a.txt) do (
        set /a n+=1
        for %%a in (!n!) do set "#%%a=!#%%a! %%i"
    )
    set /a m=n,n=0
)
(for /l %%a in (1,1,%m%) do echo,!#%%a:~1!)>C:/湿度-文件1/210.txt

DAIC

回复 3# 思想之翼


    2楼那个代码你能看懂吗？照那个方法修改就行了

思想之翼

回复 4# DAIC
有些细节不会处理，照着扩展运用发现有错误。还望您给予帮助！

DAIC

回复 5# 思想之翼


    把你尝试修改过的代码发出来我看看

思想之翼

回复 6# DAIC

烦请您给予斧正。

@echo off
setlocal enabledelayedexpansion
for /l %%a in (1001,1,1210) do (
    set n=%%a
    set x=!n:~-3!
    set y=!n:~-3!
    call :Copy_File !x! !y!
)
goto :eof

:Copy_File
set 文件数=100
for /l %%a in (1,1,%文件数%) do (
    for /f "delims=" %%i in (C:/湿度/ %1/地点/%%a.txt) do (
        set /a n+=1
        for %%a in (!n!) do set "#%%a=!#%%a! %%i"
    )
    set /a m=n,n=0
)
(for /l %%a in (1,1,%m%) do echo,!#%%a:~1!)>C:/湿度-文件1/ %2.txt
    goto :eof
)

DAIC

回复 7# 思想之翼


    把%1左边的空格删掉

思想之翼

回复 8# DAIC

实际测试，得到的结果是错误的。不知道错在哪里。

DAIC

回复 9# 思想之翼


    具体描述一下错误是什么样的

思想之翼

回复 10# DAIC

001文件夹处理后少第一个文本的数据，002文件夹开始，处理后的结果无端多出很多数据。

DAIC

@echo off
setlocal enabledelayedexpansion
set filenum=100
for /l %%x in (1001,1,1210) do (
    set y=%%x
    for /l %%a in (1,1,%filenum%) do (
        for /f "delims=" %%i in (C:\湿度\!y:~1!\地点\%%a.txt) do (
            set /a n+=1
            for %%a in (!n!) do set "#%%a=!#%%a! %%i"
        )
        set /a m=n,n=0
    )
    (for /l %%a in (1,1,!m!) do echo,!#%%a:~1!)>C:\湿度-文件1\!y:~1!.txt
)
复制代码

apang

回复 12# DAIC


    好像 #%%a 变量需要清空吧，否则其值可能会一直累加

思想之翼

回复 12# DAIC

谢谢！经测试，存在如下问题：
001文件夹处理正确
002文件夹处理后，是001文件夹处理+002文件夹处理
003文件夹处理后，是001文件夹处理+002文件夹处理+003文件夹处理
以此类推

xxpinqz

@echo off
set filenum=100
for /l %%x in (1001,1,1210) do (
    set y=%%x
    setlocal enabledelayedexpansion
    for /l %%a in (1,1,%filenum%) do (
        for /f "delims=" %%i in (C:\湿度\!y:~1!\地点\%%a.txt) do (
            set /a n+=1
            for %%a in (!n!) do set "#%%a=!#%%a! %%i"
        )
        set /a m=n,n=0
    )
    (for /l %%a in (1,1,!m!) do echo,!#%%a:~1!)>C:\湿度-文件1\!y:~1!.txt
    endlocal
)
复制代码

这样试试