[特效代码] 求批处理进度条

xiaoguren

进度条，60秒减少一格，10分钟减完
代码如下，怎么调试也不显示进度条
求大神帮忙

@echo off&setlocal enabledelayedexpansion
mode con cols=113 lines=20 &color 9f 
set a=■■■■■■■■■■ 
for /l %%i in (600,-1,1) do (
cls
set /a n=%%i%60
set /a m=60
if !n! geq 60 set /a m-=1
echo After %%i seconds ,start thunder
echo !a:~-%m%!
ping /n 2 127.1 >nul 
)
复制代码

523066680

[attach]11654[/attach]

yhcfsr

@echo off&setlocal enabledelayedexpansion
mode con cols=113 lines=20 &color 9f 
set "bar=■■■■■■■■■■"

for /l %%i in (600,-1,0) do (
	if %%i neq 600 (set/a "num=%%i%%60")
	if defined num if !num! equ 0 set bar=!bar:~,-1!
	cls
	echo After %%i seconds ,start thunder
	echo;!bar!
	ping /n 2 127.1 >nul 
)
pause
复制代码

SQYSQYSQY

回复 1# xiaoguren

@echo off&setlocal enabledelayedexpansion
mode con cols=113 lines=20 &color 9f 
set "a=■■■■■■■■■■"
for /l %%a in (600 -1 1) do (
set /a "b=(%%a+59)/60"
cls
echo After %%a seconds ,start thunder
for %%b in (!b!) do echo !a:~0,%%b!
ping -n 2 127.1 >nul 
)
cls
echo After 0 seconds ,start thunder
pause >nul
复制代码

我调试过的，没问题

Zhou.

我这有一个不用开启变量延迟的方法。
:start
cls
set a=10
set b=■■■■■■■■■■
:jindu
cls
set /a a=a-1
if "%a%"=="9" set b=■■■■■■■■■
if "%a%"=="8" set b=■■■■■■■■
if "%a%"=="7" set b=■■■■■■■
if "%a%"=="6" set b=■■■■■■
if "%a%"=="5" set b=■■■■■
if "%a%"=="4" set b=■■■■
if "%a%"=="3" set b=■■■
if "%a%"=="2" set b=■■
if "%a%"=="1" set b=■
if "%a%"=="0" goto kaishi
echo 还剩%a%秒
echo %b%
ping /n 2 127.0.0.1>nul
goto jindu
已测试，没问题。

Zhou.

回复 5# Zhou.
说错了！
:start
cls
set a=10
set b=■■■■■■■■■■
:jindu
cls
set /a a=a-1
if "%a%"=="9" set b=■■■■■■■■■
if "%a%"=="8" set b=■■■■■■■■
if "%a%"=="7" set b=■■■■■■■
if "%a%"=="6" set b=■■■■■■
if "%a%"=="5" set b=■■■■■
if "%a%"=="4" set b=■■■■
if "%a%"=="3" set b=■■■
if "%a%"=="2" set b=■■
if "%a%"=="1" set b=■
if "%a%"=="0" goto kaishi
echo 还剩%a%秒
echo %b%
ping /n 2 127.0.0.1>nul
goto jindu

:kaishi
echo 成功！
pause
exit

Zhou.

回复 6# Zhou.


    记得前面加上@echo off