[文本处理] [已解决]在批处理for语句中 如何引用“=”号？

慕夜蓝化

先详述一下问题。
起初是打算将文本中的大写字母都替换为小写字母，写不出来=。=
就去搜索了一下代码。。。
然后：

@echo off
setlocal enabledelayedexpansion
set str=A=a B=b C=c D=d E=e F=f G=g H=h I=i J=j K=k L=l M=m N=n O=o P=p Q=q R=r S=s T=t U=u V=v W=w X=x Y=y Z=z
set /p inp=输入大写字母：
for %%i in (!str!) do (
set inp=!inp:%%i!
)
echo !inp!
pause
复制代码

我的原意是将输入的大写字母替换为小写字母，但是for 命令默认是将 “=”作为分隔符的，这样一来命令就是错误的。。
还有、将文本中的所有大写字母替换为小写字母，批处理应该可以实现吧。。
初学者，命令还很生疏，求教应该怎么做？
以上这串命令又该怎么修改呢？
我见有人用 for /f ，我对for /f 最大的感受，是以行为基本，来对字符串进行操作的，而提取字符串中的独立元素、循环，使用 for /f 能解决这个问题吗？
最后，批处理之家的一日一教学命令，基本上都看完了，基础还是有些的；大家尽管说好了，有不明白的，我会直接说出来的。
先谢过！

yiwuyun

学习了，原来大小写字母可以这样转换。我一般是用序号来转的。

慕夜蓝化

回复 2# apang
真的很感谢，以上两种方法都可以，只是对for和set命令还有好多不了解的地方，慢慢来！

apang

set "str=%str:A=a%" 与 set "str=%str:a=a%" 效果一样
也就是，替换之前的字符不区分大小写，替换之后的字符才区分大小写

所以顶楼代码可以这样子：

@echo off
setlocal enabledelayedexpansion
set "str=a b c d e f g h i j k l m n o p q r s t u v w x y z"
set /p inp=输入大写字母：
for %%i in (!str!) do (
        set "inp=!inp:%%i=%%i!"
)
echo,!inp!
pause
复制代码

如果一定要用 set str=A=a B=b C=c...
那就先把等号两端的字符用双引号包围起来（转义），像这样：

for %%i in ("!str: =" "!") do (
        set "inp=!inp:%%~i!"
)
复制代码