100元求助，批量压缩文件解压，重命名文件问题

liwan123

现在我有上千个winrar压缩文件，winrar文件名是不规则，压缩文件里面有一级、二级、三级、四级文件夹等情况，里面含有一个或多个pd和/或word文件，现在我的需求：
1、批量解压到各自压缩包文件名下，这一步好办。
2、把解压后得到的pdf和/或word文件移动到压缩包解压后的单独文件夹里
3、再把pdf和或word文件重命名为文件夹名字，多个文件的分别命名为-1、-2、-3.......
压缩包文件结构见附图：
[attach]12438[/attach][attach]12437[/attach][attach]12439[/attach]，
解压后并移动文件、重命名需求：
[attach]12442[/attach]

liwan123

请各位老铁们多多帮忙，可微信转账或支付宝转账，测试功能正常马上付款。测试文件包链接：https://pan.baidu.com/s/1FDjZqpvCVkG4uMFloIFB_Q
提取码：uot1

qazplm

@echo off
rem 有问题,可加QQ956535081及时沟通
set "exefile=C:\Program Files\WinRAR\WinRAR.exe"
if not exist "%exefile%" (echo;"%exefile%" not found&goto end)
for /f "delims=" %%a in ('dir /a-d/b/s *.rar ') do (
    echo;"%%a"
    "%exefile%" x -ibck -y "%%a" "%%~dpa#%%~na\"
    if not exist "%%~dpa%%~na\" md "%%~dpa%%~na\"
    for /f "delims=" %%b in ('dir /a-d/b/s "%%~dpa#%%~na\" 2^>nul') do (
        call :loop "%%b" "%%~dpa%%~na\" "%%~na"
    )
    rd /s /q "%%~dpa#%%~na\"
)
:end
cd /d "%~dp0"
pause
exit
:loop
set n=2
set "newfile=%~2\%~3%~x1"
:check
if not exist "%newfile%" (goto break)
set "newfile=%~2\%~3-%n%%~x1"
set /a n+=1
goto check
:break
move "%~1" "%newfile%"
exit/b
复制代码

went

@echo off
set "path=%path%;C:\Program Files\WinRAR\"
for /f "delims=" %%i in ('dir /b /a-d *.rar') do (
	set /p=urar %%i  <nul
	unrar e -ep -or -ad "%%i" >nul 2>nul
	call :renFile "%%~i"
	echo done.
)
pause&exit
:renFile
set "key=1"
for /f "delims=" %%a in ('dir /b /a-d "%~n1" 2^>nul') do (
	rename "%~n1\%%a" "%~n1%%~xa" 2>nul || (
		call rename "%~n1\%%a" "%~n1-%%key%%%%~xa" 
		set /a "key+=1"
	)
)
复制代码

保存为bat放到rar文件目录下

liwan123

两位老铁的代码都可以正常运行，按先来先得原则，我建议qazplm分得70元，went分的30元，两位同意的话，请留下微信二维码或者支付宝，明天我再测试下，下午就付钱，谢谢！

qazplm

回复 5# liwan123

大家是冲着100来的，这样分开就不好，谁先解决给谁就行了，后者可以适当给点小费即可，付款扫我头像或加我Q

went

回复 5# liwan123


    支付宝18281837522

liwan123

回复 6# qazplm
100元已发支付宝。

liwan123

回复 7# went
账号不存在，或对方关闭了通过手机号找到我隐私开关。