[文件操作] [已解决]BAT批量去掉文件名中的括号和括号里的内容

liziyunabcd

文件夹里有很多个DOC文件。
文件名如下：
我是一个小白1(我是小白三42342号fwsffq)
我是一个小白2(我是小白三2342号erqrqer)
我是一个小白3(我是小白三rqr2号rfdsh)
我是一个小白4(我是小白三req号rweqrq)

请教大神：如何批量把括号里的内容和括号一起删除。

netdzb

ren 我是一个小白？(*).doc 我是一个小白？.doc
这样可以吗？

xp3000

得用这个工具，放入C:\Windows\System32
或者放入需要处理的DOC或DOCX文件夹里面
http://bcn.bathome.net/tool/ren2.exe

@echo off
@for /f "delims=" %%i in ('dir /b *.DOC *.DOCX') do ( 
ren2 -f "(.*)\(.*\).*%%~xi" "$1%%~xi"
)
pause
复制代码

went

for /f "tokens=1* delims=(" %%i in ('dir /b "*(*).doc"') do rename "%%i(%%j" "%%i.doc"
复制代码

liziyunabcd

回复 3# xp3000 感谢大佬，完全可行！！谢谢技术大佬

liziyunabcd

回复 4# went


    完美！！！谢谢大神！！！
太完美了！！

qixiaobin0715

回复 4# went

改造一下，这样是否可以去除文件名任意位置的括号？

for /f "tokens=1,2* delims=()" %%i in ('dir /b "*.doc"') do ren "%%i(%%j)%%k" "%%i%%k"
复制代码

qixiaobin0715

括号在最前面好像也不行。

went

回复 8# qixiaobin0715

任意位置

@echo off
for /f "tokens=1* delims=(" %%i in ('dir /b "*(*)*.txt"') do (
	if "%%j"=="" ( set "a=%%i" & set "pre=" ) else ( set "a=%%j" & set "pre=%%i" )
	call set "txt=%%pre%%(%%a%%"
	call set "a=%%a:*)=%%"
	call echo rename "%%txt%%" "%%pre%%%%a%%"
	call rename "%%txt%%" "%%pre%%%%a%%"
	echo -----
)
pause&exit
复制代码

qixiaobin0715

回复 9# went

很好用！！！

Batcher

回复 1# liziyunabcd

@echo off
setlocal enabledelayedexpansion
cd /d "%~dp0"
for /f "delims=" %%i in ('dir /b /a-d "*(*)*.doc"') do (
    set "str=%%~nxi"
    set "str1=!str:(= (!"
    set "str1=!str1:)=) !"
    for %%j in (!str1!) do (
        set "str2=%%j"
        if "!str2:~,1!"=="(" (
            set "str=!str:%%j=!"
        )
    )
    ren "%%i" "!str!"
)
复制代码

Batcher

@echo off
setlocal enabledelayedexpansion
cd /d "%~dp0"
for /f "tokens=1* delims=(" %%i in ('dir /b /a-d "*(*)*.doc"') do (
	if "%%j"=="" (
        set "FileRight=%%i"
        set "FileLeft="
    ) else (
        set "FileRight=%%j"
        set "FileLeft=%%i"
    )
    set "OldName=!FileLeft!(!FileRight!"
    set "FileRight=!FileRight:*)=!"
    set "NewName=!FileLeft!!FileRight!"
    ren "!OldName!" "!NewName!"
)
复制代码