[文本处理] [已解决]批处理怎样合并txt文本？

sunflowerr_88

有a、b、c三个文件夹，每个文件夹都有近千个.txt文本，每个文本1K左右大小。要求：１、从这三个文件夹中（顺序、随机均可）各取一个文件，组成一个新的文本文件。２、在合成新文件同时将原文件删除，以确保第二次循环中不重复。
请高手编写一个批处理啊，一次能完成的那种，我是看到代码头就大了那种菜鸟，已经手工合并了N多，实在吃不消了。。。。。
谢谢啊。。。。

[ 本帖最后由 sunflowerr_88 于 2011-1-27 03:05 编辑 ]

sunflowerr_88

经测试，四楼的代码执行成功！二楼的我加了个输出名，可还是不行啊，是不是我太笨了啊。。。。。

hanyeguxing

需要设置一个输出文件夹名
实际测试没发现问题

a\1.txt
b\1.txt
c\1.txt
已复制         1 个文件。
a\2.txt
b\2.txt
c\2.txt
已复制         1 个文件。
a\a.txt
b\a.txt
c\a.txt
已复制         1 个文件。
a\b.txt
b\b.txt
c\b.txt
已复制         1 个文件。
a\cue.txt
b\cue.txt
c\cue.txt
已复制         1 个文件。

[ 本帖最后由 hanyeguxing 于 2010-12-24 03:22 编辑 ]

tmplinshi

思路：
先输出所有文本的路径，输出时在路径前标上数字，每个文件夹都从 1 开始计数，最后用 sort 命令可得出这样的列表：

1:a\复件 4.txt
1:b\2.txt
1:c\2.txt
10:a\复件 复件 5.txt
10:b\list2.txt
10:c\复件 3.txt
11:a\复件 复件 1.txt
11:b\nircmd.txt
11:c\复件 复件 5.txt
...

@echo off
set "文件夹1=a"
set "文件夹2=b"
set "文件夹3=c"
set "输出文件夹=#Output#"

SetLocal EnableDelayedExpansion
md "%输出文件夹%" 2>nul

(for %%d in ("%文件夹1%" "%文件夹2%" "%文件夹3%") do (
    set n=
    for %%f in (%%d\*.txt) do (
        set /a n += 1
        echo !n!:%%f
    )
))>"%temp%\.list"
sort "%temp%\.list" > "%temp%\.list2"

for /f "usebackq tokens=1,* delims=:" %%a in ("%temp%\.list2") do (
    set files_%%a=!files_%%a!+"%%b"
    set /a count_%%a += 1
    if !count_%%a!==3 (
        copy /b !files_%%a:~1! "%输出文件夹%\%%a.txt"
        del /a /f !files_%%a:+= !
        set count_%%a=
        set files_%%a=
    )
)

del "%temp%\.list" "%temp%\.list2"
title 完成
pause
复制代码

[ 本帖最后由 tmplinshi 于 2010-12-24 12:49 编辑 ]

sunflowerr_88

运行过上面的代码了，拒绝访问！我只有三个文件夹，文件夹名就是a,b,c，将上述代码中的
set a=a目录名
set b=b目录名
set c=c目录名
set d=d目录名（输出目录）
改成了以下
set a=a
set b=b
set c=c
还需要改什么吗？谢谢
另外，这个批处理文件我将其与这三个文件夹放在同一文件夹中，对不对？

hanyeguxing

ps：标题不符合版规

@echo off&setlocal enabledelayedexpansion
set a=a目录名
set b=b目录名
set c=c目录名
set d=d目录名（输出目录）
md "%d%\"
for %%a in ("%a%\*.txt") do set/a a_+=1&set #!a_!=%%~na
for %%a in ("%b%\*.txt") do set/a b_+=1&set @!b_!=%%~na
for %%a in ("%c%\*.txt") do (
        set/a c_+=1
        if defined #!c_! if defined @!c_! for %%b in (!c_!) do (
                copy /b "%a%\!#%%b!%%~xa" + /b "%b%\!@%%b!%%~xa" + /b "%%a" "%d%\%%~nxa"
                del /a/q/f "%a%\!#%%b!%%~xa"
                del /a/q/f "%b%\!@%%b!%%~xa"
                del /a/q/f "%%a"
))
复制代码

[ 本帖最后由 hanyeguxing 于 2010-12-24 02:20 编辑 ]