[日期时间] 批处理如何获取当前日期的后一天日期（即明天的日期）？

eddyann

各位大神过年好   
如题 如何获取系统时间 后一天的时间  比如今天2月9日  我想获取 明天的日期 就是2月10日   
获取到的时间格式 是   X月X日 星期X
举例说明：今天是2月9日   需要获取 2月10日 星期三    星期后面跟的是中文数字


谢谢大神

hlzj88

这里有求上一天的，你修改代码加一天
http://zhidao.baidu.com/link?url ... jJGQjkG0nE3sLBpIv-q

ivor

我的win7 date格式为“2016/02/09 周二”测试正常，
楼主自行修改 周一到周天的常量吧

@echo off
rem 计算指定天数之前的日期
set DaysAgo=-1
rem 假设系统日期的格式为yyyy-mm-dd
call :DateToDays %date:~0,4% %date:~5,2% %date:~8,2% PassDays
set /a PassDays-=%DaysAgo%
call :DaysToDate %PassDays% DstYear DstMonth DstDay
set DstDate=%DstYear%-%DstMonth%-%DstDay%
call :weekdays %DaysAgo% 
echo %DaysAgo%天的日期是%DstDate% %week%
pause
goto :eof

:DateToDays %yy% %mm% %dd% days
setlocal ENABLEEXTENSIONS
set yy=%1&set mm=%2&set dd=%3
if 1%yy% LSS 200 if 1%yy% LSS 170 (set yy=20%yy%) else (set yy=19%yy%)
set /a dd=100%dd%%%100,mm=100%mm%%%100
set /a z=14-mm,z/=12,y=yy+4800-z,m=mm+12*z-3,j=153*m+2
set /a j=j/5+dd+y*365+y/4-y/100+y/400-2472633
endlocal&set %4=%j%&goto :EOF

:DaysToDate %days% yy mm dd
setlocal ENABLEEXTENSIONS
set /a a=%1+2472632,b=4*a+3,b/=146097,c=-b*146097,c/=4,c+=a
set /a d=4*c+3,d/=1461,e=-1461*d,e/=4,e+=c,m=5*e+2,m/=153,dd=153*m+2,dd/=5
set /a dd=-dd+e+1,mm=-m/10,mm*=12,mm+=m+3,yy=b*100+d-4800+m/10
(if %mm% LSS 10 set mm=0%mm%)&(if %dd% LSS 10 set dd=0%dd%)
endlocal&set %2=%yy%&set %3=%mm%&set %4=%dd%&goto :EOF

:weekdays DaysAgo
set 周一=1
set 周二=2
set 周三=3
set 周四=4
set 周五=5
set 周六=6
set 周日=7
set /a a=%date:~11,4%-%1%%7
for /f "tokens=1-7" %%1 in ("周一 周二 周三 周四 周五 周六 周日") do (
	set week=%%%a%
)
goto :EOF
复制代码

pcl_test

@echo off
for /f "delims=" %%a in ('mshta VBScript:Execute("NewDate=DateAdd(""d"",1,date):FmtDate=month(NewDate)&""月""&day(NewDate)&""日""&chr(32)&weekdayname(weekday(NewDate)):CreateObject(""Scripting.FileSystemObject"").GetStandardStream(1).Write FmtDate:close"^)') do echo;%%a
pause
复制代码

WHY

回复 1# eddyann


    卤猪，这个帖子你怎么看？http://www.bathome.net/thread-39317-1-1.html

WHY

powershell -c "(get-Date).AddDays(1).ToString('M月d日 dddd')"