[文本处理] [已解决]批处理结合WMIC获取文件路径怎样去掉行末带换行？

escortmnm

用wmic命令的datefile全盘查找指定扩展名的文件并获取其全名的代码：

@echo off
echo 正在搜索，请等待……
for /f "skip=1 tokens=* eol=" %%a in ('wmic datafile where "Extension='mof'" get name') do (
echo "%%a")
pause
复制代码

输出的结果如下：

可以发现获取到的文件名后面莫名其妙地多了个换行符，导致双引号的第二半被换行了。
如何解决？
怎样才能让获取到的文件是个真实的路径即通过判断文件存在检验是否满足条件：

@echo off
echo 正在搜索，请等待……
for /f "skip=1 tokens=* eol=" %%a in ('wmic datafile where "Extension='mof'" get name') do (
if not exist "%%a" echo 如果显示了本句话，测试失败。)
pause
复制代码

请知道的朋友不吝赐教,小弟感激不尽!

for/f的参数我没设置好，不知如何设置才能得到我希望得到的效果。

escortmnm

嗯，没用过WIN7，我现在用的是XP。问题刚刚已经解决了，方法如下：

@echo off&setlocal enabledelayedexpansion
echo 正在搜索，请等待……
for /f "skip=1 delims=" %%a in ('wmic datafile where "Extension='ppt'" get name') do (
set n=%%a
set n=!n:~,-1!
echo !n!
if not exist "!n!" echo 如果显示了本句话，测试失败。)
pause
复制代码

方法：
用set命令将获取到的参数的最后一个字符删除。

Batcher

2# zm900612


跟unicode没啥关系，是行尾多了换行符，XP特有的问题，Vista/Win7里面不存在。

Batcher

批处理全盘搜索指定文件获取其完整路径
http://bbs.bathome.net/thread-3465-1-1.html

hanyeguxing

1，如果数据不带空格或其他敏感字符，使用call传递
2，如果有，可以使用变量截取
3，不推荐使用 wmic datafile

escortmnm

2# zm900612

我的是XPSP3系统，用了你的代码还是没成功：

@echo off&setlocal enabledelayedexpansion
echo 正在搜索，请等待……
for /f "skip=1 tokens=*" %%a in ('wmic datafile where "Extension='ppt'" get name ^|more') do (
echo %%a
if not exist "%%a" echo 如果显示了本句话，测试失败。)
pause
复制代码

代码有不对的地方吗？

CrLf

win7系统吧？wmic输出的是unicode格式，我喜欢这样转成ansi：
for /f ... in ('wmic datafile where "Extension='mof'" get name^|more') do ...