[文本处理] [已解决]批处理如何让文本中奇、偶数行合并成一行

batpro

说明：鉴于旧贴有表达不清的嫌疑，现修改题目要求，忘高手搭救！

1.txt中【原始文本】

[AmdK8 Compatible Device / AmdK8][Stopped/Manual Start]
<System32\drivers\amdk8.sys><Advanced Micro Devices>
[aswFsBlk / aswFsBlk][Running/Auto Start]
  <system32\DRIVERS\aswFsBlk.sys><ALWIL Software>
[NDIS Miniport Driver for Atheros L2 Fast Ethernet Controller / AtcL002][Running/Manual Start]
  <system32\DRIVERS\l251x86.sys><Atheros Communications, Inc.>
复制代码

如何得到这样的2.txt：


2.txt的内容为

[AmdK8 Compatible Device / AmdK8][Stopped/Manual Start]<System32\drivers\amdk8.sys><Advanced Micro Devices>
[aswFsBlk / aswFsBlk][Running/Auto Start]<system32\DRIVERS\aswFsBlk.sys><ALWIL Software>
[NDIS Miniport Driver for Atheros L2 Fast Ethernet Controller / AtcL002][Running/Manual Start]<system32\DRIVERS\l251x86.sys><Atheros Communications, Inc.>
复制代码

谢谢

CrLf

@echo off
for /f "tokens=*" %%a in (1.txt) do (
   set line=%%a
   setlocal enabledelayedexpansion
   set "out=!out!!line!"
   set /a n=!n,"1/n"||echo !out!&&set out=
   for /f "tokens=1*" %%b in ("!n! !out!") do (
      endlocal
      set "n=%%b"
      set "out=%%c"
   )
)>2.txt 2>nul
复制代码

Batcher

gawk "NR%2{printf $0;next}1" a.txt | more >b.txt
复制代码

http://bbs.bathome.net/thread-1114-1-1.html

mxxcgzxxx

7改过了，测试达效果，不过如果有!^就不能显示了

caruko

@echo off>2.txt&set n=1
FOR /f "delims=" %%1 in (1.txt) do (
2>nul    set /a n+=1,f=n%%2,1/f&&echo,%%1||set/p=%%1<nul
) >>2.txt
复制代码

已测试

batpro

7# mxxcgzxxx


已测试，失败

mxxcgzxxx

@echo off&setlocal enabledelayedexpansion
cd.>2.txt
set n=1
FOR /f "tokens=*" %%1 in (1.txt) do (
                  if !n!==1 (
                   set /p=%%1<nul >>2.txt
                   )  else (
                   echo %%1>>2.txt
                   set n=0
                   ) 
         set /a n+=1
          )
复制代码

自己写语法错了，改了，可以达到效果不过 ！^等特殊符号过不了关

batpro

5# Batcher


谢谢管理员，终于明白了sed的强大，让困扰我好多天的问题得以解决，谢谢
顺便问一句，如果不借助第三方工具，单纯用bat能解决这个问题么？

Batcher

sed "$!N;s/\n//" a.txt | more >b.txt
复制代码

http://bbs.bathome.net/thread-1114-1-1.html

batpro

谢谢大家 辛苦 ，尽管还是不懂

Batcher

grep -B 1 "<system32\\DRIVERS\\eamon.sys>" a.txt | more >b.txt
复制代码

http://bbs.bathome.net/thread-1114-1-1.html

tmplinshi

@echo off
setlocal enabledelayedexpansion

for %%i in (
    "<system32\DRIVERS\eamon.sys><N/A>"
    "<system32\DRIVERS\easdrv.sys><N/A>"
    "<system32\DRIVERS\epfwtdir.sys><N/A>"
) do set %%~i=#

for /f "tokens=*" %%i in (1.txt) do (
    if defined %%i (
        >>2.txt echo !last_line!             %%i
        >>3.txt echo 驱动名称：!last_line!
        >>3.txt echo 对应路径：%%i
    )
    set last_line=%%i
)

pause
复制代码