[文本处理] 【已解决】批处理如何提取文件内容重命名原文件？

meiszp

提取目录下1-1.txt文件第4行（不包含空白行）的字符串101，将1-1.txt命名为101.txt

1-1.txt前几行数据如下：

BLOWER Co.                                                            
  
***********************************************************************
    ANALABC OF  SEALS      
    101                                                                                                                                    
***********************************************************************
  
  ***********************************************

@echo off
setlocal enabledelayedexpansion 
set /a count=0
for /f "tokens=1 delims= " %%i in (1-1.txt) do (
	set /a count+=1
    	if !count! == 4  ren 1-1.txt !i!.txt

)
endlocal 
pause
复制代码

写个简单代码不成功。
之前成功打印，发现"tokens=1 delims= "非空行计数，"tokens=1 delims="空行也计数

qixiaobin0715

@echo off
setlocal enabledelayedexpansion 
for /f "tokens=1*" %%i in (1-1.txt) do (
    set /a n+=1
    if !n! equ 4 set NFN=%%i
)
ren "1-1.txt" "!NFN!.txt"
pause
复制代码

aloha20200628

回复 1# meiszp

采用 for 循环读取文本文件会自动剔除空行，因此直接用 set/a n+=1 判断会错行，建议采用skip参数直接跳到目标行n-1。
即便如此，skip之后仍不能及时退出循环而导致反复空读，尤其是当其后有较多文本行时，故此法效率就很低...
建议用以下代码可明显提效，原因是其一能实现及时退出for循环，其二是skip参数会计入空行，其实在楼主前帖 http://www.bathome.net/viewthrea ... ghlight=&page=1 14楼代码中已用过此法...

(call :getN "1-1.txt" 5 nF)
ren "1-1.txt" "%nF%.txt"
:getN
   if %~2 equ 1 for /f "usebackq delims= " %%a in ("%~1") do (set "%~3=%%a"&exit/b)
   set/a "n=%~2-1"
   for /f "usebackq skip=%n% tokens=1 delims= " %%a in ("%~1") do (set "%~3=%%a"&exit/b)
   exit/b
复制代码

77七

"tokens=1 delims="空行也计数

楼主的文本第二行含有空格，不算空行（写代码可以使用其它文本编辑工具，把显示空格打开，就一目了然...）

@echo off
for /f "delims=" %%i in ('dir /b /a-d *.txt') do (
	call :1 "%%i"
)
pause & exit

	:1
	(for /l %%l in (1,1,5) do (
		set /p str=
	))<"%~1"
	for /f "tokens=*" %%a in ("%str%") do (
		ren "%~1" "%%~nxa%~x1"
	)
	exit /b
复制代码

qixiaobin0715

使用临时文件+“伪循环”也可：

@echo off
findstr /n .* 1-1.txt|findstr /b "5:">temp
for /f "tokens=2 delims=:	 " %%i in (temp) do ren "1-1.txt" "%%i.txt"
del temp
复制代码

meiszp

回复 2# qixiaobin0715
谢谢热心回复

meiszp

回复 3# aloha20200628

谢谢热心回复，代码试验不成功。试验文本已上传
链接: https://pan.baidu.com/s/1WIh9ZwUnGojdq-bJ9JfA4Q?pwd=mmjr

meiszp

回复 4# 77七
谢谢热心回复，代码试验不成功，提示“文件名、目录名或卷标语法不正确”。试验文本已上传
链接: https://pan.baidu.com/s/1WIh9ZwUnGojdq-bJ9JfA4Q?pwd=mmjr

meiszp

回复 5# qixiaobin0715

谢谢热心回复。

77七

回复 8# meiszp


  

 SHAANXI BLOWER Co.                                                             
  
 ***********************************************************************
    ANALYSIS OF LABYRINTH SEALS       SEAL3D
    101								                                                                     
 ***********************************************************************
复制代码

论坛输入框右上角点高级模式，点代码，把代码粘贴进去，可以保留文本的制表符。
4楼代码在第10行下增加一行

	set "str=%str:	=%"
复制代码

aloha20200628

回复 7# meiszp

以下代码用楼主提供的示例文件测试通过...

@echo off
(call :getN "1-1.txt" 5 nF)
ren "1-1.txt" "%nF%.txt"
exit/b
:getN
	if %~2 equ 1 for /f "usebackq delims= " %%s in ("%~1") do (set "%~3=%%s"&exit/b)
	set/a "n=%~2-1"
	for /f "usebackq skip=%n% delims= " %%s in ("%~1") do (set "%~3=%%s"&exit/b)
	exit/b
复制代码

meiszp

回复 11# aloha20200628
第五行，101前面是空格，后面是制表符，所以代码没有完美解决。
delims分隔符用制表符和空格可以解决。

aloha20200628

回复 12# meiszp

很棒！调整getN子过程中的 skip/tokens/delims/... 切割器，完美实现个性化需求
纯P代码中类似getN方法的主要优势就是能 “及时退出循环”，在此前提下没有多余的系统开销，一步到位，尤其是从大体量文本文件中提取部分数据时其功效更加明显...

qixiaobin0715

回复 12# meiszp
如果分隔符只有制表符和空格，delims参数省略即可。