[文件操作] [已解决]批处理如何把多个jpg全部copy到d盘0000目录下？

ygqiang

xx盘DCIM目录下有不同的子目录，里面有很多*.jpg文件，如何全部copy到d盘yy目录下？
只想找到所有jpg文件，全部复制到目标目录下面。

md "d:\%date:~0,4%-%date:~5,2%-%date:~8,2%"
setlocal enabledelayedexpansion
for /f %%i in ('dir /b/s e:\*.jpg') do (copy "%%~fi" "d:\%date:~0,4%-%date:~5,2%-%date:~8,2%"  /y
del /q "%%~fi")
for /f %%i in ('dir /b/s e:\*.mov') do (copy "%%~fi" "d:\%date:~0,4%-%date:~5,2%-%date:~8,2%"  /y
del /q "%%~fi")
for /f %%i in ('dir /b/s e:\*.avi') do (copy "%%~fi" "d:\%date:~0,4%-%date:~5,2%-%date:~8,2%"  /y
del /q "%%~fi")
for /f %%i in ('dir /b/s e:\*.mp4') do (copy "%%~fi" "d:\%date:~0,4%-%date:~5,2%-%date:~8,2%"  /y
del /q "%%~fi")
for /f %%i in ('dir /b/s e:\*.mts') do (copy "%%~fi" "d:\%date:~0,4%-%date:~5,2%-%date:~8,2%"  /-y
del /q "%%~fi")
pause
复制代码

以上代码运行正常。

for %%a in (e f g h i j k l m n o p q r s t) do (

if exist "%%a:\DCIM" (md "d:\%date:~0,4%-%date:~5,2%-%date:~8,2%"
setlocal enabledelayedexpansion
for /f %%i in ('dir /b/s %%a:\*.jpg') do (copy "%%~fi" "d:\%date:~0,4%-%date:~5,2%-%date:~8,2%"  /y
del /q "%%~fi")
for /f %%i in ('dir /b/s %%a:\*.mov') do (copy "%%~fi" "d:\%date:~0,4%-%date:~5,2%-%date:~8,2%"  /y
del /q "%%~fi")
for /f %%i in ('dir /b/s %%a:\*.avi') do (copy "%%~fi" "d:\%date:~0,4%-%date:~5,2%-%date:~8,2%"  /y
del /q "%%~fi")
for /f %%i in ('dir /b/s %%a:\*.mp4') do (copy "%%~fi" "d:\%date:~0,4%-%date:~5,2%-%date:~8,2%"  /y
del /q "%%~fi")
for /f %%i in ('dir /b/s %%a:\*.mts') do (copy "%%~fi" "d:\%date:~0,4%-%date:~5,2%-%date:~8,2%"  /-y
del /q "%%~fi")

)
)
复制代码

更新下：这个代码，修改以后，可以正常运行了。

Batcher

@echo off
for %%a in (e f g h i j k l m n o p q r s t) do (
    if exist "%%a:\DCIM" (
        md "d:\%date:~0,4%-%date:~5,2%-%date:~8,2%"
        for %%b in (jpg mov avi mp4 mts) do (
            for /f %%i in ('dir /b /s /a-d %%a:\*.%%b') do (
                copy /y "%%~fi" "d:\%date:~0,4%-%date:~5,2%-%date:~8,2%"
                del /q "%%~fi"
            )
        )
    )
)
复制代码

ygqiang

最终代码如下：

————————————————————————————————————————————————————————————————
md "d:\%date:~0,4%-%date:~5,2%"
explorer "d:\%date:~0,4%-%date:~5,2%"

for %%a in (e f g h i j k l m n o p q r s t) do (
    if exist "%%a:\DCIM" (

        for %%b in (jpg arw crw cr2 nef rw2 orf raf dng x3f avi mov mp4 mts) do (
            for /f %%i in ('dir /b /s /a-d %%a:\DCIM\*.%%b') do (
                copy /y "%%~fi" "d:\%date:~0,4%-%date:~5,2%"
                del /q "%%~fi"
            )
        )

        for %%b in (mp4 mts) do (
            for /f %%i in ('dir /b /s /a-d %%a:\*.%%b') do (
                copy /y "%%~fi" "d:\%date:~0,4%-%date:~5,2%"
                del /q "%%~fi"
            )
        )

    )
)
————————————————————————————————————————————————————————————————
复制代码