[文件操作] for中用SET设置变量后不生效，第2次执行才生效

keetian

@echo off

set "wmpfile=C:\Program Files\Windows Media Player\wmplayer.exe"
if not exist "%wmpfile%" (
echo 未安装Windows Media Player 11...
)
if exist "%wmpfile%" (
for /f "tokens=5" %%i in ('filever.exe  "%wmpfile%"') do SET wmpver=%%i
echo 已安装Windows Media Player "%wmpver%"
)

以上代码存为f.bat,在cmd窗口中，第一次执行f.bat,输出已安装Windows Media Player ""
第一次执行f.bat,输出已安装Windows Media Player "10.0.0.3802"
请问怎么解决呢？

pcl_test

回复 1# keetian

@echo off
setlocal enabledelayedexpansion
set "wmpfile=C:\Program Files\Windows Media Player\wmplayer.exe"
if not exist "%wmpfile%" (
echo 未安装Windows Media Player ...
) else (
for /f "tokens=5" %%i in ('filever.exe "%wmpfile%"') do SET wmpver=%%i
echo 已安装Windows Media Player !wmpver!
)
pause
复制代码

DAIC

@echo off
setlocal enabledelayedexpansion
set "wmpfile=C:\Program Files\Windows Media Player\wmplayer.exe"
if not exist "%wmpfile%" (
    echo 未安装Windows Media Player ...
) else (
    for /f "tokens=5" %%i in ('filever.exe "%wmpfile%"') do (
        set "wmpver=%%i"
    )
    echo 已安装Windows Media Player !wmpver!
)
pause
复制代码