mac007cn

@echo off
set /a "x=%random%%%10000"
if %x% lss 1000 ( set /a "x+=1000" )
echo %x%
复制代码

ithinkican

内容………

skuny

@echo off
setlocal enabledelayedexpansion
set str=0123456789
for /l %%i in (1 1 20) do (
for /l %%i in (1 1 11) do (
  set /a a=!random! %% 9
  call set str=!a!%%str:!a!=%%
)
set str0=!str:~-4,1!
if !str0!==0 (echo !str:~-5,4!) else echo !str:~-4,4!
)
pause
复制代码

用楼主的 代码 扩展一下哈哈

jixun66

@echo off
call :n r1
call :n r2
call :n r3
call :n r4
if not %r1%==%r2% if not %r2%==%r3% if not %r3%==%r4% goto fin
%0
:n
set /a %1=%random%%%9+1
goto :eof
:fin
echo %r1%%r2%%r3%%r4%
pause>nul
%0
复制代码

虽然麻烦了点……但是电脑运行的速度足够在一秒之内算出来了吧。

[ 本帖最后由 jixun66 于 2010-10-26 01:03 编辑 ]

lvsehuaxue

@echo off
:a1
set n=0
:a
set /a var=%random% %% 9000 +1000
set v1=%var:~,1%
set v2=%var:~1,1%
set v3=%var:~2,1%
set v4=%var:~3,1%
if %v1%==%v2% goto a
if %v1%==%v3% goto a
if %v1%==%v4% goto a
if %v2%==%v3% goto a
if %v2%==%v4% goto a
if %v3%==%v4% goto a
set /a n+=1
set var%n%=%var%
if %n% lss 4 goto a
if %var1%==%var2% pause&goto a1
if %var1%==%var3% pause&goto a1
if %var1%==%var4% pause&goto a1
if %var2%==%var3% pause&goto a1
if %var2%==%var4% pause&goto a1
if %var3%==%var4% pause&goto a1
echo %var1%
echo %var2%
echo %var3%
echo %var4%
pause
复制代码

lvsehuaxue

@echo off&setlocal enabledelayedexpansion
:a1
set n=0
:a
set /a var=%random% %% 9000 +1000
set v1=%var:~,1%
set v2=%var:~1,1%
set v3=%var:~2,1%
set v4=%var:~3,1%
if %v1% neq %v2% (
   if %v1% neq %v3% (
      if %v1% neq %v4% (
         if %v2% neq %v3% (
            if %v2% neq %v4% (
               if %v3% neq %v4% (
                  goto b
               ) else (
                 goto a
)))))) 
:b
set /a n+=1
set var%n%=%var%
if %n% lss 4 goto a
if %var1% neq %var2% (
   if %var1% neq %var3% (
      if %var1% neq %var4% (
         if %var2% neq %var3% (
            if %var2% neq %var4% (
               if %var3% neq %var4% (
                  goto c
                 ) else (
                 goto a1
))))))
:c
echo %var1%
echo %var2%
echo %var3%
echo %var4%
pause
复制代码

edmond

@echo off
setlocal enabledelayedexpansion
:start
set n=1
:loop
set/a a1=!random!%%9
set/a a2=!random!%%9
set/a a3=!random!%%9
set/a a4=!random!%%9
if !a1!==!a2! (goto loop)
if !a2!==!a3! (goto loop)
if !a3!==!a4! (goto loop)
if !a1!==!a4! (goto loop)
if !a1!==!a3! (goto loop)
if !a2!==!a4! (goto loop)
if !a1!==0 (goto loop)
set res!n!=!a1!!a2!!a3!!a4!
set/a n+=1
if !n!==5 (goto ss)
goto loop
:ss
if !res1!==!res2! (goto start)
if !res2!==!res3! (goto start)
if !res3!==!res4! (goto start)
if !res1!==!res4! (goto start)
if !res1!==!res3! (goto start)
if !res2!==!res4! (goto start)
echo !res1!
echo !res2!
echo !res3!
echo !res4!
pause

cjiabing

投机取巧，但并非每次都得

@echo off&setlocal enabledelayedexpansion
:d
set ddr=!random!
echo 原始随机数：!ddr!
set ddd=!ddr:-4,1!
if defined ddd if not "!ddr:~-1,1!"=="!ddr:~-2,1!" if not "!ddr:~-3,1!"=="!ddr:~-4,1!" if not "!ddr:~-1,1!"=="!ddr:~-3,1!" if not "!ddr:~-2,1!"=="!ddr:~-4,1!" if not "!ddr:~-2,1!"=="!ddr:~-3,1!" if not "!ddr:~-1,1!"=="!ddr:~-4,1!" echo 新生随机数：!ddr:~-1,1!!ddr:~-2,1!!ddr:~-3,1!!ddr:~-4,1!||goto d
pause
goto d
复制代码

leap

@echo off&setlocal enabledelayedexpansion
set a=0123456789
set b=10
set tt=
set/p tt=输入您需要的几位不重复数字：
set ttt=9999999999
:1
set ttt=!ttt:~0,%tt%-1!
set/a n=!random!%%10
set/a b-=1
if !b! equ 0 (echo 洗牌完毕&goto 2)
set aa=!a:~%n%,1!
set a=!aa!!a:%aa%=!
echo !a!>a.txt
goto 1
:2
for /f %%i in (a.txt) do (
	set jg=%%i
	set jg1=!jg:~0,%tt%!
	set jg2=!jg:~1,%tt%!
	if !jg1! gtr !ttt! (echo !jg1!) else (echo !jg2!
))
pause&del a.txt
复制代码

leap

@echo off&setlocal enabledelayedexpansion
set a=0123456789
set b=
set/p b=输入随机洗牌次数：
:1
set/a n=!random!%%10
set/a b-=1
if !b! equ 0 (echo 洗牌完毕&goto 2)
set aa=!a:~%n%,1!
set a=!aa!!a:%aa%=!
echo !a!>a.txt
goto 1
:2
for /f %%i in (a.txt) do (
        set jg=%%i
        set jg1=!jg:~1,4!
        set jg2=!jg:~2,4!
        if !jg1! gtr 999 (echo !jg1!) else (echo !jg2!
))
pause&del a.txt
复制代码

netbenton

27楼回贴只看到第一个条件，

再来个满足两个条件的：（随机列出所有四位数，并满足一楼的两个条件要求）

@echo off&setlocal enabledelayedexpansion
for /l %%i in (0,1,9) do set ms=!ms! %%i

set as=!ms: 0=!
(
for %%a in (!as!) do (
  set bs=!ms: %%a=!
  for %%b in (!bs!) do (
    set cs=!bs: %%b=!
    for %%c in (!cs!) do (
      set ds=!cs: %%c=!
      for %%d in (!ds!) do (
        echo;!random! %%a%%b%%c%%d
) ) ) )

)>nums.tmp
for /f "tokens=2" %%a in ('sort nums.tmp') do (echo;%%a)
pause
复制代码

523066680

我测了一下总数
15楼的代码找到漏洞：
筛选重复数字的部分：

for /l %%j in (0,1,9) do (
set ss=!#%%i:%%j=!
if !ss! lss 100 (set "#%%i=")
)

这里，比如数字是1023 ， 剔除1=023
而023<100 所以会被清理。 所以15楼的代码永远不会出现10开头的4位数

523066680

刚刚想了一下 ， inittab 的剔除重复数字的应该是比较全面稳妥的做法
本顿的测试导出100个，偶尔是会出现重复的，
如果数字更大一些，重复的会多一些。

回忆到以前学概率的时候哎，0-9组成 4位数，每一位不重复，第一位不能为0
9*9*8*7=4536 种不同结果

[ 本帖最后由 523066680 于 2010-9-27 22:40 编辑 ]

netbenton

炒冷饭呀~~~
我也来个，一次搞得一百个。
不够么！！自己把100改大点。。。

@echo off&setlocal enabledelayedexpansion
for /l %%i in (0,1,9) do set ms=!ms!%%i

:lp
for /l %%i in (1,1,100) do (
  set ns=!ms!
  set n=9
  set/a v=!random!%%9+1
  for %%b in (!v!) do set s=!ns:~%%b,1!

  for /l %%a in (1,1,3) do (
    for %%b in ("!s:~-1!") do set ns=!ns:%%~b=!
    set /a v=!random!%%n,n-=1
    for %%b in (!v!) do set s=!s!!ns:~%%b,1!
  )
echo !s!
)
pause
goto :lp
复制代码

523066680

擦啊……都这么精简
粗也上了

@echo off
setlocal enabledelayedexpansion
set /a mi=0
:main
for /l %%a in (0,1,9) do (set arr[%%a]=%%a)
set /a i=0,num=%random% %% 9+1
set /a arr[%num%]=arr[9]
   :next
     set /a i+=1,rnd=%random% %% (10-i),last=9-i
     set /a rand=!arr[%rnd%]!,num=num*10+rand,arr[%rnd%]=arr[%last%]
   if %i% lss 3 goto :next
   if defined number[%num%] (goto :main) else (
       set /a number[%num%]=1,mi+=1
       echo %num%
   )
if %mi% lss 4 goto :main
pause
复制代码

[ 本帖最后由 523066680 于 2010-9-28 15:08 编辑 ]