[文本处理] [已处理]批处理怎样检查每个文件夹里有多少张图片列出到文本？

luckcsz

每一个文件夹中有不等数量的文件，图片文件格式jpg、tif格式
   文件夹名称           里面的数量（是指图片格式文件共多少个，）文件夹中还有别的文件的。
(比如AA-0001)   图片文件数量 5
(比如AA-0002)   图片文件数量 7
(比如AA-0003)   图片文件数量 25   
等等

哪位老师路过看看帮忙做下，在文件夹下直接点击运行谢谢~！

cfwyy77_bat

@echo off
setlocal enabledelayedexpansion
(for /f  %%i in ('dir /b /a:d') do (
	for /f %%j in ('dir /b %~dp0%%i\*.jpg %~dp0%%i\*.tif ^| find /c "."') do set n=%%j
	echo %%i 图片文件数量 !n!  
	)) >1.txt 2>nul
pause
复制代码

仅供参考。

lifei259

@echo off&setlocal enabledelayedexpansion
for /f "delims=" %%a in ('dir/ad/b') do (set n=0
    for /f "delims=" %%i in ('dir/a-d/b,%%~sa\*.jpg %%~sa\*.tif 2^>nul') do (
        set /a n+=1
    )
echo,%%a中图片文件数量!n!
)
pause
复制代码

luckcsz

回复 2# cfwyy77_bat

谢谢~！处理成功~！

luckcsz

回复 3# lifei259
  
    谢谢~！处理成功

Batcher

例如：AAA文件夹中运行，文件夹下有1个或者10个子文件夹取得每个子文件夹的图片各自总数，目前这个批处理是这样的。
我想AAA文件夹中运行，取得子各自文件夹的总数量，假如子文件夹下还有子文件夹也可以统计取得各自的总数量

@echo off
(for /f "delims=" %%i in ('dir /b /s /ad') do (
    pushd "%%i"
	for /f %%j in ('dir /b *.jpg *.tif 2^>nul ^| find /c "."') do (
        echo %%i 图片文件数量 %%j
    )
    popd
))>"%~dp01.txt"
复制代码

luckcsz

回复 6# Batcher


    已经成功，老师谢谢您~！

luckcsz

回复 6# Batcher


    空文件夹能不能不要列出来~？