[文件操作] 批处理如何查找卷标为指定内容的盘符？

wiyml

大家好，我是新手。
在PE下，有一个驱动的卷标是“C_PAN",我想用批处理查找到底是哪个盘。
因为有二块硬盘，有时是C盘，有时显示是其它盘。
如何实现？
谢谢大家。

522235677

@echo off
ver|find "5.1" >nul && (set v=1) || (set v=2)
for /f "tokens=%v%" %%a in ('wmic logicaldisk^|find "C_PAN"') do set p=%%a
echo %p%
pause
复制代码

apang

回复 2# 522235677


    WinPE下貌似不能用wmic吧？

apang

@echo off
set "volume=C_PAN"
for %%a in (C D E F G H I J K L M N O P Q R S T U V W X Y Z) do (
        if exist %%a:\ if not defined Drv (
                call :Next %%a
        )
)
echo,%Drv%
pause & exit/b

:Next
for /f "tokens=3*" %%a in ('dir %1:\ 2^>nul') do (
        if /i "%%b" == "%volume%" set "Drv=%1:"
        goto :eof
)
复制代码

neorobin

用楼上的改了下, 用 vol 或者 label 命令都可以获取卷标的

下面代码中, 当活动代码页为 437时, 用 tokens=5*  当活动代码页为 936 时, 用 tokens=3*

for %%d in (C D E F G H I J K L M N O P Q R S T U V W X Y Z) do (
    if exist %%d: (
        for /f "tokens=3* delims= " %%a in ('vol %%d:') do if /i "%%b"=="C_PAN" start %%d:&echo %%d:&pause&exit
    )
)
复制代码

neorobin

回复 4# apang

L 打成 I 了