[文本处理] 【已解决】批处理怎样将两个txt文本行行对应合并成一行？

思想之翼

01_1.txt数据格式为
0
1
2
3
4
5
6
7
8
9
01_2.txt数据格式为
9
8
7
6
5
4
3
2
1
0
欲合并为一个新建的txt文本，数据格式为
0  9
1  8
2  7
3  6
4  5
5  4
6  3
7  2
8  1
9  0
实际运用中txt文本不仅仅2个。
恳望得到大家的帮助！

思想之翼

谢谢各位鼎力帮助！代码全部能够完美解决问题。

xxpinqz

这个，还是6楼的强悍...

tmplinshi

paste.exe -d " " *.txt >__all.txt
复制代码

paste 下载地址: http://www.bathome.net/thread-1114-1-1.html

xxpinqz

上面那个是独立合并，这个是全部合并

@echo off
setlocal enabledelayedexpansion
for %%a in (*.txt) do set "fn=!fn! "%%a""
call :sc!fn!
exit /b
:sc
set n=10000
for /f "delims=" %%a in (%~1) do (
set /a n+=1
for %%b in (!n!) do set "#%%b=!#%%b! %%a"
)
if not "%~2"=="" (
  shift /1
) else (
  (for /f "tokens=1* delims== " %%c in ('set #') do echo,%%d)>all_.txt
  goto :eof
)
goto sc
复制代码

xxpinqz

@echo off
for %%i in (*_1.txt) do (
for /f "delims=_" %%j in ("%%~ni") do set fstr=%%j
setlocal enabledelayedexpansion
for %%a in (!fstr!_*.txt) do set "fn=!fn! "%%a""
echo 处理!fstr!_*.txt。。。。。
call :sc!fn!
endlocal
)
ren *.$$$ *.txt
exit /b
:sc
set n=10000
for /f "delims=" %%a in (%~1) do (
set /a n+=1
for %%b in (!n!) do set "#%%b=!#%%b! %%a"
)
if not "%~2"=="" (
  shift /1
) else (
  (for /f "tokens=1* delims== " %%c in ('set #') do echo %%d)>all_!fstr!.$$$
  goto :eof
)
goto sc
复制代码

思想之翼

回复 2# xxpinqz

感谢您的热心帮助！您的批处理代码，经试验，可以将2个txt文本并列合并。
可能是叙述有误，我希望将所有txt文本，按排列顺序并列合并到一个txt文本，合并后的数据格式是：
5 4 9 ... 6 2
1 5 2 ... 8 8
7 3 5 ... 4 7
4 6 1 ... 1 3
2 7 7 ... 3 6
9 2 0 ... 2 1
0 8 3 ... 9 4
8 9 6 ... 0 0
6 1 8 ... 7 9
3 0 4 ... 5 5
恳望继续得到您的帮助！

xxpinqz

@echo off&setlocal enabledelayedexpansion
for %%a in (*_1.txt) do (
  set "fn=%%~na"
  set "fn=!fn:~,-1!"
  if exist "!fn!2.txt" (
  	for /f "delims=" %%b in ('type "%%a"') do (
  	set /p str=
  	echo %%b !str!
  	)
  )<"!fn!2.txt">"!fn!1+2.txt"
)
复制代码