[文本处理] 紧急求助:删除指定路径下指定天数之前（以文件的创建日期为准）的文件

shugeer

我采用的是这个帖子的方案四(以文件的创建日期为准),在演示过程中我的文件创建日期不在指定的范围内也会删除,这是为什么?
http://bbs.bathome.net/thread-3334-1-1.html

Batcher

回复 8# shugeer


是的。
如果你的系统默认日期格式是 yyyy/mm/dd 的话，可以把注册表相关的语句全部删掉。

@echo off
::演示：删除指定路径下指定天数之前（以文件的创建日期为准）的文件。
::如果演示结果无误，把del前面的echo去掉，即可实现真正删除。

rem 指定待删除文件的存放路径
set SrcDir=D:\DCIM\823WGTMA
rem 指定天数
set DaysAgo=42

call :DateToDays %date:~0,4% %date:~5,2% %date:~8,2% PassDays
set /a PassDays-=%DaysAgo%
call :DaysToDate %PassDays% DstYear DstMonth DstDay
set DstDate=%DstYear%/%DstMonth%/%DstDay%

for /f "delims=/" %%a in ('dir /s /b /a-d "%SrcDir%"') do (
    call :CompareTime "%%a"
)
pause
goto :eof

:DateToDays %yy% %mm% %dd% days
setlocal ENABLEEXTENSIONS
set yy=%1&set mm=%2&set dd=%3
if 1%yy% LSS 200 if 1%yy% LSS 170 (set yy=20%yy%) else (set yy=19%yy%)
set /a dd=100%dd%%%100,mm=100%mm%%%100
set /a z=14-mm,z/=12,y=yy+4800-z,m=mm+12*z-3,j=153*m+2
set /a j=j/5+dd+y*365+y/4-y/100+y/400-2472633
endlocal&set %4=%j%&goto :EOF

:DaysToDate %days% yy mm dd
setlocal ENABLEEXTENSIONS
set /a a=%1+2472632,b=4*a+3,b/=146097,c=-b*146097,c/=4,c+=a
set /a d=4*c+3,d/=1461,e=-1461*d,e/=4,e+=c,m=5*e+2,m/=153,dd=153*m+2,dd/=5
set /a dd=-dd+e+1,mm=-m/10,mm*=12,mm+=m+3,yy=b*100+d-4800+m/10
(if %mm% LSS 10 set mm=0%mm%)&(if %dd% LSS 10 set dd=0%dd%)
endlocal&set %2=%yy%&set %3=%mm%&set %4=%dd%&goto :EOF

:CompareTime
for /f "skip=5 tokens=1-2 delims= " %%h in ('dir /a-d /tc %1') do (
    if "%%h" leq "%DstDate%" (
        if exist %1 (
            echo del /a /f /q %1
        )
    )
    goto :eof
)
复制代码

shugeer

回复 6# Batcher

我把代码中日期的"-"符号改为"/"竟然可以了,谢谢Batcher 大神!

@echo off
::演示：删除指定路径下指定天数之前（以文件的创建日期为准）的文件。
::如果演示结果无误，把del前面的echo去掉，即可实现真正删除。

rem 指定待删除文件的存放路径
set SrcDir=D:\DCIM\823WGTMA
rem 指定天数
set DaysAgo=42
for /f "delims=" %%a in ('reg query "HKEY_CURRENT_USER\Control Panel\International" /v sShortDate') do (
    set "RegDateOld=%%a"
)
set RegDateOld=%RegDateOld:~-8%
reg add "HKEY_CURRENT_USER\Control Panel\International" /v sShortDate /t REG_SZ /d yyyy/M/d /f>nul
call :DateToDays %date:~0,4% %date:~5,2% %date:~8,2% PassDays
reg add "HKEY_CURRENT_USER\Control Panel\International" /v sShortDate /t REG_SZ /d %RegDateOld% /f>nul
set /a PassDays-=%DaysAgo%
call :DaysToDate %PassDays% DstYear DstMonth DstDay
set DstDate=%DstYear%/%DstMonth%/%DstDay%

for /f "delims=/" %%a in ('dir /s /b /a-d "%SrcDir%"') do (
    call :CompareTime "%%a"
)
reg add "HKEY_CURRENT_USER\Control Panel\International" /v sShortDate /t REG_SZ /d %RegDateOld% /f>nul
pause
goto :eof

:DateToDays %yy% %mm% %dd% days
setlocal ENABLEEXTENSIONS
set yy=%1&set mm=%2&set dd=%3
if 1%yy% LSS 200 if 1%yy% LSS 170 (set yy=20%yy%) else (set yy=19%yy%)
set /a dd=100%dd%%%100,mm=100%mm%%%100
set /a z=14-mm,z/=12,y=yy+4800-z,m=mm+12*z-3,j=153*m+2
set /a j=j/5+dd+y*365+y/4-y/100+y/400-2472633
endlocal&set %4=%j%&goto :EOF

:DaysToDate %days% yy mm dd
setlocal ENABLEEXTENSIONS
set /a a=%1+2472632,b=4*a+3,b/=146097,c=-b*146097,c/=4,c+=a
set /a d=4*c+3,d/=1461,e=-1461*d,e/=4,e+=c,m=5*e+2,m/=153,dd=153*m+2,dd/=5
set /a dd=-dd+e+1,mm=-m/10,mm*=12,mm+=m+3,yy=b*100+d-4800+m/10
(if %mm% LSS 10 set mm=0%mm%)&(if %dd% LSS 10 set dd=0%dd%)
endlocal&set %2=%yy%&set %3=%mm%&set %4=%dd%&goto :EOF

:CompareTime
for /f "skip=5 tokens=1-2 delims= " %%h in ('dir /a-d /tc %1') do (
    if "%%h" leq "%DstDate%" (
        if exist %1 (
            echo del /a /f /q %1
        )
    )
    goto :eof
)
复制代码

shugeer

回复 6# Batcher
我的是win8系统，执行批处理可能不够权限修改注册表，
现在已经用你4楼给出的命令手动修改日期为这种格式了"2014-09-04"，是可以了!
我的系统系统要默认用"2014/09/04"这种格式的,能否帮我修改下代码?
谢谢!

Batcher

回复 5# shugeer


这个结果看起来没有问题。
一般来说修改注册表之后，第50行%%h获取的值应该是"2014-09-04"这种格式，而不应该是"2014/09/04"这种。
你在第49行上面加个延时看看能否解决问题：
ping -n 10 127.1 >nul

shugeer

回复 4# Batcher

结果如下:
C:\Users\EGNTT>reg add "HKEY_CURRENT_USER\Control Panel\International" /v sShor
Date /t REG_SZ /d yyyy-M-d /f
操作成功完成。

C:\Users\EGNTT>reg query "HKEY_CURRENT_USER\Control Panel\International" /v sSh
rtDate

HKEY_CURRENT_USER\Control Panel\International
    sShortDate    REG_SZ    yyyy-M-d


C:\Users\EGNTT>dir /a-d /tc
驱动器 C 中的卷没有标签。
卷的序列号是 EE81-3F3B

C:\Users\EGNTT 的目录

2014-08-17  09:09           153,956 gpreport.html
2014-08-01  12:44         3,932,160 NTUSER.DAT
2014-08-01  12:44           565,248 ntuser.dat.LOG1
2014-08-01  12:44                 0 ntuser.dat.LOG2
2014-08-01  12:44            65,536 NTUSER.DAT{2b468684-d713-11e1-8545-a4badb40
f56}.TM.blf
2014-08-01  12:44           524,288 NTUSER.DAT{2b468684-d713-11e1-8545-a4badb40
f56}.TMContainer00000000000000000001.regtrans-ms
2014-08-01  12:44           524,288 NTUSER.DAT{2b468684-d713-11e1-8545-a4badb40
f56}.TMContainer00000000000000000002.regtrans-ms
2014-08-01  12:44                20 ntuser.ini
2014-08-01  12:44               468 ntuser.pol
               9 个文件      5,765,964 字节
               0 个目录 54,564,569,088 可用字节

C:\Users\EGNTT>

Batcher

回复 3# shugeer


打开一个CMD窗口，依次执行这三个命令：
reg add "HKEY_CURRENT_USER\Control Panel\International" /v sShortDate /t REG_SZ /d yyyy-M-d /f
reg query "HKEY_CURRENT_USER\Control Panel\International" /v sShortDate
dir /a-d /tc

结果发出来
不用截图，我能看到结果就行。

shugeer

回复 2# Batcher

加入上面代码后显示如下面(抱歉上传不了图片):del /a /f /q "D:\DCIM\823WGTMA\IMG_1197.JPG"
"2014/09/04" leq "2014-08-31"
del /a /f /q "D:\DCIM\823WGTMA\IMG_1218.JPG"
"2014/09/04" leq "2014-08-31"
del /a /f /q "D:\DCIM\823WGTMA\IMG_1219.JPG"
"2014/09/04" leq "2014-08-31"

这些文件是2014/09/04日创建的，距今计算日期是41天，我现在设置了日期为45天之前的，但现在还是删除了
应该是日期计算的错误，求Batcher大神修改下,谢谢!

原代码如下

@echo off
::演示：删除指定路径下指定天数之前（以文件的创建日期为准）的文件。
::如果演示结果无误，把del前面的echo去掉，即可实现真正删除。
::本例调用了 Ritchie Lawrence 的日期函数进行日期计算
::日期转换的核心算法请参考http://bbs.bathome.cn/thread-3056-1-1.html
::本例为兼容不同的日期格式，调用reg命令（XP系统自带）统一设置日期格式，
::处理完毕之后再把日期格式恢复成原来的状态。

rem 指定待删除文件的存放路径
set SrcDir=D:\DCIM\823WGTMA
rem 指定天数
set DaysAgo=45
for /f "delims=" %%a in ('reg query "HKEY_CURRENT_USER\Control Panel\International" /v sShortDate') do (
    set "RegDateOld=%%a"
)
set RegDateOld=%RegDateOld:~-8%
reg add "HKEY_CURRENT_USER\Control Panel\International" /v sShortDate /t REG_SZ /d yyyy-M-d /f>nul
call :DateToDays %date:~0,4% %date:~5,2% %date:~8,2% PassDays
reg add "HKEY_CURRENT_USER\Control Panel\International" /v sShortDate /t REG_SZ /d %RegDateOld% /f>nul
set /a PassDays-=%DaysAgo%
call :DaysToDate %PassDays% DstYear DstMonth DstDay
set DstDate=%DstYear%-%DstMonth%-%DstDay%

for /f "delims=/" %%a in ('dir /s /b /a-d "%SrcDir%"') do (
    call :CompareTime "%%a"
)
reg add "HKEY_CURRENT_USER\Control Panel\International" /v sShortDate /t REG_SZ /d %RegDateOld% /f>nul
pause
goto :eof

:DateToDays %yy% %mm% %dd% days
setlocal ENABLEEXTENSIONS
set yy=%1&set mm=%2&set dd=%3
if 1%yy% LSS 200 if 1%yy% LSS 170 (set yy=20%yy%) else (set yy=19%yy%)
set /a dd=100%dd%%%100,mm=100%mm%%%100
set /a z=14-mm,z/=12,y=yy+4800-z,m=mm+12*z-3,j=153*m+2
set /a j=j/5+dd+y*365+y/4-y/100+y/400-2472633
endlocal&set %4=%j%&goto :EOF

:DaysToDate %days% yy mm dd
setlocal ENABLEEXTENSIONS
set /a a=%1+2472632,b=4*a+3,b/=146097,c=-b*146097,c/=4,c+=a
set /a d=4*c+3,d/=1461,e=-1461*d,e/=4,e+=c,m=5*e+2,m/=153,dd=153*m+2,dd/=5
set /a dd=-dd+e+1,mm=-m/10,mm*=12,mm+=m+3,yy=b*100+d-4800+m/10
(if %mm% LSS 10 set mm=0%mm%)&(if %dd% LSS 10 set dd=0%dd%)
endlocal&set %2=%yy%&set %3=%mm%&set %4=%dd%&goto :EOF

:CompareTime
for /f "skip=5 tokens=1-2 delims= " %%h in ('dir /a-d /tc %1') do (
echo "%%h" leq "%DstDate%"
    if "%%h" leq "%DstDate%" (
        if exist %1 (
            echo del /a /f /q %1
        )
    )
    goto :eof
)
复制代码

Batcher

在第50行代码上面加一行：
echo "%%h" leq "%DstDate%"
测试结果发出来看看