[文本处理] 【已解决】批处理命令for如何截取一个路径中的程序名字？

szl1123

比如
C:\Program Files\kuwo\kuwomusic\KwMusic.exe
C:\Program Files (x86)\Tencent\QQ\QQProtect\Bin\QQProtect.exe

要截取KwMusic.exe QQProtect.exe并赋值到变量到%sky%。

其中路径是不确定的，就是要获取最后一个“\”后面的内容并赋值到变量到%sky%。

szl1123

DAIC 发表于 2014-8-16 16:47

    非常感谢，代码简洁正，式我需要的。
另外也感谢楼上其他几位。

在补充一下，来自 for /?：

另外，FOR 变量参照的替换已被增强。您现在可以使用下列
选项语法:

     %~I          - 删除任何引号(")，扩展 %I
     %~fI        - 将 %I 扩展到一个完全合格的路径名
     %~dI        - 仅将 %I 扩展到一个驱动器号
     %~pI        - 仅将 %I 扩展到一个路径
     %~nI        - 仅将 %I 扩展到一个文件名
     %~xI        - 仅将 %I 扩展到一个文件扩展名
     %~sI        - 扩展的路径只含有短名
     %~aI        - 将 %I 扩展到文件的文件属性
     %~tI        - 将 %I 扩展到文件的日期/时间
     %~zI        - 将 %I 扩展到文件的大小
     %~$PATH:I   - 查找列在路径环境变量的目录，并将 %I 扩展
                   到找到的第一个完全合格的名称。如果环境变量名
                   未被定义，或者没有找到文件，此组合键会扩展到
                   空字符串

可以组合修饰符来得到多重结果:

     %~dpI       - 仅将 %I 扩展到一个驱动器号和路径
     %~nxI       - 仅将 %I 扩展到一个文件名和扩展名
     %~fsI       - 仅将 %I 扩展到一个带有短名的完整路径名
     %~dp$PATH:I - 搜索列在路径环境变量的目录，并将 %I 扩展
                   到找到的第一个驱动器号和路径。
     %~ftzaI     - 将 %I 扩展到类似输出线路的 DIR

在以上例子中，%I 和 PATH 可用其他有效数值代替。%~ 语法
用一个有效的 FOR 变量名终止。选取类似 %I 的大写变量名
比较易读，而且避免与不分大小写的组合键混淆。
复制代码

DAIC

@echo off
set "str=C:\Program Files\kuwo\kuwomusic\KwMusic.exe"
:loop
set "sky=%str:*\=%"
if "%sky%" equ "%str%" (
    echo %sky%
) else (
    set str=%sky%
    goto :loop
)
pause
复制代码

DAIC

@echo off
for %%i in ("C:\Program Files\kuwo\kuwomusic\KwMusic.exe") do (
    set "sky=%%~nxi"
)
echo,%sky%
pause
复制代码

apang

回复 2# 浪子神剑


    可以合起来写： %%~nxi

浪子神剑

回复 1# szl1123

没赋值到变量，把路径复制到文本path.txt中

@echo off

for /f "delims=" %%i in (path.txt) do (
	echo %%~ni%%~xi
)

pause
复制代码