PCL505512957

悲剧啊，我这个代码哪错啦？老运行不了

@if not defined debug @echo off&setlocal enabledelayedexpansion
set ",=一二三四五" num=
for /f %%i in (a.txt) do (
call echo %%,:~!num!,1%%^|%%i
set /a num+=1
)
pause >nul
复制代码

wangqi0077

@echo off
setlocal enabledelayedexpansion
set /a n=1
set a= 一二三四五六七八九十

for /f %%i in (1.txt) do (
for %%c in (!n!) do set /p=!a:~%%c,1!^|%%i
set /a n=!n!+1
)
pause >nul
复制代码

we6540

@echo off
setlocal EnableDelayedExpansion
for /f %%i in (1.txt) do (
set a=%%i
set b=!a:要=一┃要!
set c=!b:可=二┃可潜!
set e=!c:可看=三┃可看!
set f=!e:也=四┃也!
set g=!f:你=五┃你!
echo !g!
)
echo.
ECHO.
echo 好像有点勉强！！！！！！！~M_M~
pause

weichenxiehou

@echo off
setlocal enabledelayedexpansion
set str=一二三四五
set m=0
for /f "delims=" %%i in (a.txt) do (
for %%j in (!m!) do echo !str:~%%j,1!^|%%i&set /a m+=1
)
pause

vincentzhou

@echo off
for /f "tokens=1,* delims=:" %%a in ('findstr /n .* a.txt') do (
if "%%a"=="1" echo 一│%%b
if "%%a"=="2" echo 二│%%b
if "%%a"=="3" echo 三│%%b
if "%%a"=="4" echo 四│%%b
if "%%a"=="5" echo 五│%%b
)
pause>nul
复制代码

[ 本帖最后由 vincentzhou 于 2011-1-1 00:07 编辑 ]

qq106942397

@echo off&setlocal enabledelayedexpansion
Title 未完整板        →ψ疯行天魔Ф
set "ψ=零 一 二 三 四 五 六 七 八 九"
for /f "tokens=1,* delims=:" %%a in ('findstr /n .* "a.txt"') do (
set "Ф=%%a"
set ФФ=0
for %%c in (%ψ%) do (
call set Ф=%%Ф:!ФФ!=%%c%%
set /a ФФ+=1
)
echo !Ф!┃%%b)
pause
复制代码

[ 本帖最后由 qq106942397 于 2010-7-28 21:48 编辑 ]

poxi

答：

 
@echo off
setlocal EnableDelayedExpansion
set str=一二三四五六七八九十
set /a a=0
for /f %%i in (a.txt) do (
   call echo %%str:~!a!,1%%┃%%i
   set /a a+=1
)
pause
复制代码

效果：
[attach]2724[/attach]

=========================
end；

gxuan2008

@echo off
setlocal enabledelayedexpansion
set "str=一┃二┃三┃四┃五┃"
set /a num=0
for /f "delims=" %%a in (a.txt) do (
    call set new=%%str:~!num!,2%%
    set /a num+=2
    echo !new!%%a
)
pause
复制代码

对call 的用法还不是很明白。==#。

[ 本帖最后由 gxuan2008 于 2010-7-4 14:52 编辑 ]

aiguozhe

高手云集啊！我还需要加紧追赶！

wgoxm521

@echo off & setlocal EnableDelayedExpansion
set "a= 一二三四五"
for /f "delims=" %%i in (2.txt) do (
        set /a "num+=1"
        set "wind!num!=%%i"
)
for /l %%j in (1,1,5) do (
        set "b=!wind%%j!"
        set "c=!a:~%%j,1!"
        echo !c!┃!b!
)
pause>nul
复制代码

十五楼的代码简洁，很巧妙。学习了....

[ 本帖最后由 wgoxm521 于 2010-1-29 08:07 编辑 ]

feidian1028

@ echo off&setlocal enabledelayedexpansion
set index=0
for /f %%i in (text.txt)do set /a index+=1&echo !index!｜%%i
pause>nul

bamboo

@echo off
setlocal enabledelayedexpansion
set "number=一二三四五"
for /f "tokens=*" %%a in (a.txt) do (
set no=!number:~0,1!
echo !no!^|%%a
set number=!number:~1!
)
echo    按任意键退出！
pause>nul
复制代码

zgq0301

@echo off
setlocal enabledelayedexpansion
set /a var=0
set list=一二三四五
for /f %%i in (a.txt) do (
   call echo %%list:~!var!,1%%┃%%i
   set /a var+=1
   )
pause>nul
%0

Batcher

参考：批处理中的变量延迟扩展、变量嵌套
http://bbs.bathome.net/viewthread.php?tid=2899

sjzong

请问： call echo %%!num!┃%%i
!num!的前面为什么要加两个%%呢？不是用call调用时用%1，%2……表示吗？？