neorobin

正要说这个, 用换班的方法会造成矛盾,
设换班号之前两个后门生其中一个在 M 班, 要去 P 班
而另一个在 N 班, 要去 Q 班
就存在两次班号调换, M<==>P, N<==>Q
这样, 当 M, N, P, Q 这四个数字中有相同, 但又不是 M=Q且P=N的情况, 就会至少使一个后门生到不了要去的班号.

单单调换学生时, 如果学生不属一个类别, 不会有问题, 如果有相同类别的后门生都要换班, 那么代码须要更复杂的设计

@echo off & setlocal enableDelayedExpansion
for %%a in (A B C D) do (
  for /l %%i in (1001 1 1100) do set "sStu=!sStu!%%a-%%i"
  set "sStu=!sStu:-1=-!"&  set "base=100"
  for /l %%x in (1 1 10) do (
    for /l %%i in (1 1 10) do (
      set /a "start=(!random!%%base)*5"
      for %%s in (!start!) do (
        set "choose=!sStu:~%%s,5!"
        for %%c in (!choose!) do (
          set "X-%%x=!X-%%x! %%c"
          set "sStu=!sStu:%%c=!"
          set /a base-=1
) ) ) ) )
(echo 开后门之前...)&set X-&pause
(echo 开后门...)&call :backDoor B-060 X-3 11&call :backDoor C-049 X-8 21
(echo 开后门之后...)&set X-&pause
exit /b

:backDoor 学生编号 班编号 班内目标号 如: C-049 安排到 X-8, C 起始于 #21
for /l %%i in (1 1 10) do (
  if /i "X-%%i" neq "%2" (
    (echo !X-%%i!|find /i "%1">nul)&&(
      for /f "tokens=%3 delims= " %%t in ("!%2!") do (
        (echo 调换: X-%%i 班的 %1 ^<==^> %2 班的 %%t )
        set "X-%%i=!X-%%i:%1=%%t!"
        set "%2=!%2:%%t=%1!"
      )  
      exit /b
) ) )
exit /b
复制代码

[ 本帖最后由 neorobin 于 2010-6-28 00:17 编辑 ]

随风

假设两个后门学生都在一个班呢？
又或者都在3班或8班呢？

neorobin

这里换班号的方法是错误的, 13楼, 14楼 有说明

@echo off & setlocal enableDelayedExpansion
for %%c in (A B C D) do (
  set "Max=10"
  for /l %%i in (0 1 9) do (set "ptClass%%i=%%i"& set Cnt%%i=0)
  for /l %%s in (1 1 100) do (
    set /a to_pt=!random! %% !Max!
    set /a "to=ptClass!to_pt!"
    for %%t in (!to!) do (
      set "X-%%t=!X-%%t! %%c-%%s"
      set /a Cnt%%t+=1
      if !Cnt%%t! geq 10 (
        set /a last=Max-1
        set /a tt=ptClass!to_pt!
        set /a ptClass!to_pt!=ptClass!last!
        set /a ptClass!last!=tt
        set /a Max-=1
      )
    )
  )
)
set "X-10=!X-0!"& set "X-0="
for /l %%i in (1 1 10) do set "X-%%i=!X-%%i! "& rem 加入尾部空格防止单数错误替换
echo 开后门之前...
set X-
pause
echo 开后门...
call :backDoor B-60 X-3
call :backDoor C-49 X-8
echo 开后门之后...
set X-
pause 
exit /b

:backDoor 学生编号 班编号 [color=red] 错误后门方法 [/color]
for /l %%i in (1 1 10) do (
  if /i "X-%%i" neq "%2" (
    rem find 后是一个含尾空格的查找串 "%1 ", 避免将1位以上的数字错误处理
    (echo !X-%%i!|find /i "%1 ">nul)&&(
      (echo 调换: %1 所在的 X-%%i 班 ^<==^> %2 班)
      set tt=!X-%%i!& set X-%%i=!%2!& set "%2=!tt!"
      exit /b
    )
  )
)
exit /b
复制代码

[ 本帖最后由 neorobin 于 2010-6-27 23:49 编辑 ]

batman

开窍了，哈哈，是的，任何问题从多个角度上来想，总能找到解决的好办法的。

neorobin

对, 不需要调换学生, 找到所在的班, 直接和想要的班换一下就可以了, 实质上也就是把后门学生所要的班号 换成 所要求的就行了, 比如 B-60 被安排到了 8 班, 那么直接把 8 班看成 3  班, 3 班看成 8 班就行了!

batman

开后门也不难，思路打开点，试试交换法，嘿嘿。。。

neorobin

我的方法是先全部 平等 对待 安排, 之后再找出相应的 班和学生 调换一下(如果已经安排到了所要的班就免调换了)即可,  前部的代码排除了 特殊性, 可以写得简洁

随风

开后门还真是有难度，思考中。。。。。

neorobin

@echo off & setlocal enableDelayedExpansion
for %%c in (A B C D) do (
  set "Max=10"
  for /l %%i in (0 1 9) do (set "ptClass%%i=%%i"& set Cnt%%i=0)
  for /l %%s in (1 1 100) do (
    set /a to_pt=!random! %% !Max!
    set /a "to=ptClass!to_pt!"
    for %%t in (!to!) do (
      set "X-%%t=!X-%%t! %%c-%%s"
      set /a Cnt%%t+=1
      if !Cnt%%t! geq 10 (
        set /a last=Max-1
        set /a tt=ptClass!to_pt!
        set /a ptClass!to_pt!=ptClass!last!
        set /a ptClass!last!=tt
        set /a Max-=1
      )
    )
  )
)
set "X-10=!X-0!"& set "X-0="
for /l %%i in (1 1 10) do set "X-%%i=!X-%%i! "& rem 加入尾部空格防止单数错误替换
echo 开后门之前...
set X-
pause
echo 开后门...
call :backDoor B-60 X-3 11
call :backDoor C-49 X-8 21
echo 开后门之后...
set X-
pause 
exit /b

:backDoor 学生编号 班编号 班内目标号 C-49 安排到 X-8, C 起始于 #21
for /l %%i in (1 1 10) do (
  if /i "X-%%i" neq "%2" (
    (echo !X-%%i!|find /i "%1">nul)&&(
      for /f "tokens=%3 delims= " %%t in ("!%2!") do (
        (echo 调换: X-%%i 班的 %1 ^<==^> %2 班的 %%t )
        set "X-%%i=!X-%%i:%1 =%%t !" & rem 带尾部空格防止双数被当成单数替换, 
        set "%2=!%2:%%t =%1 !"       & rem 例: B-12 会当作 B-1 与 2
      )  
      exit /b
    )
  )
)
exit /b
复制代码

[ 本帖最后由 neorobin 于 2010-6-27 21:38 编辑 ]

随风

应该不难，但要求简洁。。。只怕有难度。

batman

所谓的办法在每个人的心中，呵呵。。。

如觉得有难度，先可不开后门（本来就反对开后门）

[ 本帖最后由 batman 于 2010-6-27 20:44 编辑 ]

Batcher

1、是的，因为题目里面说“同时要求每个班有10名优等生、10名高等生、10名中等生、10名差等生”。
2、B代表高等、C代表中等。

随风

每个班规定40人吗
那两个开后门的是差等生，还是？
那个所谓的办法，能用文字表达一下吗？