[文本处理] [已解决]批处理如何实现多行合并成一行？

yuanzheng

a.txt文本内容如下：
===================================
11111111111
22222222222
33333333333
44444444444
55555555555
66666666666
77777777777
88888888888
99999999999
00000000000
.......................................

批处理后想得到的结果文件b.txt
====================================
11111111111;22222222222;33333333333;44444444444;55555555555;
66666666666;77777777777;88888888888;99999999999;00000000000
.............................


（注意：文本中的每行的字符数量不一样，意思就是说有长有短）


找到一个命令只是将全部行变为一行。代码如下，请参考...

@echo off

　　:: 把多行文本拼接成用;连接的一行

　　:: <NUL 不能省略，省略掉就无法运行下去

　　for /f "tokens=*" %%i in (a.txt) do set /p "var=%%i;" >b.txt

　　exit
复制代码

[ 本帖最后由 yuanzheng 于 2011-3-9 13:21 编辑 ]

hucuibai

@echo off
for /f  %%a in (a.txt) do set /p=%%a;<nul>>b.txt
复制代码

batman

@echo off&setlocal enabledelayedexpansion
set /a num=1
for /f "delims=" %%a in (a.txt) do (
     set /a n+=1,m=n%%5
     set "str=!str!%%a;"
     if !m! equ 0 echo !str!>!num!.txt&set "str="&set /a num+=1
)
if defined str echo %str%>%num%.txt
复制代码

Batcher

你这是每5行合并成1行么？

Commander

@echo off
setlocal enabledelayedexpansion
set "SrcFile=a.txt"
set "DstFile=b.txt"
set "MergeNum=5"
set "Delimiter=;"

type nul>"%DstFile%"
for /f "usebackq tokens=*" %%a in ("%SrcFile%") do (
    set /a RowTotal+=1
    set /a Count+=1
    set "RowMerge=!RowMerge!%Delimiter%%%a"
    if !Count! equ !MergeNum! (
        >>"%DstFile%" echo,!RowMerge:~1!
        set RowMerge=
        set Count=0
    )
)

set /a RowMod=RowTotal%%MergeNum
if !RowMod! equ 0 (
    goto :end
)
>>"%DstFile%" echo,!RowMerge:~1!
:end
复制代码

yuanzheng

感谢大家。   Commander符合要求 。

batman

请楼主说说三楼哪里不符合要求？

yuanzheng

我想要的是输出一个文件。你的是输出多个文件。

CrLf

原先有点错，改下

@echo off
(for /f  %%a in (a.txt) do (
    set /a n+=1,m=n%%5&set /p=%%a;<nul
    set /a test=1/m||echo;
))>b,txt
复制代码

[ 本帖最后由 zm900612 于 2011-3-9 15:37 编辑 ]

wc726842270

不知道怎么样。

@echo off&setlocal enabledelayedexpansion
for /f "delims=" %%i in (2.txt) do (set /a n+=1
 set a=!a!%%i
 if !n! equ 5 (echo !a!>>输出文件.txt&&set n=&set a=)
)
pause
复制代码

batman

难道楼主自己就不能动一下手修改一下，就只习惯复制粘贴双击这三个动作？

Batcher

你找一个6行内容的文件试试？