batman

原帖由 ieutk 于 2008-8-1 02:37 发表
这里面也有类似的题目

http://bbs.bathome.net/viewthread.php?tid=850&extra=page%3D1@echo off
setlocal enabledelayedexpansion
for /l %%a in (12 -1 1) do set "str= %%a !str!"
for /l %%a in (29 -1 13) ...

　　代码已经够简洁了，但存在效率问题：每循环一次还要用for循环对变量str
进行一行判断，当然在总人数和退出数不大的情况下是没有问题的，当数量提
上去以后，这个判断循环数将是可观的，效率自会大打折扣。

batman

原帖由 more 于 2008-7-30 20:25 发表
不知道这样是否正确?@echo off
set "str=13 14 15 16 17 18 19 20 21 22 23 24 25 26 27 28 29 1 2 3 4 5 6 7 8 9 10 11 12"
:again
for /f "tokens=1,2,4*" %%a in ("%str%") do (
   if not "%%c"=="" (set "s ...

　　思路是好的，但代码不通用，因为for /f "tokens=*" 是有个极限值tokens=31的，
运行以下的代码就会明白：

@echo off
for /l %%i in (1,1,32) do call,set str=%%str%% a
for /f "tokens=31" %%i in ("%str%") do echo %%i
for /f "tokens=32" %%i in ("%str%") do echo %%i
pause>nul
复制代码

　　可能大家会说这里tokens=1,2,4*是个循环，根本不涉及到最大tokens值的问题，
是的，本题是不会出现这个tokens最大值的问题，但如果将退出数增加到31以上呢？
如总人数为100，数到50的人退出，这样的代码将无法运行。
　　

ieutk

这里面也有类似的题目

http://bbs.bathome.net/viewthread.php?tid=850&extra=page%3D1

@echo off
setlocal enabledelayedexpansion
for /l %%a in (12 -1 1) do set "str= %%a !str!"
for /l %%a in (29 -1 13) do set "str= %%a !str!"

:main
set "ie=0"
for %%a in (%str%) do set /a ie+=1
if %ie% neq 1 (
        for %%a in (%str%) do (
                set /a num+=1
                if !num! equ 3 (
                        set "num=0"
                        set "str=!str: %%a =!
                    )
            )
        goto main
    )
echo %str%
pause
复制代码

more

@echo off
Setlocal Enabledelayedexpansion
:begin
cls&set "str="&set "var="&set "n=0"&set "m=0"
set /p men=请输入人数:
set /p bgn=请输入开始的编号:
set /a "nn=%bgn%-1"
set /p num=请输入循环数:
for /l %%a in (%bgn% 1 %men%) do (call set "str=%%str%% %%a")
for /l %%a in (1 1 %nn%) do (call set "str=%%str%% %%a")
if "%num%"=="1" (
   for %%a in (%str%) do (set "res=%%a")
   echo.&echo 最后剩下: !res!&echo.&pause&goto :begin
)
:again
for %%i in (%str%) do (
   set /a "m+=1"
   if "!m!"=="%num%" (set "%%i="&set "m=0") else (set "%%i=!m!")
)
for %%b in (%str%) do (if defined %%b (set "var=!var! %%b"))
for %%c in (%var%) do (set /a "n+=1")
if "%n%"=="1" (echo.&echo 最后剩下: %var%&echo.&pause&goto :begin)
set "n=0"&set "str=%var%"&set "var="&goto :again
复制代码

pusofalse

楼上的朋友可再深入一下。
n个人报数，从编号为z的人开始数，数到m的人退出，求最后的是原来的几号。
nzm为用户输入的数字。

more

不知道这样是否正确?

@echo off
set "str=13 14 15 16 17 18 19 20 21 22 23 24 25 26 27 28 29 1 2 3 4 5 6 7 8 9 10 11 12"
:again
for /f "tokens=1,2,4*" %%a in ("%str%") do (
   if not "%%c"=="" (set "str=%%c %%d %%a %%b"&goto :again) else (echo %%b&pause&exit)
)
复制代码

pusofalse

Joseph loop
我打算直接复制我的上来，却发现没保存。
给新人如何~