[文本处理] 求助如何用批处理对文件里的内容加1进行批量修改？

wjx4254131

文件名为:10date.lst
文件内容有挺多行:
例如文件内容为:
................................
................................
..................................
Object Update = 1   
{     
version = 1.0.0.53
}
Object Html = 100
{
Object 12wws.html = 101
{
  version = 1.0.0.19
}
      Object l52al.html = 102
{
   version = 3.0.0.428
}
Object asd/eer.swf = 103
{
  version = 1.0.0.243
}
.....................................
...................................

想对version =后面的数字统一进行加1(如:version =3.0.0.248===>加一后;变成:version =3.0.0.249)
希望高手指点....谢谢

[ 本帖最后由 wjx4254131 于 2009-3-23 19:08 编辑 ]

随风

看你这好像是ip地址，如果加一后大于255怎么办？
另外，你的 version 前面有空格是吗？还是不确定？
再就是文本中有空行吗？

wjx4254131

可以大于255
version 前面是有空格
文本中是有空行

Batcher

估计不是IP地址，而是版本控制信息。

随风

@echo off&setlocal enabledelayedexpansion
for /f "tokens=1* delims=:" %%i in ('findstr /n .* a.txt') do (
  if "%%j"=="" (echo.) else (
     for /f "tokens=1,2 delims==" %%a in ("%%j") do (
        set str=%%a&set "var=!str: =!"&set "max=%%b"
     )
     if "!var!"=="version" (
        for /f "tokens=1-4 delims=." %%a in ("!max!") do (
           set /a n=%%d+1
           echo !str!= %%a.%%b.%%c.!n!
        )
     ) else echo.%%j
))
pause
复制代码

[ 本帖最后由 随风 于 2009-3-23 19:53 编辑 ]

wjx4254131

谢谢随风高手
但MS修改不了.

Batcher

@echo off
(for /f "delims=" %%a in (10date.lst) do (
  set "StrRow=%%a"
  setlocal enabledelayedexpansion
  set StrRow=!StrRow: =!
  if "!StrRow:~0,8!" equ "version=" (
    for %%h in ("%%a") do (
      set StrVer=%%~xh
      set StrVer=!StrVer:~1!
      set /a StrVer+=1
      echo.%%~nh.!StrVer!
    )
  ) else (
    echo.%%a
  )
  endlocal
))>"%temp%\a.txt"
move /y "%temp%\a.txt" 10date.lst
复制代码

wjx4254131

谢谢
但MS修改不了

Batcher

经测试，改的了。

wjx4254131

我这边测试了,修改不了.郁闷

Batcher

请检查你的10date.lst是不是unicode编码
请检查你的10date.lst是不是和批处理放在同一目录下
请在命令行解释器中运行批处理并贴出报错信息

wjx4254131

文件是用这个编写的ultraEdit10
都放在同一个目录下,(测试:如果是单独一行是可运行加一的,而多行就加不了)
命令行没报什么错

Batcher

文本编码格式跟它用什么编辑器没有必然的联系。
把的文件压缩一下然后传上来看看吧。

lvsehuaxue

这样也行吧

@echo off&setlocal enabledelayedexpansion
(for /f "tokens=1,2 delims=:" %%a in ('findstr /n .* a.txt') do (
      if "%%b" equ "" echo.
     (if "%%b" neq "" echo %%b |findstr "version">nul&&for /f "tokens=1-4 delims=." %%i in ("%%b") do (
          set /a n=%%l+1
          echo %%i.%%j.%%k.!n!
     )) || echo %%b
))>a
move a a.txt
复制代码