[日期时间] 批处理怎样获取昨天/前一天的日期赋值给变量？

lky216

一个LOG日志文件夹下有很多每天生成的日志，像2012-05-18，2012-05-19等等这样的文件夹，这样子。
想把当天的昨天，比如今天，也就是2012-05-18，把昨天，也就是2012-05-17这个文件夹复制到指定的文件夹，比如C：
想法就是获取当天的日期%date:~0,4%%date:~,2% 然后退后一天，存成变量，然后xcopy 今天的昨天 2012-05-17 到 C：

到了明天，执行的时候，也是和上面的差不多，自动获取当天的日期，然后复制当天的昨天的日志到C：

这样子循环，就是每个月没有固定几天的，所以比较麻烦，下面有一个代码，是获取指定时间+—几天，生成结果
可以试一下，可以输入3 也可以输入负的，也就是-3等。

@echo off
title 日期查询 Make by Willsort
color 1f
if [%1]==[] call :Help
call :Date2Day %1 days
set/a days=%days%+%2
call :Day2Date %days% date
echo.
echo -----------结果---------------
echo.
echo 你查询的日期为：%date%
echo ------------------------------
cmd /k

:Date2Day
setlocal ENABLEEXTENSIONS 
for /f "tokens=1-3 delims=/-, " %%a in ('echo/%1') do ( 
  set yy=%%a & set mm=%%b & set dd=%%c 
)
set /a dd=100%dd%%%100,mm=100%mm%%%100 
set /a z=14-mm,z/=12,y=yy+4800-z,m=mm+12*z-3,j=153*m+2 
set /a j=j/5+dd+y*365+y/4-y/100+y/400-2472633
endlocal&set %2=%j%&goto :EOF 

:Day2Date
setlocal ENABLEEXTENSIONS 
set /a i=%1,a=i+2472632,b=4*a+3,b/=146097,c=-b*146097,c/=4,c+=a 
set /a d=4*c+3,d/=1461,e=-1461*d,e/=4,e+=c,m=5*e+2,m/=153,dd=153*m+2,dd/=5 
set /a dd=-dd+e+1,mm=-m/10,mm*=12,mm+=m+3,yy=b*100+d-4800+m/10 
(if %mm% LSS 10 set mm=0%mm%)&(if %dd% LSS 10 set dd=0%dd%) 
endlocal&set %2=%yy%-%mm%-%dd%&goto :EOF 

:Help
    cls
    echo ________________________________________________                       
    echo 使用方法：%~nx0 [日期] [天数] 
    echo.                           
    echo 日期格式：2007-03-31                     
    echo 天数格式：+/-查询的天数                        
    echo 示例：%~nx0 2007-03-31 3 就是查询3天后的日期  
    echo ________________________________________________
    echo.
    cmd /k
复制代码

fatcat

回复 1# lky216

这类问题相关的帖子相当多了, 以下列举部分, 楼主可自行搜索 昨天, 日期 等等 关键字

批处理怎样把昨天写入文件？
http://www.bathome.net/viewthread.php?tid=16045

批处理获取指定天数之前的日期
http://bbs.bathome.net/thread-3330-1-1.html

批处理单行版时间日期计算 算法讨论
http://www.bathome.net/viewthread.php?tid=16147

批处理 如何删除以系统日期创建的前一周的文件夹
http://www.bathome.net/viewthread.php?tid=16388

lky216

回复 2# fatcat


    谢谢你，哈哈，发帖之后有再自己看其他 和日期相关的。

lky216

回复 2# fatcat


   
F:\>xcopy /s/e/h/k/r/c/y "f:\新建文件夹" "C:\新建文件夹"
目标 C:\新建文件夹 是文件名
还是目录名
(F = 文件，D = 目录)?

然后 这样子怎么办？怎么自动输入D，不然还要先MD目录

neorobin

回复 4# lky216

"C:\新建文件夹\"

最后有一个反斜杠 \  就可以了, 就会当作目录来处理

lky216

回复 5# neorobin


    哈哈，谢谢，这个论坛真好。