[特效代码] [已更新]批处理自动随机更改桌面背景

zljzsmzzx

闲来没事。随便写了个批处理。先看代码吧。
声明：该帖先个几分钟也在非常批处理发布过，绝对原创，并非转载。

代码已更新。

@echo off&setlocal enabledelayedexpansion
if not "%1"=="h" mshta vbscript:createobject("wscript.shell").run("""%~nx0"" h",vbhide)(window.close)&exit
set "bmp="%USERPROFILE%\Local Settings\Application Data\Microsoft\Wallpaper1.bmp""
if not exist delay.vbs echo wscript.sleep 10000>delay.vbs
set ADD=reg add "HKEY_CURRENT_USER\Control Panel\Desktop"
(
%ADD% /v TileWallpaper /d "0" /f
%ADD% /v WallpaperStyle /d "3" /f
)>nul 2>nul
:start
set "n="
for /f %%i in ('dir/b *.bmp') do set/a n+=1
:+REN标签会以001.bmp的形式自动重命名当前目录下的*.bmp位图文件。
:+但如果原文件名中带有半角叹号“!”会出错，目前还没想到解决办法。
:+所以在下载保存图片的时候请自己注意一下图片名字是否还有“!”，有则删掉再保存。
:REN
set "ver="
for /f "delims=" %%i in ('dir /b *.bmp') do (
set /a ver+=1&set "name=0000000!ver!.bmp"&set "name=!name:~-7!"
if /i "%%i" neq "!name!" (
if exist "!name!" (ren "!name!" "TMP_!random!.bmp"&ren "%%i" "!name!"&goto REN) else ren "%%i" "!name!"
))
%ADD% /v Wallpaper /d %bmp% /f
set/a "a=%random%%%%n%+1"
set "a=000%a%"&set "b=!a:~-3!"
for %%i in (%x%) do (if "%b%" equ "%%i" goto start)
set/a m+=1
:+下面这个10是控制随机更换的10张图片内不会重复。可以自行设置。
:+不能大于图片总数减1。如共50张图片则最大只能设成49。
if %m% gtr 10 (
set "x=%b% %x:~0,-4%"
)else set "x=%b% %x%"
copy /y "%b%.bmp" %bmp%>nul 2>nul
RunDll32.exe USER32.DLL,UpdatePerUserSystemParameters
delay.vbs
goto start
复制代码

这次更新的主要内容是增加了自动重命名图片的功能，也就是说批处理会自动重命名与批处理同目录下的所有*.bmp图片。这样大家用起来就更方便了，随时都可以增加新图片或是删除看腻了的图片，只要图片格式*.bmp不要搞错就行了。如果大家在使用过程中发现什么问题请跟帖反应，大家共同学习。
如果用着感觉不错就请回来帮我顶顶帖哦，鼓励鼓励我这个新手。

[ 本帖最后由 zljzsmzzx 于 2009-6-29 12:08 编辑 ]

Batcher

相关讨论：
http://bbs.bathome.net/thread-337-1-1.html

a794685135

收藏了，改日定当好生研究

zljzsmzzx

原来早有人写过了。不过思路不完全一样。而且“随风”的那个也没有“自动”的效果。他有的我有，我有的他不全有，这样应该不算抄袭吧。重要的是我之前根本就没看过那个帖。不过。他的“set /a w=%random%%%%var%+1”用法可以借鉴一下。另外有一点我觉得很抱歉，就是在非常批处理发帖之前我搜索了相关帖，而来这里发的时候就给忘了。

[ 本帖最后由 zljzsmzzx 于 2009-6-25 20:18 编辑 ]

zljzsmzzx

原代码借鉴了“set /a w=%random%%%%var%+1”的用法已经有所更新。现在能支持999张图片了。

zljzsmzzx

再次更新。更方便好用了。