[文件操作] [已解决]如何用批处理全盘搜索指定TXT文件列表里的文件并删除？

y169168712

各位大哥，我想用批处理全盘搜索并删除文本文件a.txt里的文件？

D:\a.txt的类容如下：
1.zip
2.txt
3.mp3
4.7z
5.rm

注意a.txt文件里有隐藏文件
具体应该怎么做了

下面的这个批处理需要有文件的全部路径
@echo off
for /f "delims=" %%a in (a.txt) do del /q "%%a"

[ 本帖最后由 y169168712 于 2010-3-26 21:14 编辑 ]

jcy0307

头痛中。。。。 感冒一直没好 不想动脑了！下面代码 是根据前段时间写的BAT版杀毒代码改编的 有空再想想！

@echo off
color 0a
for /r c:\ %%i in (*.*) do (
cls
echo 正在扫描 %%i
for %%k in (%%~nxi) do (
for /f %%j in (a.txt) do (
if "%%j"=="%%k" echo 发现文件:%%j & echo 发现文件-%%i >> 扫描日志.txt & ping -n 2 127.1>nul
)
)
)
if not exist 扫描日志.txt echo 没有发现文件！& pause>nul & exit
echo 扫描完成,按任意键后开始删除！
pause>nul
for /f "delims=- tokens=2" %%k in (扫描日志.txt) do (
echo 正在删除--%%k 
del /f /q "%%k" 
echo 删除成功--%%k >> 删除日志.txt
pause
复制代码

y169168712

由忠的感谢jcy0307
感冒要快点好起来哦～～！
就是搜索的速度有点慢，不知道有没有更快的方法

[ 本帖最后由 y169168712 于 2010-3-26 21:08 编辑 ]

caruko

for /f %%i in ('dir /a:-d /s /b') do echo %%~nxi |findstr /l /g:a.txt && del /f /q "%%i"
复制代码

caruko

或者

for /f %%i in (a.txt) do set %%i=1
for /f %%a in ('dir /a:-d /s /b') do if defined %%~nxa del /s /q %%a
复制代码

namejm

@echo off
set drive=c d e f g h i j k l m n o p q r s t u v w x y z
for %%i in (%drive%) do (
    for /f "delims=" %%j in (d:\a.txt) do del /a /f /q /s "%%i:\%%j" 2>nul
)
pause
复制代码

WBATW

回复 4# caruko

FINDSTR: 无法从 a.txt 读取字符串