[数值计算] [已解决]批处理如何统计三个在指定范围内的数字的和为指定值的组合有多少种？

xpw

牵扯到call语句或goto语句在for 语句中的应用，这个我不是很明白，所以一直没有正确计算出，是要再加点什么吗？

@echo off &setlocal enabledelayedexpansion
set num3=0
set num4=0
set num5=0
set num6=0
set num7=0
set num8=0
set num9=0
set num10=0
set num11=0
set num12=0
set num13=0
set num14=0
set num15=0
set sum=0
for /l %%a in (1 1 5) do (
   for /l %%b in (1 1 5) do (
      for /l %%c in (1 1 5) do (
set /a sum=%%a+%%b+%%c
call :!sum!
  )
 )
)
echo 3的组合有!num3!种
echo 4的组合有!num4!种
echo 5的组合有!num5!种
echo 6的组合有!num6!种
echo 7的组合有!num7!种
echo 8的组合有!num8!种
echo 3的组合有!num9!种
echo 10的组合有!num10!种
echo 11的组合有!num11!种
echo 12的组合有!num12!种
echo 13的组合有!num13!种
echo 14的组合有!num14!种
echo 15的组合有!num15!种
pause>nul

:3
set /a num3+=1

:4
set /a num4+=1

:5
set /a num5+=1

:6
set /a num6+=1

:7
set /a num7+=1

:8
set /a num8+=1

:9
set /a num9+=1

:10
set /a num10+=1

:11
set /a num11+=1

:12
set /a num12+=1

:13
set /a num13+=1

:14
set /a num14+=1

:15
set /a num15+=1
复制代码

apang

哦，是算排列啊，楼主应该改下标题

523066680

这让我想起比赛 第3题

@echo off
setlocal enabledelayedexpansion

set au=AAAAA
set bu=BBBBB
set cu=CCCCC
set du=DDDDD

set /a n=0
for /l %%a in (1 1 5) do (
   for /l %%b in (1 1 5) do (
      for /l %%c in (1 1 5) do (
         for /l %%d in (1 1 5) do (
            set /a sum=%%a+%%b+%%c+%%d
            if !sum! equ 8 (
               set /a n+=1
               echo %%a%%b%%c%%d !au:~0,%%a!!bu:~0,%%b!!cu:~0,%%c!!du:~0,%%d!
            )
         )
      )
   )
)
echo 有%n%个结果
pause
复制代码

有ABCD四组元素，随机组成8位字符，每组至少出现一次。
那么不同次数全列出来，有多少种形式呢？(未排列的情况下)

1115 ABCDDDDD
1124 ABCCDDDD
1133 ABCCCDDD
1142 ABCCCCDD
1151 ABCCCCCD
1214 ABBCDDDD
1223 ABBCCDDD
1232 ABBCCCDD
1241 ABBCCCCD
1313 ABBBCDDD
1322 ABBBCCDD
1331 ABBBCCCD
1412 ABBBBCDD
1421 ABBBBCCD
1511 ABBBBBCD
2114 AABCDDDD
2123 AABCCDDD
2132 AABCCCDD
2141 AABCCCCD
2213 AABBCDDD
2222 AABBCCDD
2231 AABBCCCD
2312 AABBBCDD
2321 AABBBCCD
2411 AABBBBCD
3113 AAABCDDD
3122 AAABCCDD
3131 AAABCCCD
3212 AAABBCDD
3221 AAABBCCD
3311 AAABBBCD
4112 AAAABCDD
4121 AAAABCCD
4211 AAAABBCD
5111 AAAAABCD
有35个结果

xpw

楼主如果用Call可以这样

            [此处省略若干代码]
          set /a sum=%%a+%%b+%%c
         ...
PakTC 发表于 2013-7-29 22:14

    看来我思路还不够简捷，没想到可以这样做

xpw

PakTC 发表于 2013-7-29 21:58

3个[1-5]范围内的数字和为3 的情况有：1 种
3个[1-5]范围内的数字和为4 的情况有：3 种
3个[1-5]范围内的数字和为5 的情况有：6 种
3个[1-5]范围内的数字和为6 的情况有：10 种
3个[1-5]范围内的数字和为7 的情况有：15 种
3个[1-5]范围内的数字和为8 的情况有：18 种
3个[1-5]范围内的数字和为9 的情况有：19 种
3个[1-5]范围内的数字和为10 的情况有：18 种
3个[1-5]范围内的数字和为11 的情况有：15 种
3个[1-5]范围内的数字和为12 的情况有：10 种
3个[1-5]范围内的数字和为13 的情况有：6 种
3个[1-5]范围内的数字和为14 的情况有：3 种
3个[1-5]范围内的数字和为15 的情况有：1 种

    就是要这个计算结果！

xpw

回复 3# apang

把for 嵌套改成：
for /l %%a in (1 1 5) do (
    for /l %%b in (1 1 5)do (
        for /l %%c in(1 1 5)do (...)
计算出来的结果就对了

PakTC

楼主如果用Call可以这样

            [此处省略若干代码]
          set /a sum=%%a+%%b+%%c
          call :func !sum!
            [此处省略若干代码]

:func
set /a num%1+=1

PakTC

回复 6# apang


    没去注意，直接用楼主的改的。
只是告诉楼主重复句子多了。
还有就是没有goto :eof

apang

回复 4# PakTC


    这是排列个数吧？

PakTC

回复 1# xpw


    错误在于
:3
set /a num3+=1

:4
set /a num4+=1

:5
set /a num5+=1

每个环节之间没有用goto :eof
如果你调用了:3 ， 那么从:3到:15的所有公式都+1。
这些数值被重复计算了。

PakTC

@echo off &setlocal enabledelayedexpansion
for /l %%i in (3,1,15) do (
    set /a N[%%i]=0
)

set /a sum=0
for /l %%a in (1 1 5) do (
   for /l %%b in (1 1 5) do (
      for /l %%c in (1 1 5) do (
          set /a sum=%%a+%%b+%%c
          set /a N[!sum!]+=1
  )
 )
)
for /l %%i in (3,1,15) do (
    echo 3个[1-5]范围内的数字和为%%i 的情况有：!N[%%i]! 种
)
pause
复制代码

apang

不敢确定，这样算对不对？

@echo off&setlocal enabledelayedexpansion
for /l %%a in (3 1 15) do set /a s%%a=0
set /a num=0
for /l %%a in (1 1 5) do (
   for /l %%b in (%%a 1 5) do (
      for /l %%c in (%%b 1 5) do (
         set /a num=%%a+%%b+%%c
         set /a s!num!+=1
      )
   )
)
for /l %%a in (3 1 15) do echo,%%a的组合有!s%%a!种
pause>nul
复制代码

PakTC

你是说  有3个数，范围是1-5，求和为N的情况有多少种组合？