[文本处理] 批处理怎样替换包含空格的字符串？

FIR1987

setlocal ENABLEDELAYEDEXPANSION
for /f  "delims=" %%i in ( c:\bat3.txt ) do (
 set var=%%i
 set var=!var:Timing, TOTAL TIME (CREATE CUBE)=Timing!
 echo !var! >> c:\newbat3.txt
 ) 
PAUSE
复制代码

用这段代码替换 如果!var：a=b! 是这样的字母好使，但是如果中间有空格 就不好用了
其实我想把Timing, TOTAL TIME (CREATE CUBE)整个在文本中删除。多谢

CrLf

感觉是)号的问题，试试改成：
set "var=!var:Timing, TOTAL TIME (CREATE CUBE)=Timing!"

applba

set "str1=Timing, TOTAL TIME (CREATE CUBE)"
set "var=!var:str1="

hanyeguxing

“想把Timing, TOTAL TIME (CREATE CUBE)整个在文本中删除”为什么还要在=后指定Timing呢？

@echo off&setlocal ENABLEDELAYEDEXPANSION
(for /f  "delims=" %%i in (c:\bat3.txt) do (
    set "var=%%i"
    set "var=!var:Timing, TOTAL TIME (CREATE CUBE)=!"
    echo;!var!
))> c:\newbat3.txt
复制代码

FIR1987

4# hanyeguxing

因为我觉得不能没东西 我一直没试出来 呵呵 明天再试试 谢谢版主

FIR1987

2# zm900612
憨豆 你是说我的括号是中文吗 应该不是这个问题吧 我是从日志里截取的啊

FIR1987

感觉是)号的问题，试试改成：
set "var=!var:Timing, TOTAL TIME (CREATE CUBE)=Timing!"
zm900612 发表于 2011-4-27 14:18

憨豆 版主的都可以

憨豆为啥要加双引号 是因为括号吗

hanyeguxing

你在1楼中发的两个都是英文的 Timing, TOTAL TIME (CREATE CUBE)
(（前面是英文后面是中文

CrLf

因为()是语块的分隔符，若在语句内含有不应该用于划分语句的)而未转义或加双引号，常会被错误划分：

setlocal ENABLEDELAYEDEXPANSION
for /f  "delims=" %%i in ( c:\bat3.txt ) do 【(
set var=%%i
set var=!var:Timing, TOTAL TIME (CREATE CUBE)】=Timing!
echo !var! >> c:\newbat3.txt
) 
PAUSE
复制代码

Hello123World

9# zm900612
【】这中文大括号是什么意思？

hanyeguxing

只是用来提示命令解释器将哪两个括号作为一对来划分，不是代码的内容

yjstone

这样就可以了：

    setlocal ENABLEDELAYEDEXPANSION
   for /f  "delims=" %%i in ( c:\bat3.txt ) do (
    set var=%%i
   set var=!var:Timing, TOTAL TIME ^(CREATE CUBE^)=Timing!
    echo !var! >> c:\newbat3.txt
    )
   PAUSE
复制代码

yjstone

还可以更简洁一些：

 for /f  "delims=" %%i in ( c:\bat3.txt ) do (
   set var=%%i
   call echo %%var:Timing, TOTAL TIME ^(CREATE CUBE^)=Timing%%>>c:\newbat3.txt
   )
   PAUSE
复制代码