【出题】批处理输出n阶幻方

lhjoanna

所谓n阶幻方：1-n^2个数排为n行n列，横、竖、对角线相加和相同。
  输入：幻方阶数n (暂限制为奇数阶)
  输出：n行n列的方阵，横、竖、对角线相加和相同。
  举例：5阶幻方，横、竖、对角线相加和为65

17 24  1  8 15
23  5  7 14 16
4  6 13 20 22
10 12 19 21  3
11 18 25  2  9

keen

把setlocal enabledelayedexpansion放在for语句里面是为了防止读取某些含有叹号！字符串时，丢失叹号！字符。

而你的这个算幻方的题，可能不涉及到叹号！字符串的处理。所以可以把setlocal enabledelayedexpansion放在for语句外面防止超过最大递归层。

但当你处理一些含有叹号！字符串时，应该注意把setlocal enabledelayedexpansion放在for语句内部，防止丢失。

这就叫 “随机应变”，就是看情况选择setlocal enabledelayedexpansion的位置。

Lumiere

那个帖子我看了，上面说最好把变量延迟扩展申明放在for结构内，哪里需要哪里申明，然后再结束，那我的问题不就没办法解决了么？我试过了，在for里申明然后在结构结束之前用endlocal结束，结果还是会出现那个恼人的错误提示。但是我照33楼兄弟的说法把申明放到for结构之前，问题就没有了。到底哪个是对的？如果要放在for里面的话，如何把我的问题解决？

Batcher

确实应该好好看看，也许你会发现不把变量延迟扩展放在for里面有时可能带来更多的问题^_^

Lumiere

呵呵，就要这种效果，一句话就解决，我把变量延迟放到外面就不会提示那个错误了。再去好好看看这个问题的描述，多谢啦！

Batcher

“已经达到最大的setlocal递归层”的问题，请参考：
http://bbs.bathome.net/thread-1224-1-3.html

zhouyongjun

变量延迟不要放在for里面

Lumiere

晕菜啊，这么久也没人来指点一下啊，再等~

Lumiere

好早之前看到这个帖子了，在这个帖子还没有回复的时候就开始研究写了代码，可是错误不少，后来因为工作的事就一直没时间去斟酌。现在有时间了，仔细看了下，终于改出来了，本来挺高兴的，结果上来一看，前辈们早就把代码反复推敲了N久了，而且问题的本质已经从对症下药给出合理的解决代码上升倒了代码效率高下的研究，这是本人不敢企及的。本来不打算把代码贴上来了，可是本人后来输入较大点的数字的时候，又出现一个问题，就是“已经达到最大的setlocal递归层”但是似乎幻方的生成还是没有影响，数字也都对，我不太明白这个错误怎么长生的。老调重弹，麻烦前辈们给解释下，不胜感激！
我写的代码如下：

@echo off
:start
set /p n=Please input your odd integer:
set /a p=n%%2
if %p% equ 0 echo Input error!&&goto start

set /a i=%n%
set /a t=(%n%+1)/2
set /a a%t%_%n%=1,temp=1,m=n-1,p=n
:repeat
set /a p-=1
if %p% lss 0 goto array
for /l %%a in (1 1 %m%) do (
   setlocal enabledelayedexpansion
   if !t! gtr %n% set /a t=1
   if !i! gtr %n% set /a i=1
   set /a s=!t!+1,q=!i!+1
   if !s! gtr %n% set /a s=1
   if !q! gtr %n% set /a q=1
   set /a a!s!_!q!=a!t!_!i!+1,t+=1,i+=1
   set /a temp+=1
   if !temp! equ %n% (
         set /a temp=1,tmp=a!s!_!q!,q-=1,i-=1
         if !q! equ 0 set /a q=n 
         set /a a!s!_!q!=tmp+1
         goto repeat
)    
)
pause
:array
echo Now behold the powerful Magic Sqaure^^!:
set /a a!t!_!n!=1
for /l %%c in (!n! -1 1) do (
   for /l %%d in (1 1 !n!) do (
              set /a result=a%%d_%%c
              set /p=!result!<nul       
)
echo.
)
pause>nul
复制代码

如上，输入7以上的奇数就会出现那个问题，没弄明白，只好请教诸位了。

lhjoanna

按照兄的建议修改了下，感觉效率还有待提高。批代码中大量操作都用于矩阵的赋值与运算，而高级语言中数组则作为内嵌类型，而MATLAB更是以矩阵作为基本的操作单元，所以对矩阵进行线性运算耗费时间很低，可能这也就是其效率高的原因吧。
    MATLAB中有很多经典算法，并且许多用于数值分析的算法都是世界一流的算法，效率自然很高，许多的源代码都是可以自己修改的，也很值得学习借鉴。我现在也就只能看懂整个程序的流程，至于为什么如此构造可以实现(以幻方为例)我还想不明白，这确实需要很强的数学背景了！

随风

想通过代码来了解算法太难了，大致看了下兄的代码流程，只发现一处影响代码效率的地方。
批处理的运行效率，个人认为 set 或 set /a 并不会太影响，关键是看代码的设计，for的循环次数尤其是嵌套循环，再就是call若在for循环中有call则一定会使效率大打折扣。
建议改进的地方：
:exchange 标签下
call set _%%i%%j=%%_!i!%%j%%
改为 for %%a in (!i!) do set _%%i%%j=!_%%a%%j!

lhjoanna

下午偶然从MATLAB上找到了构造幻方的源代码，是用MATLAB程序设计语言实现的(基于C语言设计)，可以生成阶数不限的幻方。下午把此算法用批处理实现了。下面附上批版代码以及magic(n)函数源代码。

@echo off
:begin
 setlocal enabledelayedexpansion
 set rank=
 echo.&set /p "rank=请输入幻方阶数:"
 set /a remainder=rank%%2
 if !remainder! equ 1 (
    call :odd !rank!
 ) else (
     set /a remainder=rank%%4
     if !remainder! equ 0 ( 
        call :even_4
     ) else call :even_2
   )

rem --------------奇数阶幻方------------------

:odd
 set rank=%1
 call :create
 for /l %%i in (1 1 !rank!) do (
     for /l %%j in (1 1 !rank!) do (
         set /a $%%i%%j="(.%%i%%j+.%%j%%i-(rank+3)/2+rank)%%rank"
         set /a #%%i%%j="(.%%i%%j+.%%j%%i*2-2+rank)%%rank"
         set /a _%%i%%j="rank*$%%i%%j+#%%i%%j+1"
     )
  )
 if not "%~2" equ "" goto :eof
 call :output
 endlocal&goto :begin

rem -------------偶数阶幻方(4整除)---------------

:even_4
 call :create
 set num=0
 for /l %%i in (1 1 !rank!) do (
     for /l %%j in (1 1 !rank!) do (
         set /a "a=(.%%i%%j%%4)/2,b=(.%%j%%i%%4)/2"
         if !a! equ !b! ( set "_%%i%%j=1" ) else set "_%%i%%j=0"
         set /a "num+=1,n=rank*rank+1"
         set /a #%%i%%j=!num!
         if !_%%i%%j! equ 1 (set /a _%%i%%j=n-#%%i%%j) else set _%%i%%j=!#%%i%%j!
     )
 )
 call :output
 endlocal&goto :begin

rem --------------偶数阶幻方(2整除)--------------

:even_2
 set /a p=rank/2,q=rank,p1=p+1
 call :odd !p! OK
 set rank=!q!
 call :rearrange 1 !p! !p1! !rank! 2
 call :rearrange !p1! !rank! 1 !p! 3
 call :rearrange !p1! !rank! !p1! !rank! 1
 call :transpos !p!
 if !rank! equ 2 (
   call :output
   endlocal&goto :begin
 )
 for /l %%i in (1 1 !p!) do set "var_i=!var_i! %%i" 
 set /a k=(rank-2)/4,m=rank-k+2
 for /l %%i in (1 1 !k!) do set "var_j=!var_j! %%i"
 for /l %%i in (!m! 1 !rank!) do set "var_j=!var_j! %%i"
 call :exchange "!var_i!" "!var_j!"
 set /a i=k+1
 set "j=1 !i!"
 call :exchange "!i!" "!j!"
 call :output
 set i=
 set j=
 set var_i=
 set var_j=
 endlocal&goto :begin


rem -------------以下为子函数-----------------

:create
 set /a rank_2=rank*rank,i=1,j=1
 for /l %%i in (1 1 !rank_2!) do (
       set .!i!!j!=!j!
       set /a j+=1
       if !j! gtr !rank! set j=1&set /a i+=1
 )
 goto :eof

:output
  call :append !rank!
  for /l %%i in (1 1 !rank!) do (
     for /l %%j in (1 1 !rank!) do set result=!result! !_%%i%%j:~-3!
     echo.!result!&set result=
  )
  goto :eof

:rearrange
 set /a p2=%5*p*p,i=1,j=1
 for /l %%i in (%1 1 %2) do (
     for /l %%j in (%3 1 %4) do (
         set /a _%%i%%j=_!j!!i!+p2
         set /a j+=1
     )
     set /a "i+=1,j=1"
 )
 goto :eof

:exchange
 for %%i in (%~1) do (
     for %%j in (%~2) do (
         set /a i=%%i+p
         set tmp=!_%%i%%j!
         call set _%%i%%j=%%_!i!%%j%%
         set _!i!%%j=!tmp!
     )
 )
 goto :eof

:transpos
 for /l %%i in (1 1 %1) do (
     for /l %%j in (%%i 1 %1) do (
         if not %%i equ %%j (
            set tmp=!_%%i%%j!
            set _%%i%%j=!_%%j%%i!
            set _%%j%%i=!tmp!
         )
     )
 )
 goto :eof

:append
  for /l %%i in (1 1 %1) do (
     for /l %%j in (1 1 %1) do (
         set "_%%i%%j=   !_%%i%%j!"
     )
  )
  goto :eof
复制代码

函数magic(n);

function M = magic(n)
%MAGIC  Magic square.
%   MAGIC(N) is an N-by-N matrix constructed from the integers
%   1 through N^2 with equal row, column, and diagonal sums.
%   Produces valid magic squares for all N > 0 except N = 2.

%   Copyright 1984-2002 The MathWorks, Inc.
%   $Revision: 5.15 $  $Date: 2002/04/15 03:44:23 $

% Historically, MATLAB's magic was a built-in function.
% This M-file uses a new algorithm to generate the same matrices.

n = floor(real(double(n(1))));

% Odd order.
if mod(n,2) == 1
   [J,I] = meshgrid(1:n);
   A = mod(I+J-(n+3)/2,n);
   B = mod(I+2*J-2,n);
   M = n*A + B + 1;

% Doubly even order.
elseif mod(n,4) == 0
   [J,I] = meshgrid(1:n);
   K = fix(mod(I,4)/2) == fix(mod(J,4)/2);
   M = reshape(1:n*n,n,n)';
   M(K) = n*n+1 - M(K);

% Singly even order.
else
   p = n/2;
   M = magic(p);
   M = [M M+2*p^2; M+3*p^2 M+p^2];
   if n == 2, return, end
   i = (1:p)';
   k = (n-2)/4;
   j = [1:k (n-k+2):n];
   M([i; i+p],j) = M([i+p; i],j);
   i = k+1;
   j = [1 i];
   M([i; i+p],j) = M([i+p; i],j);
end

分三种情况，奇数、偶数、双偶数。MATLAB源代码中调用了一些函数，可以在帮助文档中找到。
附：
    在MATLAB软件环境下用命令调用magic(n)，效率很高，上千阶的幻方也只需要2-3秒；可用批实现的代码效率却不尽如人意，比上面几楼各位的代码还要低些，可能是大量的变量赋值运算影响了效率吧；大家再来优化下代码，看哪里还有提升的空间。

xxx

嗯,我承认我是迟到了...而且还不是batch的...
是python的:

#09/4/4/12
def make_list(num):
    n,k,b,c = num,0,num/2,num**2
    listx = []
    for x in xrange(n):
        listx.append([])
        for _x in xrange(n):
            listx[x].append(False)
    for _x in xrange(c):
        if((_x+1)==1):
            listx[k] = 1

        elif((_x+1)%n==1):
            k = k+1
            if(k>n-1):
                k = k-n
            listx[k] = _x+1
        else:
            k = k+2
            b = b+1
            if(b>n-1):
                b = 0
            if(k>n-1):
                k = k-n
            listx[k] = _x+1
    for y in xrange(n):
            print(listx[y])

def start():
    print("Input a number:")
    x = input()
    if(x%2==0):
        print("Wrong.")
    else:
        make_list(x)
 
if __name__ == "__main__":
     start()
复制代码

[ 本帖最后由 xxx 于 2009-4-12 14:05 编辑 ]

小勇12

真是厉害，呀 向大家学习

terse

凑热闹 马步的
修改前面的set ".!h!-!m!=1"这句放在FOR里面

@echo off
:start
setlocal enabledelayedexpansion
echo.&set /p n= 请输入一个奇数 &cls
set /a m=n/2+1,c=n*n,he=(n*n+1)*n/2
echo  !n! 阶幻方各行,列以及对角线相加的和为: %he%&echo.
for /l %%i in (1 1 !c!) do (
   set/a i=%%i%%n
   if !i! equ 1 (set/a h=h%%n+1) else set/a h=h%%n+2,m=m%%n+1
   if !h! gtr !n! set h=1
      set ".!h!-!m!=%%i"
)
for %%i in (0 1 10) do if not "!c:~%%i,1!"=="" set /a j=%%i+2&set "k=!k! "
for /l %%a in (1 1 !n!) do (
   set "var="
   for /l %%b in (1 1 !n!) do (
      set "str=!k!!.%%a-%%b!"
      set "var=!var! !str:~-%j%!"
    )
    echo.!var:~1!
)
pause
endlocal&goto start
复制代码

[ 本帖最后由 terse 于 2009-4-6 11:07 编辑 ]