[其他] [已解决]bat中如何转义并实现如下代码

shootman2

@echo off
setlocal enabledelayedexpansion
set deploy_cmd_file=d:\appDeploy.txt
echo off>"%deploy_cmd_file%"
set fileList=d:\WebContent_20150328.zip
set fileName=WebContent_20150328.zip
for %%x in ("cd /home/weblogic/bea" "put "^"%fileList%^" "^"%fileName%^"" "exit") do echo %%~x>>"%deploy_cmd_file%" 这段代码调试有问题

我想实现最后写入到文件中的内容是这样的

cd /home/weblogic/bea
put "d:\WebContent_20150328.zip" "WebContent_20150328.zip"       要加上双引号
exit

这具体该怎么实现呢？求大神帮助！！！

shootman2

回复 20# pcl_test


    ok！问题得解！

pcl_test

回复 19# shootman2

@echo off
setlocal enabledelayedexpansion
::未见初始化host_list_file、deploy_app_folder、deploy_cmd_file，代码缺失？
for /f "usebackq eol=# tokens=1-14 delims=|" %%a in ("%host_list_file%") do (
        set fileList=
        set fileName=
        set /a filesCnt=0
        for /f "delims=" %%x in ('dir /a /b /s "%deploy_app_folder%\*.zip"') do set fileList=%%x&set fileName=%%~nxx&set /a filesCnt+=1
        if !filesCnt! equ 0 (
                echo 没有应用可以发布
        ) else if !filesCnt! equ 1 (
                (
                  echo,cd /d %%g
                  echo,put "!fileList!" "!fileName!"
                  echo,exit
                )>"%deploy_cmd_file%"
                echo psftp %%c -l %%d -pw %%e<"%deploy_cmd_file%"
                echo plink -l %%d -pw %%e %%d@%%c "unzip !fileName!;A"
                echo 主机 %%a.%%b 上的服务 %%f 的应用已经发布
        ) else if !filesCnt! gtr 1 (
                echo 应用程序包有多个，不知道该发布哪个
        )
)
echo 按任意键退出
pause>nul
复制代码

shootman2

回复 14# pcl_test


setlocal enabledelayedexpansion
for /f "usebackq eol=# tokens=1-14 delims=|" %%a in ("%host_list_file%") do (
        set fileList=
        set fileName=
        set /a filesCnt=0
        for /f "delims=" %%x in ('dir /a /b /s "%deploy_app_folder%\*.zip"') do set fileList=%%x&set fileName=%%~nxx&set /a filesCnt+=1
        if !filesCnt! equ 0 (
                echo 没有应用可以发布
        ) else if !filesCnt! equ 1 (
                echo off>"%deploy_cmd_file%"
                for %%x in ("cd %%g" "put "%%fileList%%" "%%fileName%%"" "exit") do echo %%~x>>"%deploy_cmd_file%"               
                echo psftp %%c -l %%d -pw %%e<"%deploy_cmd_file%"
                echo plink -l %%d -pw %%e %%d@%%c "unzip !fileName!;A"
                echo 主机 %%a.%%b 上的服务 %%f 的应用已经发布
        ) else if !filesCnt! gtr 1 (
                echo 应用程序包有多个，不知道该发布哪个
        )
)
echo 按任意键退出
pause>nul

bailong360

回复 17# CrLf


    看来真是我的电脑问题

CrLf

回复 16# bailong360


    64位 win7，chrome v36，所见即所得测试结果正常：

@Echo Off
SetLocal EnableDelayedExpansion
For /L %%i In (1 1 100) Do Echo Test%%i
Exit
复制代码

bailong360

回复 15# CrLf


        解决了,Win8.1 32位 Chrome36下用所见即所得模式发的贴会这样

@Echo OffSetLocal EnableDelayedExpansionFor /L %%i In (1 1 100) Do Echo Test%%iExit
复制代码

PS 这样...

CrLf

回复 2# bailong360


    什么浏览器，发一个试试，我看下是怎么回事

pcl_test

回复 13# shootman2

把你的完整代码发下，发现你发出的三段代码都不完整，不好整合

shootman2

回复 12# bailong360


    大神，请继续帮助！

bailong360

回复 10# 523066680


    那样似乎十分有趣~并且实用

bailong360

回复 9# shootman2


    可以把那个%%a改成%%1,或者%%A

523066680

回复 8# bailong360


    论坛也该内部支持一下彩色代码了，给论坛放个模块的事儿

shootman2

回复 8# bailong360


    还是不行的，最外层的语句  for /f "usebackq eol=# tokens=1-14 delims=|" %%a in ("%host_list_file%") do (     中，有tokens=1-14，也就是说
有%%a,%%b,%%c,%%d,%%e,%%f,%%g,%%h,%%i,%%j,%%k,%%l,%%m,%%n

这一句中 for %%x in ("cd %%g" "put "%%fileList%%" "%%fileName%%"" "exit") do echo %%~x>>"%deploy_cmd_file%"   %%fileList被系统当做 %%f +ilelist处理了！

bailong360

@echo off
setlocal enabledelayedexpansion
for /f "usebackq eol=# tokens=1-14 delims=|" %%1 in ("%host_list_file%") do (
        set fileList=
        set fileName=
        set /a filesCnt=0
        for /f "delims=" %%x in ('dir /a /b /s "%deploy_app_folder%\*.zip"') do set fileList=%%x&set fileName=%%~nxx&set /a filesCnt+=1
        if !filesCnt! equ 0 (
                echo 没有应用可以发布
        ) else if !filesCnt! equ 1 (
                echo off>"%deploy_cmd_file%"
                for %%x in ("cd %%g" "put "%%fileList%%" "%%fileName%%"" "exit") do echo %%~x>>"%deploy_cmd_file%"
                psftp %%3 -l %%4 -pw %%5<"%deploy_cmd_file%"
                plink -l %%4 -pw %%5 %%d@%%3 "unzip !fileName!;A"
                echo 主机 %%1.%%2 上的服务 %%6 的应用已经发布
        ) else if !filesCnt! gtr 1 (
                echo 应用程序包有多个，不知道该发布哪个
        )
)
echo 按任意键退出
pause>nul
复制代码