[其他] [已解决]数值计算的批处理为何提示运算符不存在？

yinrui520hb

代码 如下：

@echo off&mode con cols=90 lines=15&setlocal enabledelayedexpansion
set /a col=90
set /a line=15
set /a c=0
set /a l=0
for /l %%i in (1,1,150) do (
if !col! equ 90 set /a c=0
if !col! equ 14 set /a c=1
if !line! equ 15 set /a l=0
if !line! equ 1 set /a l=1
if !c! equ 0 set /a col-=1 else set /a col+=1
if !l! equ 0 set /a line-=1 else set /a line+=1
mode con cols=!col! lines=!line!
ping 127.1 -n 1 >nul
)
pause>nul
复制代码

运行时会出“运算符不存在”
苦苦折磨了莪 4个多小时 就是没搞定

[ 本帖最后由 yinrui520hb 于 2009-12-26 18:52 编辑 ]

neorobin

把 else 之前的子语句用括号括起来就 OK 了, 代码有问题时, 用 打开 ECHO, 插入 PAUSE, REM, 这些调试手段, 很容易确定问题所在的.

 
@echo off&mode con cols=90 lines=15&setlocal enabledelayedexpansion
set /a col=90
set /a line=15
set /a c=0
set /a l=0
for /l %%i in (1,1,150) do (
if !col! equ 90 set /a c=0
if !col! equ 14 set /a c=1
if !line! equ 15 set /a l=0
if !line! equ 1 set /a l=1
if !c! equ 0 (set /a col-=1) else set /a col+=1
if !l! equ 0 (set /a line-=1) else set /a line+=1
mode con cols=!col! lines=!line!
ping 127.1 -n 1 >nul
)
pause>nul
复制代码

yinrui520hb

_ _〣 第一次发现报错的时候莪就做过 可能 忘了保存 结果一样 所以有删了
只能怪自己太大意 为这种问题...4个多小时.....

谢谢楼上的了

Batcher

set /a 通常用来进行数值计算，如果只是简单的变量赋值的话，用set即可。