[文本处理] 怎么把文本中的连续两个空格替换成一个，只有一个的删除，然后排版

lilarcor

rt ,然后能不能根据这个空格来排版
比如修改空格后文本如下，每个字段的长度都是不等的
XXX aaa bbb ccc dddd
VVVVVV bbb aaa dddd eee
PPPP sss aaa jjj sss

排版后，能不能达到下面的效果
XXX       aaa bbb ccc   dddd
VVVVVV bbb aaa dddd eee
PPPP      sss  aaa jjj     sss

hanyeguxing

1，怎么把文本中的连续两个空格替换成一个，然后排版？直接set "a=%a:  = %"
2，楼主提供的效果看不规律。。。每列左对齐？右对齐？

lilarcor

1.真的看不懂
2.每列左对齐

CrLf

@echo off
(for /f "delims=" %%a in (a.txt) do (
for %%b in (%%a) do set /p=%%b【此处换成tab键】<nul
echo;
))>b.txt
more /t8 b.txt>c.txt
复制代码

一个思路...

lilarcor

谢谢。另外我第一个问题有点改变，就是连续两个空格的保留一个，一个的去除，怎么弄

tmplinshi

5# lilarcor

sed "s/  /\t/g; s/ //g" 1.txt|more /t8
复制代码

lilarcor

@echo off
(for /f "delims=" %%a in (a.txt) do (
for %%b in (%%a) do set /p=%%b【此处换成tab键】b.txt
more /t8 b.txt>c.txt一个思路...
zm900612 发表于 2011-4-7 17:36

直接用tab还是有点问题的，因为每个字段长度可能会有不同。似乎会很复杂。
vim中有个align插件能够做到，但是不想用vim，享用批处理的方式做掉

batman

可以用补充空格截取字符串的方法来解决，但要通用，则必须获取文本中最长字符串的长度。。。

batman

@echo off&setlocal enabledelayedexpansion
set /a max=0
for /f "delims=" %%a in (a.txt) do (
     for %%b in (%%a) do (
          set "str=%%b"&set "n="
          for /l %%c in (1,1,80) do if "!str:~%%c!" equ "" if not defined n set "n=%%c"         
          if !max! lss !n! set /a max=n
    )
)
for /l %%a in (1,1,%max%) do set "k=!k! "
set /a max+=2
for /f "delims=" %%a in (a.txt) do (
     for %%b in (%%a) do set "str=%%b!k!"&set "var=!var!!str:~,%max%!"
     echo !var!&set "var="
)
pause>nul
复制代码

tmplinshi

直接替换源文件；
英文感叹号会被删除；
空行会被删除；
每一行中不能含有 , ; = * ?；

@echo off

set "file=a.txt"
set "Tab=【此处换成tab键】"

SetLocal EnableDelayedExpansion
set MaxLen=0
(for /f "usebackq tokens=*" %%a in ("%file%") do (
    set var=%%a
    set var=!var:  =%Tab%!
    set var=!var: =!
    echo,!var!
    for %%a in (!var!) do (
        set s=%%a
        rem ---------- 计算字符个数 ----------
        set /a a = 8189, c = 0
        for /l %%a in (1 1 13) do (
            set /a "b = (a - c) / 2 + c"
            for %%b in (!b!) do (
                if "!s:~%%b,1!"=="" (set a=!b!) else set c=!b!
            )
        )
        rem ---------- / 计算字符个数 ----------
        if !a! gtr !MaxLen! set MaxLen=!a!
    )
)) >"%file%.tmp"
set /a MaxLen += 1
more /t%MaxLen% "%file%.tmp" >"%file%"
del "%file%.tmp"
复制代码

lilarcor

各位版主大人和网友们，我只得佩服得五体投地，十分感谢，效果一级棒