[ 新手习题 9 ] 批处理交换歌曲与歌手

wxcute

可以是中文歌曲，也可以是英文歌曲。如果你想统一歌曲文件名，歌手都放前面或是都放后面。可能要进行如下操作，可是如果手工来改的话，要前面复制一下后面再复制一下，会很麻烦。
问题来了，拖一个文件到批处理图标上，自动对调歌手与歌曲名。

其中歌名可以由汉字、英语、数字组成，英文歌曲会有空格，但不含特殊符号；
歌手也可以是组合、艺名，也不含特殊符号；
中间用 “ - ” 连接，即（空格）-（空格）。

老狼 - 同桌的你.mp3　　　　　——>　　同桌的你 - 老狼.mp3
Mirror Mirror - M2M.mp3　　——>　　M2M - Mirror Mirror.mp3
复制代码

目的：学习参数的使用，可能用到 for，或是变量替换。

要求：歌曲与歌手对调，本题基本要求是能处理一个文件，当然你想多个一起交换也不反对；不考虑特殊字符。方法不限。

评分：代码可读性 1 分；
　　　首个新方法 6 分，第二个 5 分，依次类推，最少 2 分；
　　　一人可多种方法，新方法追加 3 分，已经出现过的方法追加 1 分。
=========================================
谢谢随风兄提醒，已添加说明。

[ 本帖最后由 wxcute 于 2008-12-17 19:32 编辑 ]

随风

是否应该说明一下文件名的规律？比如：歌手名和歌曲名是用－号割开的，文件名中是否有多个－号？

tireless

1、

@echo off & setlocal EnableDelayedExpansion
for %%A in (%*) do (
  for /f "tokens=1,* delims=-" %%a in ("%%~nA") do (
    set "L=%%a" & set "R=%%b"
    ren %%A "!R:~1! - !L:~,-1!.mp3"
  )
)
复制代码

2、

@echo off & setlocal EnableDelayedExpansion
for %%A in (%*) do (
  set str=%%~nA
  for /f "delims=\ tokens=1,2" %%a in ("!str: - =\!") do (
    ren %%A "%%b - %%a.mp3"
  )
)
复制代码

[ 本帖最后由 tireless 于 2008-12-18 08:05 编辑 ]

httydolphin

好的    看完   OK    批处理下吧

yuhaodong

@title 更名
@echo off
color 1f
setlocal EnableDelayedExpansion
:kaishi
set /p dir=请输入路径:
if exist %dir%\*.mp3 (for %%i in (%dir%\*.mp3) do (echo %%i >>tmp.txt)) else (echo 路径错误或*.mp3不存在&goto kaishi)
for /f "delims=\-. tokens=1,2,3,4,5,6,7,8,9" %%a in (tmp.txt) do echo %%a %%b %%c %%d %%e %%f %%g %%h %%i %%j %%k %%l %%m %%n %%o %%p %%q %%r %%s %%t %%u %%v %%w %%x %%y %%z >>1.txt
for /f "delims=%%" %%a in (1.txt) do (echo %%a >>2.txt)
for /f "delims=," %%a in (2.txt) do (
set /a s=0
for %%i in (%%a) do set /a s=!s!+1
set /a s1=!s!-2
set /a s2=!s!-1
)
for /f "tokens=%s1%,%s2%" %%a in (2.txt) do (ren "%dir%\%%a - %%b.mp3" "%%b - %%a.mp3" 2>nul
ren "%dir%\%%a-%%b.mp3" "%%b-%%a.mp3" 2>nul
)
del 1.txt
del 2.txt
del tmp.txt
set /p a=文件名已经更改完毕<nul
pause
start %dir%
exit

yuhaodong

@title 更名
@echo off
color 1f
setlocal EnableDelayedExpansion
:kaishi
set /p dir=请输入路径:
if exist %dir%\*.mp3 (for %%i in (%dir%\*.mp3) do (echo %%i >>tmp.txt)) else (echo 路径错误或*.mp3不存在&goto kaishi)
for /f "delims=\-. tokens=1,2,3,4,5,6,7,8,9" %%a in (tmp.txt) do echo %%a %%b %%c %%d %%e %%f %%g %%h %%i %%j %%k %%l %%m %%n %%o %%p %%q %%r %%s %%t %%u %%v %%w %%x %%y %%z >>1.txt
for /f "delims=%%" %%a in (1.txt) do (echo %%a >>2.txt)
for /f "delims=," %%a in (2.txt) do (
set /a s=0
for %%i in (%%a) do set /a s=!s!+1
set /a s1=!s!-2
set /a s2=!s!-1
)
for /f "tokens=%s1%,%s2%" %%a in (2.txt) do (ren "%dir%\%%a - %%b.mp3" "%%b - %%a.mp3" 2>nul
ren "%dir%\%%a-%%b.mp3" "%%b-%%a.mp3" 2>nul
)
del 1.txt
del 2.txt
del tmp.txt
set /p a=文件名已经更改完毕<nul
pause
start %dir%
exit

yuhaodong

@title 更名
@echo off
color 1f
setlocal EnableDelayedExpansion
:kaishi
set /p dir=请输入路径格式: X:\..\.. 例如 c:\music)
if exist %dir%\*.mp3 (for %%i in (%dir%\*.mp3) do (echo %%i >>tmp.txt)) else (echo 路径错误或*.mp3不存在&goto kaishi)
for /f "delims=\-. tokens=1,2,3,4,5,6,7,8,9" %%a in (tmp.txt) do echo %%a %%b %%c %%d %%e %%f %%g %%h %%i %%j %%k %%l %%m %%n %%o %%p %%q %%r %%s %%t %%u %%v %%w %%x %%y %%z >>1.txt
for /f "delims=%%" %%a in (1.txt) do (echo %%a >>2.txt)
for /f "delims=," %%a in (2.txt) do (
set /a s=0
for %%i in (%%a) do set /a s=!s!+1
set /a s1=!s!-2
set /a s2=!s!-1

)
for /f "tokens=%s1%,%s2%" %%a in (2.txt) do (ren "%dir%\%%a - %%b.mp3" "%%b - %%a.mp3" 2>nul
ren "%dir%\%%a-%%b.mp3" "%%b-%%a.mp3" 2>nul
)
del 1.txt
del 2.txt
del tmp.txt
set /p a=文件名已经更改完毕<nul
pause
start %dir%
exit

leaparde

@echo off
title Replace the filename
color 1f
mode con:cols=80 lines=30
setlocal enabledelayedexpansion
::列出当前目录下所有文件及文件夹
dir /b>tmp
::findstr用来找出所有的mp3
for /f "tokens=*" %%a in ('findstr ".mp3" "tmp"') do (
   set str=%%a
::把文件名中的“空格-空格”替换成“-”
   set str=!str: - =-!
::歌曲名称和歌手互换
   for /f "tokens=1-3 delims=-." %%i in ("!str!") do (
      set name=%%i
      set music=%%j
      echo %%a  change to !music! - !name!.mp3
      rename "%%a" "!music! - !name!.mp3"
      )
)
echo.
echo 以上文件改名成功！
del /f /q tmp
pause>nul
复制代码

空格不太会处理，代码感觉有点繁了，期待高手指点指点啊!

[ 本帖最后由 leaparde 于 2008-12-26 16:33 编辑 ]

i520king

学习学习了

zgq0301

@echo off 
for %%i in (*.mp3) do (
     for /f "delims=-. tokens=1,2" %%a  in ("%%i") do (
          ren %%i  %%b-%%a.mp3
          )
  )
  pause>nul
复制代码

[ 本帖最后由 zgq0301 于 2009-11-13 13:17 编辑 ]

battab

回复 1# wxcute

@echo off
set name=%~nx1
for /f "tokens=1,2,3 delims=-." %%a in ("%name%") do set new_name=%%b - %%a.%%c
move /y %1 "C:\Documents and Settings\Administrator\桌面\%new_name%"
复制代码

注意:最后重命名成新名字的路径要给出到目标地址上，否则默认存在...\Administrator\下!

fcxk

@echo off
for /f "tokens=1-3* delims=-." %%i in (1.txt) do (
echo;%%j - %%i.%%k
)
pause

偷懒的方法

fcxk

@echo off
setlocal EnableDelayedExpansion
for %%i in (%*) do (
set vv=%%~nxi
for /f "tokens=1-3* delims=-." %%i in ('type "!vv%%i!"') do echo;%%j - %%i.%%k
  )
pause

拖放功能

437153

@echo off
for %%a in (%*) do (
	for /f "tokens=1,2,3 delims=-. " %%i in ("%%~nxa") do (
		ren "%%~nxa" "%%j - %%i.%%k"
	)
)
复制代码

437153

回复 3# tireless


    高，学习了。字符截取原来有如此妙用！