【已解决】求批处理，网页打开状态，及文字输出，谢谢大家围观

skyuser

已解决，谢谢伟大的论坛

skyuser

着急，呼唤大神出现。
回复仅楼主可见

Batcher

@echo off
setlocal enabledelayedexpansion
for /f %%i in (1.txt) do (
    for /f %%a in ('curl -so /dev/null -w %%{http_code} %%i') do (
        set RetCode=%%a
    )
    echo !RetCode!
    for /f "tokens=3,4 delims=][ " %%a in ('ping -n 1 -w 100 %%i ^| findstr "正在"') do (
        set RetAlias=%%a
        set RetIP=%%b
    )
    if !RetCode! equ 200 (
        >>"2.txt" echo %%i--^>正常打开--别名：!RetAlias!--IP：!RetIP!
    ) else (
        >>"2.txt" echo %%i--^>无法打开
    )
)
复制代码

窄口牛

@echo off
for /f %%i in (1.txt) do (
ping %%i|find "请求找不到主机" && echo %%i--^>无法打开>>2.txt
for /f "tokens=3,4" %%a in ('ping -n 1 -w 100 %%i ^|findstr "^正在"') do echo %%i-^>正常打开--别名：%%a--IP：%%b>>2.txt

)
pause
复制代码

鼓捣了一天搞下的，乘着你的问题，自己试试，呵呵.

窄口牛

@echo off
for /f %%i in (1.txt) do (
ping %%i|find "请求找不到主机" >nul&& echo %%i--^>无法打开>>2.txt
for /F "tokens=3,4" %%a in ('ping -n 1 -w 100 %%i ^|findstr "^正在"') do echo %%i-^>正常打开--别名：%%a--IP：%%b>>2.txt
)
复制代码

skyuser

回复 3# Batcher


    首先非常感谢版主的解答，现在这个脚本，对于域名是别名解析的，会一直显示302代码，然后一直提示网站打不开，版主您能加我的QQ吗？我QQ号：2052339076，谢谢！

Batcher

回复 6# skyuser


加个302判断，是这个意思吗？

@echo off
setlocal enabledelayedexpansion
for /f %%i in (1.txt) do (
    for /f %%a in ('curl -so /dev/null -w %%{http_code} %%i') do (
        set RetCode=%%a
    )
    echo !RetCode!
    for /f "tokens=3,4 delims=][ " %%a in ('ping -n 1 -w 100 %%i ^| findstr "正在"') do (
        set RetAlias=%%a
        set RetIP=%%b
    )
    if !RetCode! equ 200 (
        >>"2.txt" echo %%i--^>正常打开--别名：!RetAlias!--IP：!RetIP!
    ) else if !RetCode! equ 302 (
        >>"2.txt" echo %%i--^>正常打开--别名：!RetAlias!--IP：!RetIP!
    ) else (
        >>"2.txt" echo %%i--^>无法打开
    )
)
复制代码

很久不上QQ了，有问题请在论坛回帖吧。

hlzj88

如果不算晚

@echo off&&setlocal enabledelayedexpansion
del /q *.ini
del /q 汇总.html
set a=0
for /f %%i in (1.txt) do (
        ping -n 1 %%i>2.ini
       findstr /i "超时 找不到主机" 2.ini&&echo ^<br^>%%i---^>无法打开>>3.ini ||echo ^<br^>%%i----^>正常打开--别名：>>3.ini&&type 2.ini>>3.ini
)
findstr /i "正常打开 正在 不到主机 无法打开" 3.ini>>4.ini
for /f "delims=" %%i in (4.ini) do (
set pp=%%i
set pp=!pp:正在 Ping =!
set pp=!pp:[=IP:!
set pp=!pp:] 具有 32 字节的数据:=!
echo !pp!>>汇总.html
)
del /q *.ini
start "" 汇总.html
cls
echo win7下  全部测试完毕
pause
复制代码

如果红包还有，请看楼上batcher的签名捐助

skyuser

回复 8# hlzj88


    谢谢您的热心参与，论坛朋友用exe完美解决了，再次感谢。

skyuser

回复 7# Batcher


    谢谢您了版主，论坛热心朋友用EXE帮我解决问题了，麻烦你帮我把那个帖子删了吧，谢谢你啦

Batcher

回复 10# skyuser


这个论坛没有在问题解决后删帖的习惯。留着吧，这几个代码说不定别人能用得上。