[已解决]批处理怎样根据LOG最后修改时间判断程序是否在运行？

jijo

有款软件会自动产生日志文件A.TXT，若日志文件A.TXT的最后修改时间与当前系统时间相差不大于5分钟，则表示该软件正常运行中。

若时间间隔大于5分钟以上，则判断该程序假死或者已经停止服务，但实际上软件的进程并未关闭。

希望批处理根据计划时间检查该程序，若日志文件时间差大于5分钟，能发邮件提醒相关人员。

以前有调试过一个是通过tasklist 判断程序进程是否存在的批处理。但是并不适用上面的问题，麻烦各位大大了~

Batcher

批处理判断一个文件在最近5分钟内是否被更新过

问题背景描述：

检测程式查看一个X.log的文本里的时间，类似2008-11-1 12:00:00 这样的格式，因为log当中每3分钟会刷新一次，所以时间也会变，现在我的思路是用程式抓到的最新也就是最大的时间和系统时间做比对，超过5分钟，则说明系统的log已经没有再生成（系统已经死了），然后确认死了之后，在连接上Oracle的一个DB，把一些栏位的资料 insert into 到一张用来发送alarm mail的table当中去。不知道bat文档能否实现。

@echo off
set SrcFile=D:\a.txt
for /f "skip=5 tokens=1-2 delims= " %%a in ('dir /tw "%SrcFile%"') do (
    set "FileDay=%%a %%b"
    goto :compare
)
:compare
call :DateToMins %FileDay:~0,4% %FileDay:~5,2% %FileDay:~8,2% %FileDay:~11,2% %FileDay:~14,3% mFileDay
call :DateToMins %date:~4,4% %date:~9,2% %date:~12,2% %time:~0,2% %time:~3,2% mToday
set /a mMinus=mToday-mFileDay
if %mMinus% gtr 5 (
    echo "The system is down"
) else (
    echo "The system is running"
)
pause
goto :eof

:DateToMins %yy% %mm% %dd% %hh% %mm% result
setlocal ENABLEEXTENSIONS
set yy=%1&set mm=%2&set dd=%3&set hh=%4&set nn=%5
if 1%yy% LSS 200 if 1%yy% LSS 170 (set yy=20%yy%) else (set yy=19%yy%)
set /a dd=100%dd%%%100,mm=100%mm%%%100
set /a z=14-mm,z/=12,y=yy+4800-z,m=mm+12*z-3,j=153*m+2
set /a j=j/5+dd+y*365+y/4-y/100+y/400-2472633
if 1%hh% LSS 20 set hh=0%hh%
if {%nn:~2,1%} EQU {p} if "%hh%" NEQ "12" set hh=1%hh%&set/a hh-=88
if {%nn:~2,1%} EQU {a} if "%hh%" EQU "12" set hh=00
if {%nn:~2,1%} GEQ {a} set nn=%nn:~0,2%
set /a hh=100%hh%%%100,nn=100%nn%%%100,j=j*1440+hh*60+nn
endlocal&set %6=%j%&goto :EOF
复制代码

jijo

看起来楼上的整个程序好复杂。后半部分一大段DateToMins是必须这样配合的么？我机器上运行了米效果。
提示如图。

Batcher

把@echo off删掉，多加几个pause，到cmd里面跟踪一下执行过程。

hanyeguxing

1，要求：
%%~ta 输出时间为2011-01-12 08:05
%date% 的格式为2011-01-12 ......
%time% 的格式为 8:27:35.25
2，当超过5分钟时，执行 echo 超过时间，可以根据需要改变
3，超时时间为5分钟，单位分，由命令 set/a K=%K: =%*60+1%time:~3,2%-100-5 设置。根据需要可以修改最后这个数字5，范围1-1439

@echo off
set K=%time:~0,2%
set/a K=%K: =%*60+1%time:~3,2%-100-5,D=1%date:~8,2%-100
set/a D-=!!(%K:-=%-K),K+=!!(%K:-=%-K)*1440,H=K/60,F=K-60*H,M=1%date:~5,2%-100-!D,Y=%date:~0,4%-!M,M+=!M*12,"K=!(M-4)|!(M-6)|!(M-9)|!(M-11)","D+=!D*(!(M-2)*(28+!(Y%%4))+K*30+(!!(M-2)&!K)*31)"
set M=0%M%&set D=0%D%&set F=0%F%&set H=0%H%
for %%a in ("D:\日志.log") do if "%Y%-%M:~-2%-%D:~-2% %H:~-2%:%F:~-2%" gtr "%%~ta" echo 超过时间
复制代码

[ 本帖最后由 hanyeguxing 于 2011-1-12 22:12 编辑 ]

jijo

o(∩_∩)o ，寒夜孤星昨晚十点多还在调试代码呀。辛苦了辛苦了。