[文本处理] [已解决]如何用批处理批量添加指定内容？

batpro

在文本1.txt中可能会有

C:\WINDOWS\system32\hNdcS96gQxDk.dll
C:\WINDOWS\system32\122B901E.dll
C:\WINDOWS\system32\A0C86020.dll
C:\WINDOWS\system32\xg4hAPNygs29.dll
C:\WINDOWS\system32\zvadNUhWHnAA69wD.dll
C:\WINDOWS\system32\76B9BA7A.dll
------------------------------------------------
ndxq9awMc.dll
y7YFM8BwXchaasyQ.dll
VBw9ZHsJt3M8tVgF.fon
CDuAUVkGy9.dll
Va7SpUWgCA5f.dll
复制代码

如何生成这样的2.txt

C:\WINDOWS\system32\hNdcS96gQxDk.dll
C:\WINDOWS\system32\122B901E.dll
C:\WINDOWS\system32\A0C86020.dll
C:\WINDOWS\system32\xg4hAPNygs29.dll
C:\WINDOWS\system32\zvadNUhWHnAA69wD.dll
C:\WINDOWS\system32\76B9BA7A.dll
------------------------------------------------
C:\WINDOWS\system32\ndxq9awMc.dll
C:\WINDOWS\system32\y7YFM8BwXchaasyQ.dll
C:\WINDOWS\system32\VBw9ZHsJt3M8tVgF.fon
C:\WINDOWS\system32\CDuAUVkGy9.dll
C:\WINDOWS\system32\Va7SpUWgCA5f.dll
复制代码

谢谢

CrLf

@echo off
cd /d C:\WINDOWS\system32\
(for /f "delims=" %%a in (%~sdp01.txt) do (
   if "%%~xa"=="" (
      echo %%~fa
   ) else echo %%a
))>2.txt
复制代码

CUer

sed "/^C:\|^---/!{s/^/C:\\WINDOWS\\system32\\/}" a.txt >b.txt
复制代码

lvsehuaxue

@echo off&setlocal enabledelayedexpansion
(for /f "delims=" %%i in (a.txt) do (
    set "str=%%i"
    if "!str!" neq "!str:C:\WINDOWS\system32\=!" (
        echo %%i
        ) else (
         if "!str:~,1!" equ "-" (echo %%i
             ) else (
             echo C:\WINDOWS\system32\%%i
             )
        )
))>2.txt
复制代码

ArdentMan

@Echo Off&SetLocal EnableDelayedExpansion
(For /F "delims=" %%i In (1.txt) Do (
  Set "Str=%%i"
  If Not Defined Mpath Set "Mpath=%%~dpi"
  If "!Str:~,1!" NEQ "-" (
    Echo !Mpath!\%%~nxi
    ) Else (
    Echo %%i
  )
))>2.txt
Start 2.txt 
复制代码

batpro

注意这些
ndxq9awMc.dll
y7YFM8BwXchaasyQ.dll
VBw9ZHsJt3M8tVgF.fon
CDuAUVkGy9.dll
Va7SpUWgCA5f.dll
只是例子而已，有可能为不同值