batman

将我19楼的代码简化并提效如下：

@echo off&setlocal enabledelayedexpansion
for /l %%a in (0,1,9) do (
    for /f "delims=" %%b in (b.txt) do (
         for %%c in (%%b) do (
              set /a num=%%c-%%a,num=num%%10
              if !num! equ 0 (
                 set "str=000%%c"&set "str=%%a!str:~-3!"
                 if defined _!str! (
                   call,set "_!str!=%%_!str!%% %%c"
                   ) else (
                   set "_!str!=%%c" 
                 )
               )        
          )
     )
)
for /f "tokens=1,2 delims==_" %%a in ('set _') do (
     set "str=%%a"&set "str=!str:~,1!"
     if not defined !str! (
       echo.&set /p=!str! %%b <nul&set "!str!=a"
       ) else (
       set /p=%%b <nul
     )
)
pause>nul
复制代码

stuqx

@echo off
setlocal ENABLEDELAYEDEXPANSION
md l100
md g100
for /l %%i in (0,1,9) do set "n%%i=%%i"
for /f "delims=" %%a in (1.txt) do (
	for %%b in (%%a) do (
		if %%b lss 100 (echo off >l100/%%b) else (echo off >g100/%%b)
		)
	)
dir /o:n /b l100 >>result.txt
dir /o:n /b g100 >>result.txt
for /f %%m in (result.txt) do (
	set num=%%m
	set re=n!num:~-1!
	call set "!re!=%%!re!%% %%m"
	)
for /l %%p in (0,1,9) do call echo %%n%%p%%
rd /s /q l100
rd /s /q g100
del result.txt
pause
goto :eof
复制代码

昨天没看到有排序的要求  HOHO  现在写好了   新手   给点鼓励

batman

原帖由 terse 于 2009-4-14 10:12 发表

虽然少个FOR 但CALL的效率不知道怎么样
@echo off&setlocal enabledelayedexpansion
for /f "delims=" %%i in (a.txt) do (
   for %%j in (%%i) do (
       set str=%%j
       call set _!str:~-1!=%%_!st ...

怎么不加上排序？

tireless

call 的效率比 for 差。(命令耗时清单)

以下是用 timeit.exe 测出的结果：

Average for terse.bat key over 5 runs

Version Number:   Windows NT 5.1 (Build 2600)
Exit Time:        10:32 am, Tuesday, April 14 2009
Elapsed Time:     0:00:00.056
Process Time:     0:00:00.062
System Calls:     5282
Context Switches: 327
Page Faults:      586
Bytes Read:       17129
Bytes Written:    0
Bytes Other:      72752


Average for terse_call.bat key over 5 runs

Version Number:   Windows NT 5.1 (Build 2600)
Exit Time:        10:32 am, Tuesday, April 14 2009
Elapsed Time:     0:00:00.143
Process Time:     0:00:00.156
System Calls:     4479
Context Switches: 658
Page Faults:      688
Bytes Read:       23031
Bytes Written:    6220
Bytes Other:      78810

[ 本帖最后由 tireless 于 2009-4-14 10:32 编辑 ]

terse

原帖由 terse 于 2009-4-13 17:10 发表
先抛砖 感觉可以少个FOR

虽然少个FOR 但CALL的效率不知道怎么样

@echo off&setlocal enabledelayedexpansion
for /f "delims=" %%i in (a.txt) do (
   for %%j in (%%i) do (
       set str=%%j
       call set _!str:~-1!=%%_!str:~-1!%% %%j
))
for /l %%a in (0,1,9) do if not "!_%%a!"=="" echo %%a!_%%a!
pause
复制代码

stuqx

@echo off
setlocal ENABLEDELAYEDEXPANSION
for /l %%i in (0,1,9) do set "n%%i=%%i"
for /f "delims=" %%a in (1.txt) do (
	for %%b in (%%a) do (
		set num=%%b
		set re=n!num:~-1!
		call set "!re!=%%!re!%% %%b"
		)
	)
for /l %%p in (0,1,9) do call echo %%n%%p%%
pause
goto :eof
复制代码

好了  今天来给我昨天那个稍微改了下  可以了  HOHO

gohai

原帖由 terse 于 2009-4-13 17:10 发表
先抛砖 感觉可以少个FOR@echo off&setlocal enabledelayedexpansion
for /f "delims=" %%i in (a.txt) do (
   for %%j in (%%i) do (
       set str=%%j
       for /l %%a in (0,1,9) do (
       if "!str: ...

set真是用的经典，学习了。

batman

感觉还可以优化，两个大循环可以合并，要开会了，占下位子先。。。

batman

向各献丑了，变量赋值法：

@echo off&setlocal enabledelayedexpansion
for /l %%a in (0,1,9) do (
    for /f "delims=" %%b in (b.txt) do (
         for %%c in (%%b) do (
              set /a num=%%c-%%a,num=num%%10
              if !num! equ 0 set "_%%a=!_%%a! %%c"
         )
    )
)
for /f "tokens=1,2 delims==_" %%a in ('set _') do (
     set /p=%%a <nul&setlocal enabledelayedexpansion
     for %%c in (%%b) do (
          set "str=000%%c"&set "str=!str:~-3!"
            if defined #!str! (
            call,set "#!str!=%%#!str!%% %%c"
            ) else (
            set "#!str!=%%c"  
     　  )
     )
     for /f "tokens=2 delims==" %%d in ('set #') do set /p=%%d <nul
     echo.&endlocal
)  
pause>nul
复制代码

随风

这个题目已经不是新手题了啊。
各位版主也出出手吧，是否应该考虑把terse兄的帖子也打开呢
batman 版主也把自己的代码晒晒吧。
11 楼 tireless 的代码产生了临时文件、效率还行、但不能处理重复数字。
12 楼 gohai 的代码同上。
rat 版主的代码是否能提高下效率。

[ 本帖最后由 随风 于 2009-4-14 04:24 编辑 ]

rat

js有个sort方法

rat

@echo off & setlocal enabledelayedexpansion
for /f "delims=" %%a in (a.txt) do (
  for %%b in (%%a) do (
    call :p %%b
  )
)
for /l %%i in (0,1,9) do (
  if defined f%%i (
    call :sortstr str%%i newstr
    echo !newstr!
  )
)
pause
goto :eof



:p
set s=%1
for /l %%i in (0,1,9) do (
  if "!s:~-1!"=="%%i" (
    if not defined f%%i2 set f%%i2=1&set str%%i=%%i
    set str%%i=!str%%i! %%b
    if not defined f%%i set f%%i=1
    goto :eof
  )
)
goto :eof

:sortstr
setlocal
for %%a in (!%1!) do (
	set/ajj+=1
	set s!jj!=%%a
)
call :sort s %jj%
for /l %%a in (1,1,%jj%) do (
	set ss=!ss! !s%%a!
)
endlocal&set %2=%ss%&goto :eof

:sort arrname %ubound%
set a=%1&set u=%2&set i=2
:sort_1
if %i% gtr %u% goto :eof
set /a %a%0=%a%%i%,j=i-1
:sort_2
if !%a%0! lss !%a%%j%! (
	set /a k=j+1
	set /a %a%!k!=%a%%j%,j-=1
	goto sort_2
)
set /a k=j+1
set /a %a%%k%=%a%0,i+=1
goto sort_1
复制代码

gohai

下面是我做的， 分类 + 排序，

@echo off
setlocal EnableDelayedExpansion

del b.txt&del 1.txt&del 2.txt
for /f "usebackq delims=" %%i in (`more a.txt`) do (
  for %%j in (%%i)do (
    set "number=   %%j"
    echo !number:~-4!>>1.txt
  )
)
for /f "usebackq" %%i in (`sort 1.txt`) do (
  echo %%i>>2.txt
)
del 1.txt
for /l %%i in (0,1,9) do (
	set /a input=0
	for /f "delims=" %%j in (2.txt) do (		
		set /a num=%%j
		set /a flag=!num:~-1,1!
		if !flag! equ %%i (
			if !input! equ 0 (
				set /p=!flag! <nul>>b.txt	
			)
			set /a input=1
			set /p=!num! <nul >>b.txt
		)
	)
	if !input! equ 1 (
		echo. >>b.txt	
	)
)
start b.txt
del 1.txt&del 2.txt
exit
复制代码

tireless

@echo off&setlocal enabledelayedexpansion
(for /f "tokens=*" %%a in (a.txt) do (
  for %%i in (%%a) do set "var=00%%i" & echo !var:~-3!
))>a_tmp.txt

for /f "tokens=* delims=0" %%a in ('sort a_tmp.txt') do (
  set var=%%a
  for %%i in (#!var:~-1!) do set %%i=!%%i! %%a
)

for /l %%a in (0 1 9) do if defined #%%a echo %%a!#%%a!
del a_tmp.txt & pause
复制代码

[ 本帖最后由 tireless 于 2009-4-14 11:50 编辑 ]

Batcher

楼主出这个题目，意图应该不仅仅是考察截取最后一位字符的方法，你可以先尝试一下其它思路，比如：取余。