[文本处理] 【已解决】求助批处理高手帮我把以下要求写成批处理

李安阳

1.我需要一个批处理 在指定路径的所有         ″文件夹后面″       加路过两个字。
2.我需要一个批处理 在指定路径生成一个批处理写入代码            ″并且打开″。
3.我需要一个批处理 在优盘插入后自动复制优盘的所有文件夹到指定路径

Batcher

不同的需求请单独发帖

Linuxer

第一个：

@echo off
::设置目标路径
set FileDir=C:\Test
::文件夹重命名
for /f %%i in ('dir /ad /b %FileDir%') do ren %FileDir%\%%i %%i路过
pause
复制代码

另外的需求请按管理员建议单独开帖详细描述。一个问题一个帖子。

李安阳

回复 2# Batcher

哦 知道了

李安阳

回复 3# Linuxer


    忘了忘了,有空格的文件夹不行啊！！
帮我再改一下 感谢高手

Batcher

回复 5# 李安阳

@echo off
set "FileDir=C:\Test"
for /f "delims=" %%i in ('dir /ad /b "%FileDir%"') do (
    ren "%FileDir%\%%i" "%%i路过"
)
复制代码

李安阳

太感谢了回复 6# Batcher

李安阳

回复 6# Batcher


    sorry大神，我把这个发给了我同学  该怎么恢复呢??

Linuxer

回复 8# 李安阳

单独还原：

@echo off
setlocal enabledelayedexpansion
::设置目标路径
set "FileDir=C:\Test"
for /f "delims=" %%i in ('dir /ad /b %FileDir%') do (
	set a_name=%%i
        ren "%FileDir%\%%i" "!a_name:~0,-2!"
)
pause
复制代码

带改名和还原。输入1就是改名，输入2就是还原。目标路径自己修改下。

@echo off
setlocal enabledelayedexpansion
::设置目标路径
set "FileDir=C:\Test"

:dowhat
set /p input=请输入数字(改名：1，还原：2）：
if not defined input echo 未输入内容&goto dowhat
if "%input%" equ "1" (
	goto renamed
) else if "%input%" equ "2" (
	goto restore
) else (
	echo 输入错误
	goto dowhat
)
::改名
:renamed
for /f "delims=" %%i in ('dir /ad /b %FileDir%') do (
	ren "%FileDir%\%%i" "%%i路过"
)
goto :eof

::还原
:restore
for /f "delims=" %%i in ('dir /ad /b %FileDir%') do (
	set a_name=%%i
	ren "%FileDir%\%%i" "!a_name:~0,-2!"
)
goto :eof
复制代码