77七

@echo off
rem 批处理保存为utf-8编码格式
chcp 65001 >nul
for /f "delims=" %%i in ('dir /b /a-d *.srt') do (
	(for /f "tokens=1* delims=[]" %%a in ('find /n /v "" ^<"%%i"') do (
		if "%%b" equ "" (
			echo=
		) else (
			set "str=%%b"
			setlocal enabledelayedexpansion
			call :1
			endlocal
		)
	))>"%%~ni_2%%~xi"
)
pause & exit

	:1
	echo !str:~0,30!
	set "_str=!str:~30!"
	if "!_str!" neq "" (
		set "str=!_str!"
		goto :1
	) else (
		exit /b
	)
复制代码

小白来了

回复 14# buyiyang


    厉害了我的哥！技术专业！谢谢谢谢！

小白来了

回复 15# Five66


    感谢大佬！谢谢

小白来了

回复 16# 77七


大佬好，感谢您！还有一点小问题~

如果时间码超过字数的话 也会跟着换行。能否只检测文字，不检测数字时间码呢？

时间码格式：00:09:30,401 --> 00:09:30,971

77七

回复 19# 小白来了


  

@echo off
rem 批处理保存为utf-8编码格式
chcp 65001 >nul
for /f "delims=" %%i in ('dir /b /a-d *.srt') do (
	(for /f "tokens=1* delims=[]" %%a in ('find /n /v "" ^<"%%i"') do (
		if "%%b" equ "" (
			echo=
		) else (
			set "str=%%b"
			setlocal enabledelayedexpansion
			set "_str=!str:~0,1!"
			if !_str! gtr Z (
				call :1
			) else (
				echo !str!
			)
			endlocal
		)
	))>"%%~ni_2%%~xi"
)
pause & exit

	:1
	echo !str:~0,30!
	set "_str=!str:~30!"
	if "!_str!" neq "" (
		set "str=!_str!"
		goto :1
	) else (
		exit /b
	)
复制代码

小白来了

回复 20# 77七


    成功了，大佬威武霸气！感谢您的专业帮助~祝您财源广进~一起顺利！！

qixiaobin0715

感谢14楼指出代码错误。下面代码最多可进行2次换行，即适合一行不超过90个字符，原字幕文件空行保留：

@echo off
chcp 65001>nul
for /f "delims=" %%i in ('dir /b /a-d *.srt') do (
    (for /f "delims=" %%j in ('type "%%i"') do (
        set "str=%%j"
        setlocal enabledelayedexpansion
        set /a t=str
        if !t! equ !str! (
            echo,%%j
        ) else if not "!str:-->=!"=="!str!" (
            echo,%%j
        ) else (
            if not "!str:~30!"=="" (
                echo,!str:~,30!
                set str=!str:~30!
                if not "!str:~30!"=="" (
                    echo,!str:~,30!
                    echo,!str:~30!
                    echo,
                ) else (
                    echo,!str!
                    echo,
                )
            ) else (
                echo,%%j
                echo,
            )
        )
        endlocal
    ))>"New-%%i"
)
复制代码

terse

powershell

<# :
@echo off 
powershell -noprofile -NoLogo "iex (${%~f0} | out-string)"
pause
exit 
#>
$re = "^\d{2}:\d{2}:\d{2},\d{3} --> \d{2}:\d{2}:\d{2},\d{3}$"
$n = 30
[IO.Directory]::EnumerateFiles($pwd, "*.srt")|%{ [IO.File]::WriteAllLines("$_._new.txt",([IO.File]::ReadAllLines($_)|%{if($_ -match $re){$_ }else{$_ -split "(?<=\G.{$n})(?=.)"}}),[Text.Encoding]::UTF8)}
复制代码

小白来了

回复 20# 77七


    大哥，这段代码改成覆盖原文件，应该怎样修改呢？我自己修改的操作完成空白文件了。求您指教~谢谢！

@echo off
rem 批处理保存为utf-8编码格式
chcp 65001 >nul
for /f "delims=" %%i in ('dir /b /a-d *.srt') do (
	(for /f "tokens=1* delims=[]" %%a in ('find /n /v "" ^<"%%i"') do (
		if "%%b" equ "" (
			echo=
		) else (
			set "str=%%b"
			setlocal enabledelayedexpansion
			set "_str=!str:~0,1!"
			if !_str! gtr Z (
				call :1
			) else (
				echo !str!
			)
			endlocal
		)
	))>"%%~ni_2%%~xi"
)
pause & exit

	:1
	echo !str:~0,30!
	set "_str=!str:~30!"
	if "!_str!" neq "" (
		set "str=!_str!"
		goto :1
	) else (
		exit /b
	)
复制代码

77七

回复 24# 小白来了


   19行下面添加一行

        move "%%~ni_2%%~xi" "%%i"
复制代码