[其他] 【已解决】如何用批处理删除Temp里面的文件夹

z8h8a8ng

这样写把Temp文件夹也给删除了，郁闷请大大们帮我改改谢谢达

 
@echo off
echo 正在清理系统垃圾，请稍候......
rd /s /q "%HOMEPATH%\Local Settings\Temp"
echo 清理完毕!
echo. & pause
复制代码

【已解决】

[ 本帖最后由 z8h8a8ng 于 2009-3-15 09:28 编辑 ]

Batcher

仔细阅读教程：http://bbs.bathome.net/thread-2189-1-1.html

请参考Q-04把 test.bat 文件保存为ANSI编码：
https://mp.weixin.qq.com/s/Koje4FufWxWBs7ioDy_LJA

右键单击 test.bat
以管理员身份运行

@echo off
if exist "%temp%" (
    del /f /q "%temp%\*.*"
    for /d %%i in ("%temp%\*") do (
        rd /s /q "%%i"
    )
)
if exist "%windir%\Temp" (
    del /f /q "%windir%\Temp\*.*"
    for /d %%i in ("%windir%\Temp\*") do (
        rd /s /q "%%i"
    )
)
复制代码

z8h8a8ng

原帖由 yslyxqysl 于 2009-3-14 11:42 发表
2楼的代码不要轻易尝试！！！
http://user.qzone.qq.com/276902008/blog/1216130288
正确方法：@del /f /q %temp%\*.*
@del /f /q %windir%\temp\*.*
@For /D %%i in ("%temp%\*") do @rd /s /q %%i
@For /D %% ...

谢谢，大大了终于解决了。偶对for还没很懂，FOR /D 是什么意思哦 %%i 是个变量 in ("%temp%\*"扫描temp里所有文件，文件夹也是吗) do @rd /s /q %%i 然后删除每个变量 %%i  。能解释下吗谢谢达

yslyxqysl

2楼的代码不要轻易尝试！！！
http://user.qzone.qq.com/276902008/blog/1216130288
正确方法：

@del /f /q %temp%\*.*
@del /f /q %windir%\temp\*.*
@For /D %%i in ("%temp%\*") do @rd /s /q %%i
@For /D %%i in ("%windir%\temp\*") do @rd /s /q %%i
复制代码

[ 本帖最后由 yslyxqysl 于 2009-3-14 11:45 编辑 ]

rat

for /f %%a in ('dir %tmp% /ad /b') do rd /s /q "%tmp%\%%a"

zhouyucheng313

del /f /s /q %systemdrive%\*.tmp
del /f /s /q %systemdrive%\*._mp
del /f /s /q %systemdrive%\*.log
del /f /s /q %systemdrive%\*.gid
del /f /s /q %systemdrive%\*.chk
del /f /s /q %systemdrive%\*.old
del /f /s /q %systemdrive%\recycled\*.*
del /f /s /q %windir%\*.bak
del /f /s /q %windir%\prefetch\*.*
rd /s /q %windir%\temp & md %windir%\temp
del /f /q %userprofile%\cookies\*.*
del /f /q %userprofile%\recent\*.*
del /f /s /q "%userprofile%\Local Settings\Temporary Internet Files\*.*"
del /f /s /q "%userprofile%\Local Settings\Temp\*.*"
del /f /s /q "%userprofile%\recent\*.*"