[文本处理] [已解决]大神帮忙做个批处理替换前十五行指定字符串

andywf

我有多个后缀为NC的文本，想把H01改成H00(只存在前十五行)并把以原文本名字输出，我自己做的是查找全文再替换H01，查找速度度慢，想大佬们帮帮忙

LJY4.0

第三方:sed.exe
下载链接:http://bcn.bathome.net/tool/4.8/sed.exe

@echo off
for /f 'delims=" %%a in ('dir /s/b/a-d *.NC') do (
sed -i s/H01/H00/g %%a
)
复制代码

andywf

回复 2# LJY4.0


    这样是替换全部吗？我只想限定于(前十五行)，谢谢你了

andywf

@echo off
for /f "delims=" %%i in ('dir /s/b *.NC') do (
for /f "delims=" %%a in ('type "%%~fi"') do (
set "foo=%%a"
call,set foo=%%foo:H01=H00%%
call,echo/%%foo%%>>"%%~fi._"
)
move "%%~fi._" "%%~fi"
)
exit

这样会搜索全文再替换，我只想限于前面15行内搜索，能否加个限制条件

Batcher

回复 3# andywf


2楼代码第3行改成这样试试

sed -i "1,15s/H01/H00/g" "%%a"
复制代码

Batcher

回复 4# andywf

@echo off
cd /d "%~dp0"
setlocal enabledelayedexpansion
for /f "delims=" %%i in ('dir /b /s /a-d *.NC') do (
    set "n=0"
    (for /f "delims=" %%a in ('type "%%i"') do (
        set /a n+=1
        if !n! leq 15 (
            set "foo=%%a"
            set "foo=!foo:H01=H00!"
            echo,!foo!
        )
    ))>"%%~fi._"
    move "%%~fi._" "%%~fi"
)
复制代码

andywf

回复 6# Batcher


    感谢大佬

andywf

回复 6# Batcher


    谢谢大佬，但是会把15行后面的内容删除

LJY4.0

    @echo off
    cd /d "%~dp0"
    setlocal enabledelayedexpansion
    for /f "delims=" %%i in ('dir /b /s /a-d *.NC') do (
        set "n=0"
        (for /f "delims=" %%a in ('type "%%i"') do (
            set /a n+=1
            if !n! leq 15 (
                set "foo=%%a"
                set "foo=!foo:H01=H00!"
                echo,!foo!
            )
        ))>"%%~fi._"
       more +15 %%i>>%%~fi._
        move "%%~fi._" "%%~fi"
    )
复制代码

回复 8# andywf

andywf

回复 9# LJY4.0


    谢谢大佬，试了下，会把全部内容删除😂

flashercs

@echo off
cd /d "%~dp0"
setlocal enabledelayedexpansion
for /f "delims=" %%i in ('dir /b /s /a-d *.NC') do (
    set "n=0"
    (for /f "delims=" %%a in ('type "%%i"') do (
        set /a n+=1
        if !n! leq 15 (
            set "foo=%%a"
            set "foo=!foo:H01=H00!"
            echo,!foo!
        ) else echo,%%a
    ))>"%%~fi._"
    move "%%~fi._" "%%~fi"
)
复制代码

andywf

回复 11# flashercs


    十分感谢大神的付出，能否再加多删除几行的命令M204 H1 D1,M24,M26,G43 H1，这几行是独立成行，命令是先删除这几行(存在前十五行内)，然后再替换H01成H00(也是前15行内)，以原来文件名输出

andywf

@echo off
setlocal enabledelayedexpansion
set "v1=M204 H1 D1"
set "v2=G43 H1"
set "v3=M24"
set "v4=M26"
for %%a in (*.ptp) do (
findstr /i /v /c:"!v1!" "%%~a">new.tmp
findstr /i /v /c:"!v2!" new.tmp>"%%~a"
findstr /i /v /c:"!v3!" "%%~a">new.tmp
findstr /i /v /c:"!v4!" new.tmp>"%%~a"
del new.tmp)
这样的代码批处理很快，然后再加上替换HO1成H00(限于前十五行)

andywf

回复 11# flashercs


    大神，因为有些文件比大大，替换速度很慢，有没有什么办法优化

qixiaobin0715

最好能在网盘上发几个大文件，有利于代码测试，看看能否有人帮你优化。